hàm SUMPRODUCT không chịu điều kiện "*text*"

[buivankiet]

Tôi có một file, ở sheet1 có các nội dung sau :
- cột a : là tên mã hàng có khi có chứa từ " jeans " ở vị trí bất kỳ
- cột b : là mô tả hàng hóa, có khi chứa từ "98%cotton" ở vị trí bất kỳ
- Cột c : là số lượng
ở ô c9, tôi muốn tính tổng số lượng các mã hàng có từ " jeans"( cột a), và thành phần ( cột b ) có từ "98%cotton". Nhưng khi viết bằng hàm Sumproduct với điều kiện có chứa từ ( tức dấu *) thì không được, tôi có sử dụng hàm Contains trên mạng, nhưng viết lồng vào hàm Sumproduct cũng không được mà phải sử dụng cột phụ.
Tôi có post file lên, nhờ các cao thủ giúp dùm

 

[dat_butmuc]

Tôi có một file, ở sheet1 có các nội dung sau :
- cột a : là tên mã hàng có khi có chứa từ " jeans " ở vị trí bất kỳ
- cột b : là mô tả hàng hóa, có khi chứa từ "98%cotton" ở vị trí bất kỳ
- Cột c : là số lượng
ở ô c9, tôi muốn tính tổng số lượng các mã hàng có từ " jeans"( cột a), và thành phần ( cột b ) có từ "98%cotton". Nhưng khi viết bằng hàm Sumproduct với điều kiện có chứa từ ( tức dấu *) thì không được, tôi có sử dụng hàm Contains trên mạng, nhưng viết lồng vào hàm Sumproduct cũng không được mà phải sử dụng cột phụ.
Tôi có post file lên, nhờ các cao thủ giúp dùm

Tôi hiểu ý bạn rồi:
Cho mảng dữ liệu ở 3 cột A,B,C - rộng 17 dòng, công thức là:
=SUMPRODUCT((ISERROR(SEARCH("jeans",A1:A17))=FALSE)*(ISERROR(SEARCH("98%cotton",B1:B17))=FALSE)*(C1:C17))

Hy vọng đúng ý bạn !

 

[BNTT]

Để tôi giải thích một tí:

Bản thân hàm SUMPRODUCT không thể đi tìm ký tự đại diện. Mà khi nói đến tìm, bạn phải dùng hàm FIND hoặc SEARCH, và tìm ký tự đại diện, thì chắc chắn phải là SEARCH.

Hàm SEARCH, nếu không tìm thấy, sẽ trả về một lỗi. Vậy muốn biết có bao nhiêu cái có lỗi (không có chứa từ "jean" chẳng hạn), người ta dùng hàm ISERROR, hoặc ISERR, các hàm này sẽ trả về kết quả là TRUE (tương đương 1) hoặc FALSE (tương đương 0). SUMPRODUCT sẽ đếm những cái TRUE, FALSE này, và cho kết quả là có bao nhiêu cái có lỗi.

Vấn đề của chúng ta là tìm xem có bao nhiêu cái "không có lỗi" chứ không phải là "có lỗi", do đó, có thể dùng cách của bạn dat_butmuc:

ISERROR(SEARCH("jeans",A1:A17))=FALSE​

Hoặc có thể dùng hàm NOT (hàm phủ định)

NOT(ISERROR(SEARCH("jeans",A1:A17)))​

Tôi thì thích dùng cách nào ngắn nhất, do đó tôi sẽ dùng ISERR và NOT:

NOT(ISERR(SEARCH("jeans",A1:A17)))​

Tương tự như thế, cho việc tìm 98% cotton.