Công thức tính tổng một cell nhiều sheet (2 người xem)

[salam]

Chào các Bác các Bác cho em hỏi cách tính tổng một ô của nhiều sheet.
Bảng của em có các sheet TH, 1,2,3 ...
ô A2 của sheet TH là tên của các sheet 1,2,3 ...
Em muốn cộng một ô của sheet 1 đến sheet 2 hoặc đến sheet 3 ... thì chọn tên sheet ở ô A2.
Em dùng ct dưới nó báo lỗi như trong file.

=SUM(INDIRECT("'1:"&$A$2&"'!"&ADDRESS(ROW(),COLUMN(),4)))

Các Bác giúp em với.

 

[tigertiger]

Chào các Bác các Bác cho em hỏi cách tính tổng một ô của nhiều sheet.
Bảng của em có các sheet TH, 1,2,3 ...
ô A2 của sheet TH là tên của các sheet 1,2,3 ...
Em muốn cộng một ô của sheet 1 đến sheet 2 hoặc đến sheet 3 ... thì chọn tên sheet ở ô A2.
Em dùng ct dưới nó báo lỗi như trong file.

=SUM(INDIRECT("'1:"&$A$2&"'!"&ADDRESS(ROW(),COLUMN(),4)))

Các Bác giúp em với.

Dùng công thức Array sau:

=SUM(IF(ROW(INDIRECT("1:"&$A$2))>0,INDIRECT(ROW(INDIRECT("1:"&$A$2))&"!"&ADDRESS(ROW(),COLUMN(),4)),0))

có Mr. Công Thức ở đây chắc ngon và ngắn hơn

tôi thử với SUMPRODUCT (k cần công thức array) chưa được, bạn phát triển xem sao

Thế này thì ngắn gọn hơn một chút

Vẫn công thức Array

=SUM(INDIRECT(ROW(INDIRECT("1:"&$A$2))&"!"&ADDRESS(ROW(),COLUMN(),4)),IF(ROW(INDIRECT("1:"&$A$2))>0,1,0))

* sorry:, tách bài vì để rõ công thức hơn và tính cập nhập

 

[salam]

Bác Hổ ơi hai cái này

=SUM(IF(ROW(INDIRECT("1:"&$A$2))>0,INDIRECT(ROW(INDIRECT("1:"&$A$2))&"!"&ADDRESS(ROW(),COLUMN(),4)),0))

=SUM(INDIRECT(ROW(INDIRECT("1:"&$A$2))&"!"&ADDRESS(ROW(),COLUMN(),4)),IF(ROW(INDIRECT("1:"&$A$2))>0,1,0))

Bác
Hình như nó lấy giá trị ô của sheet (1) nhân với A2 của sheet TH. Bác xem lại cho em với.
Cám ơn Bác nhiều.

 

[boyxin]

Các Bác đâu rồi giúp em với em đang cần.

THAM KHẢO THÊM FILE NÀY XEM GIÚP ĐƯỢC GÌ KHÔNG

 

[salam]

THAM KHẢO THÊM FILE NÀY XEM GIÚP ĐƯỢC GÌ KHÔNG

Cám ơn Boyxin nhé. CT trong file của bạn là sumif rồi. Sumif các sheets mình làm được rồi nhưng ở đây lại là cộng một ô của các sheet vào một sheet số lượng các sheet thay đổi. VD: mình có 20 sheet được đánh tên lần lượt TH, 1,2,3,4 ....19. cấu trúc các sheet giống nhau. VD tại ô A6 sheet TH mình muốn cộng tất cả các giá trị ô A6 của các sheet có thể là từ sheet1 đến sheet2 hay 1-3 ...
Nhờ Các Bác Giúp Đỡ.
Em xin cảm ơn.

 

[cadafi]

Cám ơn Boyxin nhé. CT trong file của bạn là sumif rồi. Sumif các sheets mình làm được rồi nhưng ở đây lại là cộng một ô của các sheet vào một sheet số lượng các sheet thay đổi. VD: mình có 20 sheet được đánh tên lần lượt TH, 1,2,3,4 ....19. cấu trúc các sheet giống nhau. VD tại ô A6 sheet TH mình muốn cộng tất cả các giá trị ô A6 của các sheet có thể là từ sheet1 đến sheet2 hay 1-3 ...
Nhờ Các Bác Giúp Đỡ.
Em xin cảm ơn.

Em đã test thử, hình như hàm Sum nó không hiểu indirect thì phải. Anh thử dùng if xem (nếu số lượng sheet không nhiều).
Đại loại như:

=IF(A2=1,sum('1:1'!A6),if(A2=2,sum('1:2'!A6),if(A2=3,sum('1:3'!A6),0)))

 

[salam]

Em đã test thử, hình như hàm Sum nó không hiểu indirect thì phải. Anh thử dùng if xem (nếu số lượng sheet không nhiều).
Đại loại như:

=IF(A2=1,sum('1:1'!A6),if(A2=2,sum('1:2'!A6),if(A2=3,sum('1:3'!A6),0)))

