Hàm đếm nhưng loại bỏ đếm trùng.

[Hoàng Tuấn 868]

Anh ơi cho em hỏi sao công thức này em đánh lúc ra kết quả có lúc ko nhỉ, em cũng đã ấn ctr+shift+enter rồi ạ ?

Bạn gửi file lên xem sao.

 

[hoanghoai1987]

Bạn gửi file lên xem sao.

Em cảm ơn anh ạ , em tìm ra được rồi ạ . Em đang làm copy theo công thức nên không hiểu bản chất lắm, cho em hỏi cái chỗ .....row(1:23) là nghĩa như thế nào anh nhỉ ?

 

[hoanghoai1987]

=SUMPRODUCT(($B$3:$B$22=F$2)/COUNTIF($A$3:$A$22,$A$3:$A$22))

Cho e hỏi là sao cái công thức này em áp dụng cho khoảng 20.000 dòng thì nó ko ra kết quả ạ

 

[Hoàng Tuấn 868]

Em cảm ơn anh ạ , em tìm ra được rồi ạ . Em đang làm copy theo công thức nên không hiểu bản chất lắm, cho em hỏi cái chỗ .....row(1:23) là nghĩa như thế nào anh nhỉ ?

Cứ hỏi vo không biết đâu mà lần, có file để xem thì may ra biết được bạn ạ.

 

[hoanggo123]

