Chuyên đề giải đáp các bài tập

[minhsam]

Tìm tài liệu Bài tập Excel

Chẳng là thứ 5 này mình thi nghề THPT rồi ! Ai có những tài liệu nào liên quan đến Đề thi nghề THPT của các năm trước (cả lý thuyết và thực hành) thì up lên hộ mình ! Với lại có 1 câu trong đề cương của mình như thế này :
1 địa chỉ ô chứa công thức =Average(B1:B5) , trong đó các cô từ B1 đến B5 lần lượt chứa các giá trị 1 , 2 , 3 , 4 và ô trống. Sau khi mình nhập các giá trị trên và nhập công thức theo yêu cầu luôn, thì kết quả cho ra là 2.5. Trong khi đó mình tính nhẩm thì kết quả lại ra là 2. Ai trả lời giúp mình với !!!

 

[phuonglvg]

Minh Sam mến!

Chẳng là thứ 5 này mình thi nghề THPT rồi ! Ai có những tài liệu nào liên quan đến Đề thi nghề THPT của các năm trước (cả lý thuyết và thực hành) thì up lên hộ mình ! Với lại có 1 câu trong đề cương của mình như thế này :
1 địa chỉ ô chứa công thức =Average(B1:B5) , trong đó các cô từ B1 đến B5 lần lượt chứa các giá trị 1 , 2 , 3 , 4 và ô trống. Sau khi mình nhập các giá trị trên và nhập công thức theo yêu cầu luôn, thì kết quả cho ra là 2.5. Trong khi đó mình tính nhẩm thì kết quả lại ra là 2. Ai trả lời giúp mình với !!!

Trong Ecxel thì hàm Average tính như vậy là đúng, bạn tính nhẩm như vậy là sai rồi. Vì hàm Average tính như sau: (1+2+3+4)/4=2.5 chớ không phải là 2 như bạn tính

 

[huycuongxd]

Nguyên văn bởi minhsam
1 địa chỉ ô chứa công thức =Average(B1:B5) , trong đó các cô từ B1 đến B5 lần lượt chứa các giá trị 1 , 2 , 3 , 4 và ô trống. Sau khi mình nhập các giá trị trên và nhập công thức theo yêu cầu luôn, thì kết quả cho ra là 2.5. Trong khi đó mình tính nhẩm thì kết quả lại ra là 2. Ai trả lời giúp mình với !!!

Trong Ecxel thì hàm Average tính như vậy là đúng, bạn tính nhẩm như vậy là sai rồi. Vì hàm Average tính như sau: (1+2+3+4)/4=2.5 chớ không phải là 2 như bạn tính

- Nếu cái ô B5 (ô trống) của bạn có chứa số 0 thì kết quả là (1+2+3+4+0)/5=2
- Nếu ô B5 ko có gì thì kết quả là (1+2+3+4)/4=2.5
Please double-check!

 

[TKT]

Với lại có 1 câu trong đề cương của mình như thế này :
1 địa chỉ ô chứa công thức =Average(B1:B5) , trong đó các cô từ B1 đến B5 lần lượt chứa các giá trị 1 , 2 , 3 , 4 và ô trống. Sau khi mình nhập các giá trị trên và nhập công thức theo yêu cầu luôn, thì kết quả cho ra là 2.5. Trong khi đó mình tính nhẩm thì kết quả lại ra là 2. Ai trả lời giúp mình với !!!

TH1:
B1=1
B2=2
B3=3
B4=4
B5="Trống" hoặc chứa Text (ký tự)
--> =Average(B1:B5) = 2.5

Sẽ khác:

TH2:
B1=1
B2=2
B3=3
B4=4
B5=0 (số không)
--> =Average(B1:B5) = 2

 

[minhsam]

