Các bác giúp em tính giờ làm việc với ah! (1 người xem)

[tth03]

Em có bảng tính nhu file đính kèm, mà em không biết cách nào để tính ra số giờ xe vào sửa chữa của em, (1 ngày làm việc chi 8 giờ và t7, cn, ngày lễ nghỉ ah). Làm sao tìm ra số giờ thực sự nằm trong gara của em ah. Các bác giúp em với, em cám ơn ah.

 

[Lê Hồng Minh83]

Em có bảng tính nhu file đính kèm, mà em không biết cách nào để tính ra số giờ xe vào sửa chữa của em, (1 ngày làm việc chi 8 giờ và t7, cn, ngày lễ nghỉ ah). Làm sao tìm ra số giờ thực sự nằm trong gara của em ah. Các bác giúp em với, em cám ơn ah.

Bạn cho biết ngày làm việc từ mấy giờ tới mấy giờ để tính số giờ lẻ ngày đầu và ngày cuối
Có tính số phút không hay chỉ cần tính tròn số giờ thôi?

 

[tth03]

Da. Số giờ làm việc từ 7h30 đến 11h30 và 13h30 -17h30. Không cần tính số phút anh, mình chỉ cần tính số giờ thôi ah.

 

[excel_lv1.5]

Em có bảng tính nhu file đính kèm, mà em không biết cách nào để tính ra số giờ xe vào sửa chữa của em, (1 ngày làm việc chi 8 giờ và t7, cn, ngày lễ nghỉ ah). Làm sao tìm ra số giờ thực sự nằm trong gara của em ah. Các bác giúp em với, em cám ơn ah.

Bạn dùng thử 1 trong 2 công thức này ở D5, cái nào sài được thì lấy:

D5=TEXT(SUM(({7.5,-17.5}/24-MOD(B5:C5,1)*{1,-1}+2/24-IFERROR(((2/24-IFERROR((({1,-1}*(MOD(B5:C5,1)-{11.5,13.5}/24))^0.5)^2,))^0.5)^2,))*(WEEKDAY(B5:C5,2)<6))+NETWORKDAYS.INTL(B5,C5,1)/3,"[h]:mm")

D5=TEXT(SUM(({7.5,-17.5}/24-MOD(B5:C5,1)*{1,-1}+2/24-IFERROR(((2/24-IFERROR((({1,-1}*(MOD(B5:C5,1)-{11.5,13.5}/24))^0.5)^2,))^0.5)^2,))*(WEEKDAY(B5:C5,2)<6))+SUM(N(WEEKDAY(ROW(INDIRECT(INT(B5)&":"&INT(C5))),2)<6))/3,"[h]:mm")

Cả 2 công thức đều phải bấm Ctrl+Shift+Enter!!
Lâu rồi không làm mấy bài thời gian, khó thật!!!

 

[Lê Hồng Minh83]

Da. Số giờ làm việc từ 7h30 đến 11h30 và 13h30 -17h30. Không cần tính số phút anh, mình chỉ cần tính số giờ thôi ah.

Nãy giờ hơi bận
Do bạn không yêu cầu tính chi tiết đến từng phút, nên mình làm công thức tính tương đối cho giờ ngày đầu và cuối (có loại giờ nghỉ trưa)
D5=NETWORKDAYS.INTL(B5+1,C5-1,1)*8+17-IF(HOUR(B5)<11,HOUR(B5)+2,HOUR(B5))+IF(HOUR(C5)>13,HOUR(C5)-2,HOUR(C5))-7

 

[excel_lv1.5]

Nãy giờ hơi bận
Do bạn không yêu cầu tính chi tiết đến từng phút, nên mình làm công thức tính tương đối cho giờ ngày đầu và cuối (có loại giờ nghỉ trưa)
D5=NETWORKDAYS.INTL(B5+1,C5-1,1)*8+17-IF(HOUR(B5)<11,HOUR(B5)+2,HOUR(B5))+IF(HOUR(C5)>13,HOUR(C5)-2,HOUR(C5))-7

Bạn chưa xét ngày đầu ngày cuối rơi vào T7, CN, thử từ ngày 8/7->14/7 xem!!!

 

[Lê Hồng Minh83]

Bạn chưa xét ngày đầu ngày cuối rơi vào T7, CN, thử từ ngày 8/7->14/7 xem!!!

Chủ thớt nói không làm ngày thứ 7, chủ nhật mà nên họ đâu có nhận "hàng" và trả "hàng" ngày đó đâu

 

[Phan Thế Hiệp]

Em có bảng tính nhu file đính kèm, mà em không biết cách nào để tính ra số giờ xe vào sửa chữa của em, (1 ngày làm việc chi 8 giờ và t7, cn, ngày lễ nghỉ ah). Làm sao tìm ra số giờ thực sự nằm trong gara của em ah. Các bác giúp em với, em cám ơn ah.

Góp thêm 2 cách:
1. Công thức thường:

=NETWORKDAYS(B5,C5)*8-((MEDIAN(IF(MOD(B5,1)*24<=11.5,{7.5,11.5},{13.5,17.5}),MOD(B5,1)*24)-IF(MOD(B5,1)*24<=11.5,7.5,9.5))*(WEEKDAY(B5,2)<6)+(IF(MOD(C5,1)*24<=11.5,15.5,17.5)-MEDIAN(IF(MOD(C5,1)*24<=11.5,{7.5,11.5},{13.5,17.5}),MOD(C5,1)*24))*(WEEKDAY(C5,2)<6))