Có khoảng 40 sheet cơ mà mình muốn cộng kiểu ý mới chết chứ. Sao dùng Sum(1:3,A6) thì được mà dùng sum(indirect( thì nó báo lỗi nhỉ. Tạm thời mình dùng cột phụ để cộng. Nghiên cứu sau vậy.
Cám ơn các Bác.

 

[ndu96081631]

Em đã test thử, hình như hàm Sum nó không hiểu indirect thì phải.

Hiểu được!
Cách 1: Dùng SUM

{=SUM(N(INDIRECT("'"&ROW(INDIRECT("1:"&$A$2))&"'!"&ADDRESS(ROW(),COLUMN()))))}

Cách 2: Dùng SUMPRODUCT

=SUMPRODUCT(N(INDIRECT("'"&ROW(INDIRECT("1:"&$A$2))&"'!"&ADDRESS(ROW(),COLUMN()))))

 

[salam]

Hiểu được!
Cách 1: Dùng SUM

{=SUM(N(INDIRECT("'"&ROW(INDIRECT("1:"&$A$2))&"'!"&ADDRESS(ROW(),COLUMN()))))}

Cách 2: Dùng SUMPRODUCT

=SUMPRODUCT(N(INDIRECT("'"&ROW(INDIRECT("1:"&$A$2))&"'!"&ADDRESS(ROW(),COLUMN()))))

ndu96081631 Ơi mình thử dùng CT của bạn nhưng vẫn báo lỗi. (N) là gì trong công thức vậy bạn chỉ cho mình với.
Bạn có thể cho ct vào file thực tế giúp mình với.
Xin chân thành cảm ơn.

 

[ndu96081631]

ndu96081631 Ơi mình thử dùng CT của bạn nhưng vẫn báo lỗi. (N) là gì trong công thức vậy bạn chỉ cho mình với.
Bạn có thể cho ct vào file thực tế giúp mình với.
Xin chân thành cảm ơn.

Xem file đính kèm và F1

 

[salam]

Ok rồi mình xin lỗi chưa kiểm tra hết ct chạy đúng rồi. còn N là gì bạn nhỉ.

 

[vumian]

N() là hàm của Excel mà,

Nếu kết hợp N() với SUM(), và ctrl Alt Enter ==> nó giống như {=SUM(if(...,1,))} vậy đó

 

[boyxin]

Cách 1: Dùng SUM

{=SUM(N(INDIRECT("'"&ROW(INDIRECT("1:"&$A$2))&"'!"&ADDRESS(ROW(),COLUMN()))))}

Cách 2: Dùng SUMPRODUCT

=SUMPRODUCT(N(INDIRECT("'"&ROW(INDIRECT("1:"&$A$2))&"'!"&ADDRESS(ROW(),COLUMN()))))

Thật tuyệt vời khi các sheet cần tính có tên là những con số liên tiếp (không cần sắp xếp theo thứ tự - vẫn cho kết quả đúng) và phải tính từ sheet 1 đến ...

Từ cách làm của ndu96081631 tôi sửa chút xíu để linh hoạt hơn

1. chọn tính tổng từ sheet ... đến sheet ... khi các sheet được đặt tên là những số liên tiếp
2. Khi thêm sheet mới thì tên sheet tự động cập nhật trong Use drop-down List

Nếu có thể: ndu96081631 cùng các bạn hãy nghiên cứu tiếp để:
Cho phép tính từ sheet ... đến sheet ... trong trường hợp tên các sheet là những chữ cái liên tiếp (theo A B C) nha (đang mày mò, vẫn chưa xong)

 

[ndu96081631]

Thật tuyệt vời khi các sheet cần tính có tên là những con số liên tiếp (không cần sắp xếp theo thứ tự - vẫn cho kết quả đúng) và phải tính từ sheet 1 đến ...

Nếu có thể: ndu96081631 cùng các bạn hãy nghiên cứu tiếp để:
Cho phép tính từ sheet ... đến sheet ... trong trường hợp tên các sheet là những chữ cái liên tiếp (theo A B C) nha (đang mày mò, vẫn chưa xong)

Bạn tạo ra 1 list tên tất cả các sheet thì có thể làm được điều này mà
Công thức tổng quát của nó là:

=SUMPRODUCT(N(INDIRECT("'"&Rng&"'!"&Địa chỉ cell)))

Trong đó Rng là vùng chứa tên sheet. Như vậy đâu cần tên sheet là số liên tiếp hay chử cái liên tiếp !!!
Tiếp theo nếu muốn kết hợp Validation để chọn From... To... thì đặt name với Offset để lấy Rng chính xác.
File đính kèm luôn đây!

 

[ngoducthang]

các bạn giúp tôibài excel này nhé (tính tổng nhiều sheet với nhiều điều kiện)

cụ thể là tôi đang phải tính tổng các giá trị tại tất cả các sheet, các giá trị chỉ được tính vào tổng khi thỏa mãn một số điều kiện.
cụ thể tôi đã upload file excel lên, mọi người cùng giúp nhé.
thank

 

[tueyennhi]

Bạn tạo ra 1 list tên tất cả các sheet thì có thể làm được điều này mà
Công thức tổng quát của nó là:

=SUMPRODUCT(N(INDIRECT("'"&Rng&"'!"&Địa chỉ cell)))

Trong đó Rng là vùng chứa tên sheet. Như vậy đâu cần tên sheet là số liên tiếp hay chử cái liên tiếp !!!
Tiếp theo nếu muốn kết hợp Validation để chọn From... To... thì đặt name với Offset để lấy Rng chính xác.
File đính kèm luôn đây!

Hay quá, cảm ơn thầy!

 

[phihndhsp]

các bạn giúp tôibài excel này nhé (tính tổng nhiều sheet với nhiều điều kiện)

cụ thể là tôi đang phải tính tổng các giá trị tại tất cả các sheet, các giá trị chỉ được tính vào tổng khi thỏa mãn một số điều kiện.
cụ thể tôi đã upload file excel lên, mọi người cùng giúp nhé.
thank

Với cách trình bày như thế này thì thua. có làm xong cũng sửa đi sửa lại hà