Àh mình hiểu rồi hèn gì hôm qua mình làm hoài suy nghĩ mãi mà chẳng hiểu tại sao nó lại ra như vậy ! Cuối cùng cũng mình cũng nhận được lời giải thích cặn kẽ của mấy bạn ! Thanks các bạn nhiều lắm ! Sau này có gì mình cần hỏi thêm mình sẽ post bài lên đây để có thêm kinh nghiệm nha !

 

[TranThanhPhong]

Mình gửi 20 đề bài tiếp theo, các bạn chịu khó nhập lại và upload lên cho mọi người dễ sử dụng.

Thanh Phong

 

[giotdang907]

Học hàm Excel qua các bài tập

Các Bạn giải giúp mình bài tập Excel này (có file đính kèm theo). Giải giúp mình 4 dấu sao đầu và 2 dấu sao cuối. Cảm ơn nhiều.

 

[cop_kh]

Gởi bạn File đính kèm, xem OK không nhé.

 

[BNTT]

Topic Học hàm Excel qua các bài tập đang bị lỗi kỹ thuật.
Trong khi chờ các Kỹ thuật viên sửa chữa và phục hồi lại dữ liệu, tôi xin tạm mở topic này. Sau khi phục hồi lại topic cũ, sẽ gộp lại chung với nhau.

-----------------------------------------------------------------------------------------------------------------------

Các Bạn giải giúp mình bài tập Excel này (có file đính kèm theo). Giải giúp mình 4 dấu sao đầu và 2 dấu sao cuối. Cảm ơn nhiều.

Mã tỉnh: (cột D)

[D5] =IF(AND(LEFT(B5)="0",LEFT(B5,2)<>"09"),MID(B5,2,2),"")​

Tên tỉnh (cột E, câu này, Cop_kh đưa vào cả Nội hạt lẫn Di động... Tên tỉnh thì làm sao mà có mấy cái tên này?):

[E5] =IF(D5="","",VLOOKUP(D5*1,$J$15:$K$18,2,0))​

Tiền nội hạt (cột F, câu này, Cop_kh tính không đúng, 7 phút là xem như 4 cuộc gọi, bạn tính có 3 à!):

[F5] =IF(LEFT(B5)<>"0",ROUND(C5/2,0)*400,0)​

Tiền gọi liên tỉnh (cột G):

[G5] =IF(D5="",0,C5*VLOOKUP(D5*1,$J$15:$L$18,3,0))​

Tiền gọi di động (cột H):

[H5] =IF(LEFT(B5,2)="09",C5*1800,0)​

Tính số tiền của từng loại: (K9, L9, M9)

[K9] =SUM(F5:F13)​

Tính tổng số tiền chung (J9)

[J9] =SUM(K9:M9) = 85,200 (phải không ạ?)​

Bài này, tôi cố tình dùng những công thức bình dân nhất!

 

[TKT]

Topic Học hàm Excel qua các bài tập đang bị lỗi kỹ thuật.
Trong khi chờ các Kỹ thuật viên sửa chữa và phục hồi lại dữ liệu, tôi xin tạm mở topic này. Sau khi phục hồi lại topic cũ, sẽ gộp lại chung với nhau.

-----------------------------------------------------------------------------------------------------------------------

Các Bạn giải giúp mình bài tập Excel này (có file đính kèm theo). Giải giúp mình 4 dấu sao đầu và 2 dấu sao cuối. Cảm ơn nhiều.

Mã tỉnh:
=IF(AND(LEN(B6)>8,MID(B6,2,1)<>"9"),MID(B6,2,2),"")

Tên tỉnh:
=IF(D5="","",VLOOKUP(D5*1,$J$15:$K$18,2,0))

Tiền nội hạt:
=IF(LEFT(B5)="8",MOD(C5,2)*400+INT(C5/2)*400,0)

Tiền liên tỉnh:
=IF(D5<>"",C5*VLOOKUP(D5*1,$J$15:$L$18,3,0),"")

Tiền di động:
=IF(SUM(F5:G5)>0,0,C5*1800)