Chỉ Enter.​

2. Công thức Mảng:

=NETWORKDAYS($B5,$C5)*8-SUM(CHOOSE(MATCH(MOD($B5:$C5,1)*24,{0,7.5,11.5,13.5,17.5},1),{0,8},ROUND(MOD($B5:$C5,1),4)*24*{1,-1}+{-7.5,15.5},{4,4},ROUND(MOD($B5:$C5,1),4)*24*{1,-1}+{-9.5,17.5},{8,0})*(WEEKDAY(B5:C5*1,2)<6))

Kết thúc bằng Ctrl+Shift+Enter.​

Xem file kèm.
Thân.

 

[excel_lv1.5]

Chủ thớt nói không làm ngày thứ 7, chủ nhật mà nên họ đâu có nhận "hàng" và trả "hàng" ngày đó đâu

Tính thời gian xe sữa chữa

Chủ thớt nói không làm ngày thứ 7, chủ nhật mà nên họ đâu có nhận "hàng" và trả "hàng" ngày đó đâu

Tùy theo cách nghĩ thôi, T7,CN không làm người ta vẫn có thể nhận xe. Công thức của bạn một số trường hợp vẫn chưa đúng như:
3/7/2018 8:50:00 AM->13/7/2018 8:05:00 AM nếu tính ra giờ là 63h.

 

[Lê Hồng Minh83]

Góp thêm 2 cách:
1. Công thức thường:

=NETWORKDAYS(B5,C5)*8-((MEDIAN(IF(MOD(B5,1)*24<=11.5,{7.5,11.5},{13.5,17.5}),MOD(B5,1)*24)-IF(MOD(B5,1)*24<=11.5,7.5,9.5))*(WEEKDAY(B5,2)<6)+(IF(MOD(C5,1)*24<=11.5,15.5,17.5)-MEDIAN(IF(MOD(C5,1)*24<=11.5,{7.5,11.5},{13.5,17.5}),MOD(C5,1)*24))*(WEEKDAY(C5,2)<6))

Chỉ Enter.​

2. Công thức Mảng:

=NETWORKDAYS($B5,$C5)*8-SUM(CHOOSE(MATCH(MOD($B5:$C5,1)*24,{0,7.5,11.5,13.5,17.5},1),{0,8},ROUND(MOD($B5:$C5,1),4)*24*{1,-1}+{-7.5,16.5},{4,4},ROUND(MOD($B5:$C5,1),4)*24*{1,-1}+{-9.5,17.5},{8,0})*(WEEKDAY(B5:C5*1,2)<6))

Kết thúc bằng Ctrl+Shift+Enter.​

Xem file kèm.
Thân.

Mấy bác khoái công thức dài dài ghê ta, kaka

 

[excel_lv1.5]

---Sory, bạn không quy ra hh:mm

 

[Phan Thế Hiệp]

Mấy bác khoái công thức dài dài ghê ta, kaka

Vì tính đúng và đủ mới dài.
Ví dụ: B5=Thứ sáu 29/06/2018 02:54:00 PM; C5=Thứ sáu 13/07/2018 01:55:00 PM bạn xem sẽ thấy khác.

3/7/2018 8:50:00 AM->13/7/2018 8:05:00 AM , mốc này hình như ra là 63:15 , kết quả của bạn là 63:25.

Một cái theo dạng giờ ":", một cái theo thập phân.
Tuy nhiên, trong công thức Mảng có nhầm một chỗ đã chỉnh lại, cảm ơn em.
Thân.

 

[tth03]

Em cám ơn các bác rất nhiều, sáng ngồi nghĩ mãi không ra được cách quy định thời gian. Em hứa sẽ cố gắng thềm bài khó hơn để các bác trổ tài. Em cám ơn các bác

Bài đã được tự động gộp: 13/7/18

Cho em hỏi thêm nếu đề bài thêm vào nghỉ ngày lễ thì mình thêm câu lệnh nào ah.

 

[Phan Thế Hiệp]

Em cám ơn các bác rất nhiều, sáng ngồi nghĩ mãi không ra được cách quy định thời gian.
Cho em hỏi thêm nếu đề bài thêm vào nghỉ ngày lễ thì mình thêm câu lệnh nào ah.

Nếu bạn dùng công thức của tôi thì chỉ cần thay đổi hàm:
NETWORKDAYS(B5,C5)*8
Thành:
NETWORKDAYS(B5,C5,$A$5:$A$20)*8
Hoặc:
NETWORKDAYS.INTL(B5,C5,1,$A$5:$A$20)*8
Với A5:A20 là để bạn nhập vào các ngày nghỉ lễ trong năm.

Tôi nghĩ, các công thức của các bạn còn lại cũng tương tự vậy, bạn thấy chỗ nào có dùng hàm NETWORKDAYS thì thay thế y vậy.

Em hứa sẽ cố gắng thềm bài khó hơn để các bác trổ tài.

Trên diễn đàn này, anh em GPE giúp bạn khi bạn gặp khó, chứ không là sàn diễn bạn nha!

Thân.

 

[tth03]

Vâng. Em cám ơn các bác rất nhiều!