Dùng hàm tính tổng (2 người xem)

[MinhKhai]

Em có file chấm công với các ký hiệu theo quy luật chung. Tuy nhiên việc đặt công thức tính tổng lại trở nên gian nan đến mức không thể chịu được.
Trong file đính kèm, em cần tính tổng tại 2 cột có nền vàng (cột AU và AV).
Nhờ các anh/chị giúp cho công thức nào ngắn nhất sao cho khi nhập dữ liệu trong tháng thì sẽ có kết quả đúng
(Hàm có sẵn trong 2 cột nói trên em để lại để các anh chị thấy cách hiện tại em đang dùng nó như thế nào)
Em xin cảm ơn

 

[thuhuonglee]

Em có file chấm công với các ký hiệu theo quy luật chung. Tuy nhiên việc đặt công thức tính tổng lại trở nên gian nan đến mức không thể chịu được.
Trong file đính kèm, em cần tính tổng tại 2 cột có nền vàng (cột AU và AV).
Nhờ các anh/chị giúp cho công thức nào ngắn nhất sao cho khi nhập dữ liệu trong tháng thì sẽ có kết quả đúng
(Hàm có sẵn trong 2 cột nói trên em để lại để các anh chị thấy cách hiện tại em đang dùng nó như thế nào)
Em xin cảm ơn

Nhìn 2 công thức này là bó tay toàn tập luôn.
Bạn nên diễn giải bằng lời thì mọi người mới có thể rút gọn được công thức cho bạn.
Thân ái !

 

[Phan Thế Hiệp]

Em có file chấm công với các ký hiệu theo quy luật chung. Tuy nhiên việc đặt công thức tính tổng lại trở nên gian nan đến mức không thể chịu được.
Trong file đính kèm, em cần tính tổng tại 2 cột có nền vàng (cột AU và AV).
Nhờ các anh/chị giúp cho công thức nào ngắn nhất sao cho khi nhập dữ liệu trong tháng thì sẽ có kết quả đúng
(Hàm có sẵn trong 2 cột nói trên em để lại để các anh chị thấy cách hiện tại em đang dùng nó như thế nào)
Em xin cảm ơn

Nể và cũng thương bạn!
Bạn có thể làm theo hướng sau để rút ngắn, vì thật tình muốn giúp bạn nhưng hiện tại vào "giờ cao điểm" nên tôi chỉ đưa ra hướng bạn chịu khó tìm cách thay thế hàm cũ:
Ví dụ:
1. Gom những cái nhân với 8 vào chung với nhau:

=COUNTIF($E7:$AJ7,"F")*8+COUNTIF($E7:$AJ7,"NB")*8+COUNTIF($E7:$AJ7,"BH")*8+COUNTIF($E7:$AJ7,"CĐ")*8+COUNTIF($E7:$AJ7,"H")*8+COUNTIF($E7:$AJ7,"X")*8

Thay bằng:
=SUM(COUNTIF($E7:$AJ7,{"F","NB","BH","CĐ","H","X"})*8)
​

2. Thay những ký tự chấm công giống nhau vào chung tổ hợp:

=COUNTIF($E7:$AJ7,"X1")*1+COUNTIF($E7:$AJ7,"X2")*2+COUNTIF($E7:$AJ7,"X3")*3+COUNTIF($E7:$AJ7,"X4")*4+COUNTIF($E7:$AJ7,"X5")*5+COUNTIF($E7:$AJ7,"X6")*6+COUNTIF($E7:$AJ7,"X7")*7+COUNTIF($E7:$AJ7,"X,+1")*9+COUNTIF($E7:$AJ7,"X,+2")*10+COUNTIF($E7:$AJ7,"X,+3")*11+COUNTIF($E7:$AJ7,"X,+4")*12+COUNTIF($E7:$AJ7,"X,+5")*13+COUNTIF($E7:$AJ7,"X,+6")*14+COUNTIF($E7:$AJ7,"X,+7")*15

Thay bằng:
=SUMPRODUCT(COUNTIF($E7:$AJ7,"X"&ROW($1:$7))*ROW($1:$7))+SUMPRODUCT(COUNTIF($E7:$AJ7,"X,+"&ROW($1:$7))*ROW($9:$15))​

Phía dưới bạn tiếp tục tìm những điểm giống nhau hoặc nhân với 1 số giống nhau như cách thức trên sẽ từ từ làm gọn lại công thức.

Thân!

​

 

[Phan Thế Hiệp]

Một cách khác có thể gọn hơn nhiều:

1. Bạn tạo 1 sheet khác chứa các ký hiệu chấm công và hệ số (nhân) tương ứng với ký hiệu đó (xem sheet Heso file kèm)
2. Chỉ cần dùng công thức:

   AW7=SUMPRODUCT(COUNTIF('BẢNG CÔNG'!$E7:$AJ7,Heso!$A$2:$A$252)*Heso!$B$2:$B$252)
   AX7=SUMPRODUCT(COUNTIF('BẢNG CÔNG'!$E7:$AJ7,Heso!$C$2:$C$252)*Heso!$D$2:$D$252)

   ; A252 hay B252 có thể thay đổi theo chiều dài dòng mà bảng Heso bạn tạo ra.
3. Bạn xem kết quả mẫu tại cột AW; AX để đối chiếu với kết quả từ công thức cũ của bạn.

Thân!

 

[Hau Hr]

Một cách khác có thể gọn hơn nhiều:

1. Bạn tạo 1 sheet khác chứa các ký hiệu chấm công và hệ số (nhân) tương ứng với ký hiệu đó (xem sheet Heso file kèm)
2. Chỉ cần dùng công thức:

   AW7=SUMPRODUCT(COUNTIF('BẢNG CÔNG'!$E7:$AJ7,Heso!$A$2:$A$252)*Heso!$B$2:$B$252)
   AX7=SUMPRODUCT(COUNTIF('BẢNG CÔNG'!$E7:$AJ7,Heso!$C$2:$C$252)*Heso!$D$2:$D$252)

   ; A252 hay B252 có thể thay đổi theo chiều dài dòng mà bảng Heso bạn tạo ra.
3. Bạn xem kết quả mẫu tại cột AW; AX để đối chiếu với kết quả từ công thức cũ của bạn.

Thân!

chào anh .anh có thể giải thích cách dùng hàm sumproduct trong bài giúp e được không ạ .e cảm ơn

 

[Phan Thế Hiệp]

anh ơi có thể giải thích giúp em sheet hệ số không anh .e chưa hiểu cách a trình bày sheet này thanks a

Công thức cũ của bạn @MinhKhai đều theo dạng chung:
Countif('BẢNG CÔNG'!$E7:$AJ7, "ký tự chỉ định làm tiêu chí so khớp")*"Số chỉ định"
Do có nhiều "ký tự chỉ định làm tiêu chí so khớp" và tương ứng với nó là "Số chỉ định" cụ thể và cũng nhiều, cho nên tôi gom thành 2 cột:

• "ký tự chỉ định làm tiêu chí so khớp" thành cột "Ký hiệu 1" hay "Ký hiệu 2"
• "Số chỉ định" thành cột "HS1" và "HS2"

Chẳng qua là dựa vào toàn bộ công thức cũ của bạn @MinhKhai để trích lục ra thành bảng hệ số này.
Còn ý nghĩa của ký tự và hệ số nhân chỉ có bạn @MinhKhai mới hiểu thôi.

Thân!