Giúp giải bài tập Excel kết quả tuyển sinh 2015-2016 (2 người xem)

[Triệu Quốc Việt]

giúp em câu b) KẾT QUẢ VỚI Ạ
KẾT QUẢ: đƣợc tính là ĐỖ nếu hội đủ 2 điều kiện sau đây:

Phải không có môn nào dƣới 3 điểm.

Tổng điểm phải đạt (>=) điểm đỗ chiếu theo khu vực, khu vực A có điểm đỗ là 18, khu vực B có điểm đỗ là 17, khu vực C có điểm đỗ là 16.

Ký tự đầu tiên của SBD (Số báo danh) cho biết khu vực. Ngƣợc lại đƣợc coi là TRƢỢT

 

[VetMini]

Có 1 câu hỏi đưa 2 cái hình tổ bố. Đợi load, bỏ đi uống cà phê. Về xem tính sau.

Khu vực = left(SBD, 1)
Chuyển khu vực từ ABC thành 123 để dễ tính: Match(khu vực, {"A", "B", "C"},0). Hoặc Find(khu vực, "ABC")
Điểm đỗ theo khu vực: Choose(khu vực dạng số, 18, 17, 16)
Không môn nào dưới 3 điểm; có thể tính là môn thấp điểm nhất 3 hoặc hơn: MIN(các điểm) >= 3

Ráp lại:
IF(AND(MIN(các điểm) >= 3, tổng điểm >= Choose(Find(khu vực, "ABC"), 18, 17, 16)), "đỗ", "trượt")

 

[thnghiachau]

Có 1 câu hỏi đưa 2 cái hình tổ bố. Đợi load, bỏ đi uống cà phê. Về xem tính sau.

Khu vực = left(SBD, 1)
Chuyển khu vực từ ABC thành 123 để dễ tính: Match(khu vực, {"A", "B", "C"},0). Hoặc Find(khu vực, "ABC")
Điểm đỗ theo khu vực: Choose(khu vực dạng số, 18, 17, 16)
Không môn nào dưới 3 điểm; có thể tính là môn thấp điểm nhất 3 hoặc hơn: MIN(các điểm) >= 3

Ráp lại:
IF(AND(MIN(các điểm) >= 3, tổng điểm >= Choose(Find(khu vực, "ABC"), 18, 17, 16)), "đỗ", "trượt")

Cháu thuộc hàng "cù lần", chỉ biết có IF, AND, LEFT cơ bản thôi... vậy....
ô H3=IF(AND(D3>3,E3>3,F3>3),IF(AND(LEFT(C3,1)="A",G3>=18),"đỗ",IF(AND(LEFT(C3,1)="B",G3>=17),"đỗ",IF(AND(LEFT(C3,1)="C",G3>=16),"đỗ","trượt"))),"trượt")

 

[Maika8008]

Cháu thuộc hàng "cù lần", chỉ biết có IF, AND, LEFT cơ bản thôi... vậy....
ô H3=IF(AND(D3>3,E3>3,F3>3),IF(AND(LEFT(C3,1)="A",G3>=18),"đỗ",IF(AND(LEFT(C3,1)="B",G3>=17),"đỗ",IF(AND(LEFT(C3,1)="C",G3>=16),"đỗ","trượt"))),"trượt")

Cứ cơ bản thế cho dễ hiểu.

 

[Phuocam]

Cháu thuộc hàng "cù lần", chỉ biết có IF, AND, LEFT cơ bản thôi... vậy....
ô H3=IF(AND(D3>3,E3>3,F3>3),IF(AND(LEFT(C3,1)="A",G3>=18),"đỗ",IF(AND(LEFT(C3,1)="B",G3>=17),"đỗ",IF(AND(LEFT(C3,1)="C",G3>=16),"đỗ","trượt"))),"trượt")

Đoạn này rớt rồi, phải là:

AND(D3>=3,E3>=3,F3>=3)

.

 

[VetMini]

Công thức trâu bò nè:

 

[HieuCD]

giúp em câu b) KẾT QUẢ VỚI Ạ
KẾT QUẢ: đƣợc tính là ĐỖ nếu hội đủ 2 điều kiện sau đây:

Phải không có môn nào dƣới 3 điểm.

Tổng điểm phải đạt (>=) điểm đỗ chiếu theo khu vực, khu vực A có điểm đỗ là 18, khu vực B có điểm đỗ là 17, khu vực C có điểm đỗ là 16.

Ký tự đầu tiên của SBD (Số báo danh) cho biết khu vực. Ngƣợc lại đƣợc coi là TRƢỢT

Chênh lệch các khu vực 1 điểm
=IF((G3>=15+MATCH(LEFT(C3),{"C","B","A"},0))*(MIN(D3:F3)>=3),"đỗ","trượt")

Chênh lệch các khu vực có thể <> 1 điểm
=IF((G3>=16+SUM((LEFT(C3)<{"C","B"})*{1,1}))*(MIN(D3:F3)>=3),"đỗ","trượt")