File đính kèm

 

[tuankeuqt]

làm giùm mình bài tập sau

Mình mới học nên cũng ko biết đc nhiều, 3 câu đầu làm đc rồi còn lại mình potay có ai giúp mình với

 

[0939594694]

em không biết cách làm bài này .

các bạn hãy giúp mình làm bài tập này . mình đang bí nó

 

[mountain84]

các bạn hãy giúp mình làm bài tập này . mình đang bí nó

bài của bạn đây, bạn kiểm tra lại nhé!

 

[ndu96081631]

bài của bạn đây, bạn kiểm tra lại nhé!

Bài này bạn làm công thức dài quá
Tôi làm như sau:

E3 =(1-0.05*(LEFT($B3,2)="MT"))*HLOOKUP(RIGHT($B3,2),$H$12:$L$14,3,0)

F3 =(1-0.1*(RIGHT($B3,2)="BM")*(DATE(2007,MID($B3,5,2),MID($B3,3,2))>DATE(2007,3,1)))*$D3*$E3

G3 =CHOOSE((LEFT($B3,2)="MD")*((MID($B3,3,4)="1202")+(MID($B3,3,4)="2005"))*($D3>=5)+1,"","Tặng phiếu ưu đãi")

 

[BNTT]

đây là bài của bạn, bạn thử kiểm tra xem có ổn không?

Gửi bạn mountain84, bài toán Cà phê, Đường, Gạo, Hạt điều... của tuankeuqt hỏi, bạn làm vậy cũng được, nhưng công thức của bạn dài quá. Có cách làm cho nó ngắn hơn. Bạn so sánh các công thức sau (công thức của bạn ở hàng trên, còn công thức của tôi ở hàng dưới):

Câu 2, Loại Hàng (cột D):

= VALUE(RIGHT(B2,1))
= RIGHT(B2)*1
​

Câu 3, Tên Hàng (cột C):

= VLOOKUP(LEFT(B2,1),$A$13:$E$16,2,0)
= VLOOKUP(LEFT(B2),$A$13:$E$16,2,0)​

Câu 4, Thành tiền (cột F):

= E2 * IF(AND(D2=1, C2=VLOOKUP(LEFT(B2,1),$A$13:$E$16,2,0)), VLOOKUP(LEFT(B2,1),$A$13:$E$16,3,0), VLOOKUP(LEFT(B2,1),$A$13:$E$16,4,0))
= E2 * VLOOKUP(LEFT(B2),$A$13:$D$16,D2+2,0)​

Câu 5, Thuế (cột G):

= F2 * IF(AND(VLOOKUP(LEFT(B2,1),$A$13:$E$16,2,0)=C2, VLOOKUP(C2,$B$13:$E$16,4,0)="x"), 0, VLOOKUP(VALUE(MID(B2,2,1)),$I$13:$J$16,2,0))
= F2 * VLOOKUP(MID(B2,2,1)*1,$I$13:$J$16,2,0) * (VLOOKUP(LEFT(B2),$A$13:$E$16,5,0)<>"x")​

Câu 10, Thống kê (C34:C37):

= SUMIF($C$2:$C$8,B34,$H$2:$H$8)
= SUMIF($C$2:$C$8,B34,$H$2)​

 

[0939594694]

còn câu này mình không biết .

còn câu giảm giá . tính trong 15ngày đầu . mình ko biết dùng hàm như thế nào . các bạn giúp mình với . thanks các bạn nhiêu lắm .

 

[Po_Pikachu]

Ô H3 bạn nhập công thức sao rồi Fill xuống.
=(G3*D3*10/100)*(F3-(DATE(2007,1,1))<=15)
Bạn có thể tạo topic riêng được không? Cứ chen ngang kiểu này thì không được hay đâu?
Thân.

 

[BNTT]

còn câu giảm giá . tính trong 15ngày đầu . mình ko biết dùng hàm như thế nào . các bạn giúp mình với . thanks các bạn nhiêu lắm .