Ai cho em hỏi với ạ. Đếm trực tiếp từ mảng thì làm thế nào ạ (COUNTIF doesn't accept array constants (as far as I know))
Ví dụ em có mảng: {0;3;3;5;1} đếm ra 4 phần tử khác nhau hoặc 3 phần tử khác 0 thì làm kiểu gì ạ

 

[Phan Thế Hiệp]

Ai cho em hỏi với ạ. Đếm trực tiếp từ mảng thì làm thế nào ạ (COUNTIF doesn't accept array constants (as far as I know))
Ví dụ em có mảng: {0;3;3;5;1} đếm ra 4 phần tử khác nhau hoặc 3 phần tử khác 0 thì làm kiểu gì ạ

1/ '4 phần tử' khác 0, hay đếm không loại bỏ trùng lắp:

=COUNT(1/{0;3;3;5;1})

kết thúc bằng Ctrl+Shift+Enter.

2/ '3 phần tử' khác 0, hay đếm loại bỏ trùng lắp:

=COUNT(1/(MATCH(1/{0;3;3;5;1},1/{0;3;3;5;1},)=ROW(1:100)))

kết thúc bằng Ctrl+Shift+Enter.

3/ '4 phần tử' bất kỳ kể cả 0, và đếm loại bỏ trùng lắp:

=COUNT(1/(MATCH({0;3;3;5;1},{0;3;3;5;1},)=ROW(1:100)))

kết thúc bằng Ctrl+Shift+Enter.

Thân

 

[hoanggo123]

1/ '4 phần tử' khác 0, hay đếm không loại bỏ trùng lắp:

=COUNT(1/{0;3;3;5;1})

kết thúc bằng Ctrl+Shift+Enter.

2/ '3 phần tử' khác 0, hay đếm loại bỏ trùng lắp:

=COUNT(1/(MATCH(1/{0;3;3;5;1},1/{0;3;3;5;1},)=ROW(1:100)))

kết thúc bằng Ctrl+Shift+Enter.

3/ '4 phần tử' bất kỳ kể cả 0, và đếm loại bỏ trùng lắp:

=COUNT(1/(MATCH({0;3;3;5;1},{0;3;3;5;1},)=ROW(1:100)))

kết thúc bằng Ctrl+Shift+Enter.

Thân

Em làm được rồi ạ. Thank kiu a

 

[alamledo]

Chào các Anh Chị xin cho hỏi công thức (trong 1 dãy số có 11 số .trong đó có 2 hoặc 3 số trùng nhau vậy muốn lấy giá trị số trùng lặp nhau để làm kết quả thi trong excel làm như thế nào ?) Xin xem file đính kèm

 

[ketoanabc84]

Nhờ các cao nhân hướng dẫn cách xử lý tình huống này. Mình đang gặp vấn đề là mình đang muốn tính tổng giá trị của đơn hàng nhưng trong một đơn hàng nó lại duplicate lên nhiều giá trị tổng cộng làm cho việc tính tổng bị sai. Ngoài việc sử dụng remove duplicate ra thì k biết có công thức nào để tính tổng và loại trừ những giá trị trùng lặp k. Minh gửi file mẫu để mn tham khảo .Thanks mn nhiều.

 

[ybvba]

Em muốn đếm số học sinh trong tổ không đếm trùng (Bảng tính em đính kèm) các bác giúp em với ạ. Em xin cảm ơn.

 

[Nguyễn Hởi T.Y]

VD: Có dãy số liệu từ A1:A6 (Không đếm ô rỗng)
[FONT=&quot]
SUMPRODUCT((A1:A6<>"")/COUNTIF(A1:A6;A1:A6&""))

Hoặc công thức mảng:
SUM(IF(A1:A6="";0;1/COUNTIF(A1:A6;A1:A6)))
[/FONT]

Chào anh (chị), Em có làm theo công thức này để tổng hợp báo cáo cuối tháng nhưng bị sai cột số mã SP
Với công thức tương tự thì cột số đơn hàng lại đúng.
Anh (chị) check giúp Em xem lỗi ở đâu với ạ?
Em cảm ơn ạ!

 

[Phan Thế Hiệp]

Chào anh (chị), Em có làm theo công thức này để tổng hợp báo cáo cuối tháng nhưng bị sai cột số mã SP
Với công thức tương tự thì cột số đơn hàng lại đúng.
Anh (chị) check giúp Em xem lỗi ở đâu với ạ?
Em cảm ơn ạ!

Công thức bạn dùng có 2 phần điều kiện:
C3 =SUMPRODUCT(('CT test'!$G$3:$G$420='TH Test'!$A3)*(MONTH('CT test'!$F$3:$F$420)=1)*('CT test'!$H$3:$H$420=1)*('CT test'!$A$3:$A$420<>"")*(1/COUNTIF('CT test'!$A$3:$A$420,'CT test'!$A$3:$A$420&"")))

Phần 1 (phần tử số, màu xanh): đã ghi đủ các điều kiện lọc.

Phần 2 (phần mẫu số, màu đỏ): chưa ghi đủ các điều kiện lọc, nó chỉ biết làm 1 việc là đếm có bao nhiêu mã SP mà không quan tâm đến khách hàng nào, tháng/năm nào, và loại DT nào. Do vậy, dòng mã SP từ dòng 197 đến 246 (tháng 1), sẽ cộng chung với mã SP từ dòng 250 đến 299 (tháng 2), tức mỗi mã xuất hiện 2 lần, nên dù đã thỏa điều kiện ở phần tử (=1), nhưng phần mẫu tính cộng cả 2 tháng vậy kết quả tử/mẫu là 1/2=0.5, đúng ra phải là 1/1=1.

Số của bạn ra là 137, số chênh lệch là (299-250+1)/2=25, 137+25=162 là số mà bạn muốn hỏi. Bạn có thể kiểm tra trong cột K,L,M sheet CT_TEST, file TEST (1) đính kèm.

Muốn đúng bạn chỉnh lại tiêu đề tháng, rồi thử công thức sau (xem file GPE_TEST):

C3=COUNT(1/(MATCH('CT test'!$A$3:$A$400,IF(('CT test'!$G$3:$G$400=$A3)*(TEXT('CT test'!$F$3:$F$400,"my")=TEXT(B$1,"my"))*('CT test'!$H$3:$H$420=1),'CT test'!$A$3:$A$400),)=ROW($1:$400)))

Kết thúc bằng Ctrl+Shift+Enter, Fill xuống.

Thân

 

[ybvba]

Các bác giúp em với ạ
Em đếm loại bỏ đếm trùng có điều kiện mà không được.
Cảm ơn các bác ạ

 

[Phan Thế Hiệp]

Các bác giúp em với ạ
Em đếm loại bỏ đếm trùng có điều kiện mà không được.
Cảm ơn các bác ạ

Thử:

=COUNT(1/(MATCH(A$2:A$1000&B$2:B$1000,IF((B$2:B$1000>6)*(B$2:B$1000<9),A$2:A$1000&B$2:B$1000),)=ROW($1:$1000)))

Kết thúc bằng Ctrl +Shift +Enter.

Thân

 

[ybvba]

Thử:

=COUNT(1/(MATCH(A$2:A$1000&B$2:B$1000,IF((B$2:B$1000>6)*(B$2:B$1000<9),A$2:A$1000&B$2:B$1000),)=ROW($1:$1000)))

Kết thúc bằng Ctrl +Shift +Enter.

Thân

Cảm ơn bạn nhiều mình làm được rồi