hàm logic bỏ qua các ô trống (2 người xem)

[Phan Thế Hiệp]

Như vậy, có cách nào thay nó bằng 1 mảng ko? Em thử {1:26} thì ko được (em rất yếu về mảng)

$A$1:$Z$1 thay bằng COLUMN($A:$Z)

Thân

 

[nguyenvanvietk50di]

xin nhờ các chuyên gia giúp đỡ với.
Với bài toán của mình mã không còn là số nữa có cả mã có ký tự chữ nữa thì các công thức không sử dụng được!
Mọi người có cách gì giúp đỡ mình với!

 

[Phan Thế Hiệp]

View attachment 214627
xin nhờ các chuyên gia giúp đỡ với.
Với bài toán của mình mã không còn là số nữa có cả mã có ký tự chữ nữa thì các công thức không sử dụng được!
Mọi người có cách gì giúp đỡ mình với!

Thử:

P32=IF(SUM(AGGREGATE({14,15},6,COUNTIF(E32:K32,"<"&E32:K32)/(E32:K32<>""),1)*{1,-1}),"NG","OK")

Enter, fill xuống.

Thân

 

[nguyenvanvietk50di]

Thử:

P32=IF(SUM(AGGREGATE({14,15},6,COUNTIF(E32:K32,"<"&E32:K32)/(E32:K32<>""),1)*{1,-1}),"NG","OK")

Enter, fill xuống.

Thân

cảm ơn bạn đã giúp đỡ!
Vấn đề đã được giải quyết hoàn toàn.

 

[Phan Thế Hiệp]

cảm ơn bạn đã giúp đỡ!
Vấn đề đã được giải quyết hoàn toàn.

Chưa đâu, tôi đang xem lại thêm hai trường hợp số dạng chuỗi, và số.
Tôi có ví dụ trong file kèm.


Thân

 

[nguyenvanvietk50di]

Các bạn có cách nào để lấy 1 trong các giá trị ở các cột không ạ?
Mình dùng hàm left nhưng khi các mã có số ký tự k giống nhau thì ra mã không đúng

 

[Phan Thế Hiệp]

View attachment 214638
Các bạn có cách nào để lấy 1 trong các giá trị ở các cột không ạ?
Mình dùng hàm left nhưng khi các mã có số ký tự k giống nhau thì ra mã không đúng

Lấy mã đầu:

=INDEX($E32:$K32,MATCH(1,INDEX(N(E32:K32<>""),),))&""

Lấy mã cuối:

=LOOKUP(2,1/(TRIM(E32:K32)<>""),E32:K32&"")

Thân

 

[dazkangel]

Thử:

=IF(AND(INDEX((E32:K32="")-(LOOKUP(,0/(E32:K32<>""),E32:K32)=E32:K32),)),"OK","NG")

 

[Phan Thế Hiệp]

Thử:

=IF(AND(INDEX((E32:K32="")+(LOOKUP(2,1/(E32:K32<>""),E32:K32)=E32:K32),)),"OK","NG")

Sáng tạo!

Hoặc đếm loại trùng cũng phù hợp cho bài này:

=IF(SUM(IFERROR(1/COUNTIF(E32:K32,E32:K32)/(E32:K32<>""),))>1,"NG","OK")

Kết thúc bằng Ctrl+Shift+Enter.

Thân

 

[tieuthubuongbinh]

Sáng tạo!

Hoặc đếm loại trùng cũng phù hợp cho bài này:

=IF(SUM(IFERROR(1/COUNTIF(E32:K32,E32:K32)/(E32:K32<>""),))>1,"NG","OK")

Kết thúc bằng Ctrl+Shift+Enter.

Thân

CT này chuẩn nhất đó anh.

Em post lại file với 2 dạng định dạng. CT của @dazkangel và CT cũ của anh sẽ không thỏa nếu có ô rỗng ở đầu. (vd row 339 sheet ma text)

 

[Phan Thế Hiệp]

CT này chuẩn nhất đó anh.

Em post lại file với 2 dạng định dạng. CT của @dazkangel và CT cũ của anh sẽ không thỏa nếu có ô rỗng ở đầu. (vd row 339 sheet ma text)

Các công thức đều đúng, chỉ do lấy cột không đủ.
Phải lấy từ C đến L

Thân.