Góp ý với bài của bạn tí nha.
Công thức lập Tên hàng (cột C):

=VLOOKUP(LEFT(B3, 1), $G$16:$J$18, 2, 0)& " - " & IF(RIGHT(B3, 1)="A", "loại A", "loại B")​

Chỉ cần vầy thôi nè:

=VLOOKUP(LEFT(B3), $G$16:$J$18, 2, 0)& " - Loại " & RIGHT(B3)​

Chỗ Loại, nó đã có sẵn trong mã số rồi, chỉ cần ghép thêm chữ "Loại" thôi, đâu cần tới IF.
Và hàm RIGHT, hàm LEFT, nếu chỉ lấy 1 ký tự thì khỏi gõ số 1.

Còn cái công thức để giảm giá:

Giảm giá = 10% (số lượng * đơn giá ) nếu mặt hàng được bán trong 15 ngày đầu của tháng 1/2007

Bạn tập phân tích đi:

• Số lượng: D3
  
  
• Đơn giá: G3, nhưng chỉ lấy 4 con số đầu thôi, không lấy chữ "đ" ở sau:
  
  LEFT(G3,4)
  
  Hoặc chắc ăn hơn, lỡ như giá tiền nhiều hơn 9999, thì dùng thêm hàm LEN, lấy độ dài của G3 trừ bớt đi 1:
  
  LEFT(G3, LEN(G3)-1)
  
  Trong trường hợp cụ thể bài toán bạn gởi lên, thì chỉ cần =LEFT(G3,4) là OK rồi!
  
  
• 15 ngày đầu của tháng 1/2007: lấy Ngày ở F3 đi so sánh: Phần Ngày thì nằm trong khoảng 1 đến 15, phần Tháng thì là 1:
  
  AND(DAY(F3)>=1, DAY(DAY(F3)<=15), MONTH(F3)=1)
  
  Nhưng cái này dài quá, để ý thấy bảng tính của bạn chỉ tính trong tháng 1/2007, nên tôi làm kiểu khác: Lấy ngày ở F3 trừ đi ngày 1/1/2007, nếu kết quả nhỏ hơn hay bằng 15 thì tính giảm giá:
  
  (F3-"1/1/2007")<=15
  
  (hoặc (F3-DATE(2007,1,1))<=15, nhưng 1/1 thì định dạng kiểu nào cũng ra ngày 1 tháng 1, nên khỏi cần dùng hàm DATE)

Nhân hết 3 cái đó lại với nhau, rồi nhân với -10% là ra giảm giá:

[H3] = D3 * LEFT(G3,4) * (F3-"1/1/2007"<=15) * 10%​

Ở cột thành tiền cũng phải để ý đừng có lấy nguyên ô Đơn giá mà nhân, Excel nó chửi à:

[I3] = LEFT(G3,4)*D3 - H3​

Công thức cho bảng tổng hợp (L12:M13) là:

=SUMPRODUCT((LEFT($C$3:$C$10, FIND("-", $C$3:$C$10)-2) = $K12) * (RIGHT($B$3:$B$10) = RIGHT(L$11)) * $D$3:$D$10)​

Bạn tự phân tích nghe.

 

[mountain84]

cảm ơn hai bạn ndu96081631 và bạn BNTT rất nhiều có lẽ mình còn phải học lâu nữa mới có thể nghĩ ra cách rút ngắn công thức được hay như hai bạn. Từ hai bài giải này mình học được rất nhiều, nhưng mình vẫn chưa hiểu được cách giải của bạn ndu96081631 rất mong được bạn chỉ bảo thêm. Cảm ơn hai bạn nhiều

 

[0939594694]

các bạn hãy giúp mình 3 bài này . em bí nó rồi

em đang bí 3 bài tập này . các bác giúp em cái . thanks các bác nhiều lắm .