Em xin hỏi về hàm lấy giá trị có điều kiện ạ (2 người xem)

[quangdao2411]

Em xin gửi file, nhờ các anh chị giúp đỡ ạ, em đang làm đồ án mà không biết lấy cách nào cho nhanh, làm thủ công thì lâu quá, mong các anh chị giúp đỡ em với ạ.

 

[Ba Tê]

Em xin gửi file, nhờ các anh chị giúp đỡ ạ, em đang làm đồ án mà không biết lấy cách nào cho nhanh, làm thủ công thì lâu quá, mong các anh chị giúp đỡ em với ạ.

Thử công thức này xem sao nhé:
=MAX(IF($C$2:$C$601="TT";$J$2:$J$601;0)) - Ctrl+Shift+Enter

 

[dazkangel]

Em xin gửi file, nhờ các anh chị giúp đỡ ạ, em đang làm đồ án mà không biết lấy cách nào cho nhanh, làm thủ công thì lâu quá, mong các anh chị giúp đỡ em với ạ.

Thử:

=AGGREGATE(14,6,J2:J601/((C2:C601="TT")+(C2:C601="HT")),1)

 

[HieuCD]

Em xin gửi file, nhờ các anh chị giúp đỡ ạ, em đang làm đồ án mà không biết lấy cách nào cho nhanh, làm thủ công thì lâu quá, mong các anh chị giúp đỡ em với ạ.

=MAX(IF(OR($A$2:$A$301={"TUM","T9"}),E2:E301,))
=MAX(IF(OR(C2:C601={"TT","HT"}),J2:J601,))

 

[dazkangel]

=MAX(IF(OR($A$2:$A$301={"TUM","T9"}),E2:E301,))
=MAX(IF(OR(C2:C601={"TT","HT"}),J2:J601,))

Có vẻ không ổn anh ơi, hàm or sẽ quy tất cả về 1 mối

 

[HieuCD]

Có vẻ không ổn anh ơi, hàm or sẽ quy tất cả về 1 mối

Yêu cầu: "Em muốn lấy Pmax của Story TUM, hoặc T9" dùng hàm Or hợp lý rồi

 

[dazkangel]

Yêu cầu: "Em muốn lấy Pmax của Story TUM, hoặc T9" dùng hàm Or hợp lý rồi

Em không biết giải thích sao, anh nhấn F9 câu lệnh OR($A$2:$A$301={"TUM","T9"}) thử xem.

 

[HieuCD]

Em không biết giải thích sao, anh nhấn F9 câu lệnh OR($A$2:$A$301={"TUM","T9"}) thử xem.

Đúng rồi, nó Or tất cả kết quả nên là True. Phải dùng công thức mảng

=MAX(IF(($A$2:$A$301="TUM")+($A$2:$A$301="T9"),E2:E301,""))
=MAX(IF((C2:C601="TT")+(C2:C601="HT"),J2:J601,""))

nhấn Ctrl+Shift+Enter

 

[Phan Thế Hiệp]

Đúng rồi, nó Or tất cả kết quả nên là True. Phải dùng công thức mảng

=MAX(IF(($A$2:$A$301="TUM")+($A$2:$A$301="T9"),E2:E301,""))
=MAX(IF((C2:C601="TT")+(C2:C601="HT"),J2:J601,""))

nhấn Ctrl+Shift+Enter

Có điều kỳ lạ trong công thức mảng dưới đây:
Nếu dùng:

=MAX(MMULT(N({"TUM","T9"}=A2:A601),{1;1})*E2:E601)
=MAX(MMULT(N({"TT","HT"}=C2:C601),{1;1})*J2:J601)

Phải nhấn CSE (ai cũng biết rồi! )
Nhưng:

=MAX(IF(MMULT(N({"TUM","T9"}=A2:A601),{1;1}),E2:E601,))
=MAX(IF(MMULT(N({"TT","HT"}=C2:C601),{1;1}),J2:J601,))

Cả hai đều không cần nhấn CSE!!
Ngộ nghĩnh!?
Chúc anh em ngày mới thiệt vui.

Thân.

 

[quangdao2411]

Thử công thức này xem sao nhé:
=MAX(IF($C$2:$C$601="TT";$J$2:$J$601;0)) - Ctrl+Shift+Enter

Không dùng được bạn àh

Bài đã được tự động gộp: 8/6/18

Em cảm ơn các anh chị đã giúp đỡ em, nhưng em vẫn không sử dụng được công thức nào, ý em là ở Sheet 2: Em muốn lấy M3max của Load TT, hoặc HT, hoặc của BAO MAX, chỉ 1 Load thôi ạ (em muốn chọn hết cột Load và cột M3). Ở Sheet 1: Em muốn lấy Pmax của Story TUM, hoặc T9, hoặc 1 tầng bất kỳ ạ, chỉ 1 tầng thôi ạ (em muốn chọn hết cột Story và cột P)

 

[HieuCD]

Không dùng được bạn àh

Bài đã được tự động gộp: 8/6/18

Em cảm ơn các anh chị đã giúp đỡ em, nhưng em vẫn không sử dụng được công thức nào, ý em là ở Sheet 2: Em muốn lấy M3max của Load TT, hoặc HT, hoặc của BAO MAX, chỉ 1 Load thôi ạ (em muốn chọn hết cột Load và cột M3). Ở Sheet 1: Em muốn lấy Pmax của Story TUM, hoặc T9, hoặc 1 tầng bất kỳ ạ, chỉ 1 tầng thôi ạ (em muốn chọn hết cột Story và cột P)

=MAX(IF($A$2:$A$301="TUM",E2:E301,""))
=MAX(IF(C2:C601="TT",J2:J601,""))


nhấn Ctrl+Shift+Enter

 

[quangdao2411]

=MAX(IF($A$2:$A$301="TUM",E2:E301,""))
=MAX(IF(C2:C601="TT",J2:J601,""))


nhấn Ctrl+Shift+Enter

Dạ em cảm ơn ạ, nhưng có cách nào mà không cần nhấn Ctrl+Shift+Enter không ạ, chỉ cần nhấn Enter thôi ấy ạ

 

[HieuCD]

Dạ em cảm ơn ạ, nhưng có cách nào mà không cần nhấn Ctrl+Shift+Enter không ạ, chỉ cần nhấn Enter thôi ấy ạ

Các giá trị đều <0

=INDEX(LARGE((A2:A151="TUM")*E2:E151,1+COUNTIF(A2:A151,"<>"&"TUM")),)

 

[quangdao2411]

Các giá trị đều <0

=INDEX(LARGE((A2:A151="TUM")*E2:E151,1+COUNTIF(A2:A151,"<>"&"TUM")),)

Dạ, em cảm ơn anh nhé, công thức hay lắm ạ, em cảm ơn anh rất nhiều ạ.