CÁCH ĐỐI CHIẾU DỮ LIỆU GIỮA HAI BẢNG NGANG VÀ DỌC

[namlv1]

Chào Anh/chị,
Hiện tại em có hai bảng như dưới đây:
Bảng 1:

ID	Môn	Điểm
1​	A	8​
2​	B	7​
3​	C	5​
1​	B	9​
2​	C	7​
3​	A	9​

Bảng 2;

ID	Môn A	Môn B	Môn C
1​
2​
3​

Nhiệm vụ của em là dựa vào điểm của bảng 1 - điền kết quả điểm tương ứng vào bảng 2 (2 điều kiện: ID và Môn học) ạ
Rất mong anh/chị giúp em, cám ơn anh/chị!

 

[saobekhonglac]

Chào Anh/chị,
Hiện tại em có hai bảng như dưới đây:
Bảng 1:

ID	Môn	Điểm
1​	A	8​
2​	B	7​
3​	C	5​
1​	B	9​
2​	C	7​
3​	A	9​

Bảng 2;

ID	Môn A	Môn B	Môn C
1​
2​
3​

Nhiệm vụ của em là dựa vào điểm của bảng 1 - điền kết quả điểm tương ứng vào bảng 2 (2 điều kiện: ID và Môn học) ạ

Rất mong anh/chị giúp em, cám ơn anh/chị!

Xem đúng ý chưa bạn.

 

[namlv1]

Xem đúng ý chưa bạn.

Thanks bác, trường hợp này có thể sử dụng vlookup hay hàm kết hợp giữa index và match không ạ

 

[saobekhonglac]

Cảm ơn bác, trường hợp này có thể sử dụng vlookup hay hàm kết hợp giữa index và match không ạ

Kết thúc bằng Ctrl+Shift+Enter

G2=IFERROR(INDEX($C$2:$C$7,MATCH($F2&RIGHT(G$1,1),$A$2:$A$7&$B$2:$B$7,0),),"")

G2=IFERROR(OFFSET($C$1,MATCH($F2&RIGHT(G$1,1),$A$2:$A$7&$B$2:$B$7,0),),"")

G2=IFERROR(INDIRECT("C"&MATCH($F2&RIGHT(G$1,1),$A$2:$A$7&$B$2:$B$7,0)+1),"")

 

[thinhnx22]

Cảm ơn bác, trường hợp này có thể sử dụng vlookup hay hàm kết hợp giữa index và match không ạ

=IFERROR(INDEX($C$2:$C$7,MATCH(1,INDEX(($F2=$A$2:$A$7)*(RIGHT(G$1)=$B$2:$B$7),),0)),0)

Bạn xem thử nhé

 

[Phan Thế Hiệp]

Cảm ơn bác, trường hợp này có thể sử dụng vlookup hay hàm kết hợp giữa index và match không ạ

Tham khảo thêm:

G2=SUMIFS($C$2:$C$7,$A$2:$A$7,$F2,$B$2:$B$7,RIGHT(G$1))

Thân

 

[namlv1]

Kết thúc bằng Ctrl+Shift+Enter

G2=IFERROR(INDEX($C$2:$C$7,MATCH($F2&RIGHT(G$1,1),$A$2:$A$7&$B$2:$B$7,0),),"")

G2=IFERROR(OFFSET($C$1,MATCH($F2&RIGHT(G$1,1),$A$2:$A$7&$B$2:$B$7,0),),"")

G2=IFERROR(INDIRECT("C"&MATCH($F2&RIGHT(G$1,1),$A$2:$A$7&$B$2:$B$7,0)+1),"")

Cám ơn bác rất nhiều

Bài đã được tự động gộp: 23/4/19

Cám ơn các bác rất nhiều!

 

[hocexcel_1991]

Cảm ơn bác, trường hợp này có thể sử dụng vlookup

Thêm cái cho đủ bộ

=IFERROR(VLOOKUP($F2&G$1,CHOOSE({1,2},$A$2:$A$7&"Môn "&$B$2:$B$7,$C$2:$C$7),2,),"")
nhấn CSE