Bỏ số 0 đầu chuỗi có chứa ký tự chữ (1 người xem)

[Kim Huệ 91]

Các anh chị cho em hỏi với ạ!
Em có 1 cột chứa các phiếu xuất dưới dạng: 0164V, 0012A, 00015B, 000016C, 00102A, 15P, 1258F.... em cần bỏ các số 0 đầu chuỗi đi nhưng không có phương pháp nào có hiệu quả, anh/chị nào biết chỉ giúp em với ạ. Em cảm ơn !

 

[Cu Tồ]

.

 

[Binbo2020]

Các anh chị cho em hỏi với ạ!
Em có 1 cột chứa các phiếu xuất dưới dạng: 0164V, 0012A, 00015B, 000016C, .... em cần bỏ các số 0 đầu chuỗi đi nhưng không có phương pháp nào có hiệu quả, anh/chị nào biết chỉ giúp em với ạ. Em cảm ơn !

=SUBSTITUTE(ô dữ liệu;"0";"") hoặc nếu không bấm Ctrl+F trên là 0 dưới là trắng

 

[Cu Tồ]

=SUBSTITUTE(ô dữ liệu;"0";"") hoặc nếu không bấm Ctrl+F trên là 0 dưới là trắng
View attachment 249852

định dùng hàm này nhưng nếu mã ở sau có 0 thì sẽ xóa luôn số không ở sau bạn.chắc phải thêm hàm xác định 0 nữa

 

[Kim Huệ 91]

=SUBSTITUTE(ô dữ liệu;"0";"") hoặc nếu không bấm Ctrl+F trên là 0 dưới là trắng
View attachment 249852

Em làm theo công thức của chị được rồi ạ, em cảm ơn chị nhé ! Nhưng có 1 số PX như 00102A, thì nó lại thành 12A mà đúng ra thì phải là 102A, chị còn cách nào khác không ạ ?

Bài đã được tự động gộp: 23/11/20

định dùng hàm này nhưng nếu mã ở sau có 0 thì sẽ xóa luôn số không ở sau bạn.chắc phải thêm hàm xác định 0 nữa

ơ đúng rồi, em làm không để ý với những PX như 00102A, thì nó lại thành 12A

 

[CHAOQUAY]

Các anh chị cho em hỏi với ạ!
Em có 1 cột chứa các phiếu xuất dưới dạng: 0164V, 0012A, 00015B, 000016C, .... em cần bỏ các số 0 đầu chuỗi đi nhưng không có phương pháp nào có hiệu quả, anh/chị nào biết chỉ giúp em với ạ. Em cảm ơn !

Dùng hàm dưới đây vào 1 cột phụ, sau đó copy -> paste value về cột gốc

=RIGHT(A1,LEN(A1)-1)

 

[Binbo2020]

Em làm theo công thức của chị được rồi ạ, em cảm ơn chị nhé ! Nhưng có 1 số PX như 00102A, thì nó lại thành 12A mà đúng ra thì phải là 102A, chị còn cách nào khác không ạ ?

Bài đã được tự động gộp: 23/11/20

ơ đúng rồi, em làm không để ý với những PX như 00102A, thì nó lại thành 12A

Haiz lần sau hỏi gì thì ghi hết ra vì chỉ khác nhau một ký tự có khi công thức đã khác rồi =MID(C3;MIN(IF(ISERROR(FIND({1;2;3;4;5;6;7;8;9};C3));"";FIND({1;2;3;4;5;6;7;8;9};C3)));9999)

Bài đã được tự động gộp: 23/11/20

=RIGHT(A1,LEN(A1)-1)

Sao thế được công thức này bỏ mỗi ký tự đầu thôi mà có nhiều số 0 liền nhau ở đầu mà

 

[tigertiger]

Các anh chị cho em hỏi với ạ!
Em có 1 cột chứa các phiếu xuất dưới dạng: 0164V, 0012A, 00015B, 000016C, 00102A, 15P, 1258F.... em cần bỏ các số 0 đầu chuỗi đi nhưng không có phương pháp nào có hiệu quả, anh/chị nào biết chỉ giúp em với ạ. Em cảm ơn !

Thử công thức này vậy
=REPLACE(D6,1,MATCH(TRUE,INDEX(1*MID(D6,ROW($1:$20),1)<>0,0),0)-1,"")

 

[Kim Huệ 91]

Haiz lần sau hỏi gì thì ghi hết ra vì chỉ khác nhau một ký tự có khi công thức đã khác rồi =MID(C3;MIN(IF(ISERROR(FIND({1;2;3;4;5;6;7;8;9};C3));"";FIND({1;2;3;4;5;6;7;8;9};C3)));9999)

Bài đã được tự động gộp: 23/11/20

Sao thế được công thức này bỏ mỗi ký tự đầu thôi mà có nhiều số 0 liền nhau ở đầu mà

Em làm rồi những chỗ có PX như thế nó không ra được ạ

Bài đã được tự động gộp: 23/11/20

Thử công thức này vậy
=REPLACE(D6,1,MATCH(TRUE,INDEX(1*MID(D6,ROW($1:$20),1)<>0,0),0)-1,"")

Em có sửa sai chỗ nào không mà nó cũng không ra được ạ

 

[Binbo2020]

Em làm rồi những chỗ có PX như thế nó không ra được ạ

Bài đã được tự động gộp: 23/11/20

Em có sửa sai chỗ nào không mà nó cũng không ra được ạ

Lấy dữ liệu ở cột b chứ sao lại c

 

[tigertiger]

Em làm rồi những chỗ có PX như thế nó không ra được ạ
View attachment 249853

Bài đã được tự động gộp: 23/11/20

Em có sửa sai chỗ nào không mà nó cũng không ra được ạ
View attachment 249854

Không ra được là ra cái gì,
ô C10 là #Value thfi K10 phải là #Value thôi?
Bạn phải lấy công thức theo cột B?

 

[Kim Huệ 91]

Không ra được là ra cái gì,
ô C10 là #Value thfi K10 phải là #Value thôi?
Bạn phải lấ công thức theo cột B?

Vâng em xin lỗi em để lộn cột ạ, em cảm ơn anh/chị ạ !

 

[batman1]

Bạn không mô tả dạng dữ liệu, nhưng tôi thấy là luôn chỉ có 1 chữ cái ở cuối. Nếu đấy là qui luật thì

=--LEFT(A1,LEN(A1)-1) & RIGHT(A1,1)

 

[VetMini]

=RIGHT(A1,LEN(A1)-FIND(LEFT(SUBSTITUTE(A1&" ","0",""),1),A1&" ")+1)

Giải thích:
- hàm substitute bỏ hết TẤT CẢ các 0's
- như vậy, còn lại ký tự đầu tiên là một ký tự khác 0
- tìm ký tự ấy trong chuỗi ban đầu
- lấy kể từ vị trí ấy

 

[ndu96081631]

Các anh chị cho em hỏi với ạ!
Em có 1 cột chứa các phiếu xuất dưới dạng: 0164V, 0012A, 00015B, 000016C, 00102A, 15P, 1258F.... em cần bỏ các số 0 đầu chuỗi đi nhưng không có phương pháp nào có hiệu quả, anh/chị nào biết chỉ giúp em với ạ. Em cảm ơn !

- Biến số 0 thành dấu cách
- Dùng Trim để bỏ khoảng trắng thừa
- Cuối cùng biến dấu cách thành số 0

=SUBSTITUTE(TRIM(SUBSTITUTE(A1,0," "))," ",0)

 

[Phuocam]

Mã 001002A ???

 

[VetMini]

- Biến số 0 thành dấu cách
- Dùng Trim để bỏ khoảng trắng thừa
- Cuối cùng biến dấu cách thành số 0

=SUBSTITUTE(TRIM(SUBSTITUTE(A1,0," "))," ",0)

Hàm sai khi gặp chuỗi có mã dài hơn một số 0

 

[ndu96081631]

Hàm sai khi gặp chuỗi có mã dài hơn một số 0

View attachment 249860

Sai thì thử tiếp:

=SUBSTITUTE(REPLACE(SUBSTITUTE(A1,0," "),1,FIND(LEFT(TRIM(SUBSTITUTE(A1,0," ")),1),A1)-1,"")," ",0)

-----------------------------------
Làm xong mới thấy bài 14, thôi bỏ luôn cho rồi

 

[phuongvq123]

Không biết công thức này được không bạn

 

[VetMini]

Không biết công thức này được không bạn

Nếu số 0's dẫn đầu ÍT HƠN số 0's trong chuỗi thì hàm sai.

 

[phuongvq123]

Mình gửi bạn tham khảo

 

[batman1]

Nếu số 0's dẫn đầu ÍT HƠN số 0's trong chuỗi thì hàm sai.

Thậm chí với "số 0's dẫn đầu ÍT HƠN số 0's trong chuỗi" = FALSE thì vẫn sai.

Nếu sau một loạt 0 ở đầu là chữ số > 1 thì sai.

 

[excel_lv1.5]

Các anh chị cho em hỏi với ạ!
Em có 1 cột chứa các phiếu xuất dưới dạng: 0164V, 0012A, 00015B, 000016C, 00102A, 15P, 1258F.... em cần bỏ các số 0 đầu chuỗi đi nhưng không có phương pháp nào có hiệu quả, anh/chị nào biết chỉ giúp em với ạ. Em cảm ơn !

Góp thêm:

=MID(A2,1+SUM(COUNTIF(A2,REPT(0,ROW($1:$20))&"*")),100)

hoặc

=MID(A2,MATCH(0.5,--LEFT("0"&A2,ROW($1:$20))),100)

 

[VetMini]

Góp thêm:

=MID(A2,1+SUM(COUNTIF(A2,REPT(0,ROW($1:$20))&"*")),100)

hoặc

=MID(A2,MATCH(0.5,--LEFT("0"&A2,ROW($1:$20))),100)

Công thức 1: hình như chỉ xoá được số 0 đầu tiên.


Công thức 2: không dùng được trên máy tôi


Chú: bạn gói cái công thức trong mã code cho nên lúc tôi cóp lại vào bảng tính mình thì phải xoá cái mã code ấy. Cho nên có thể sai đâu đó.

 

[excel_lv1.5]

Công thức 1: hình như chỉ xoá được số 0 đầu tiên.
View attachment 249865

Công thức 2: không dùng được trên máy tôi
View attachment 249866

Chú: bạn gói cái công thức trong mã code cho nên lúc tôi cóp lại vào bảng tính mình thì phải xoá cái mã code ấy. Cho nên có thể sai đâu đó.

Ah, tôi sài 365 chắc mấy công thức đó bấm Ctrl+Shift+Enter đấy bạn

 

[Hoàng Tuấn 868]

=MID(A2,MIN(FIND(ROW(1:9),A2)),99)
Nhấn Ctrl+Shift+Enter

 

[VetMini]

Ah, tôi sài 365 chắc mấy công thức đó bấm Ctrl+Shift+Enter đấy bạn

Nếu vậy thì công thức đúng với dữ liệu thử của tôi.

 

[Lê Duy Thương]

Góp Thêm 1 cách

=MID(A1,MATCH(FALSE,--LEFT(A1,ROW($1:$99))=0,0),99)

 

[HieuCD]

Cách khác
=MID(A1,AGGREGATE(15,3,FIND(ROW($1:$9),A1),1),33)

 

[Binbo2020]

=MID(A2,MIN(FIND(ROW(1:9),A2)),99)
Nhấn Ctrl+Shift+Enter

Cái này không bẫy lỗi thì ra sao được nhỉ

Bài đã được tự động gộp: 24/11/20

=RIGHT(A1,LEN(A1)-FIND(LEFT(SUBSTITUTE(A1&" ","0",""),1),A1&" ")+1)

Giải thích:
- hàm substitute bỏ hết TẤT CẢ các 0's
- như vậy, còn lại ký tự đầu tiên là một ký tự khác 0
- tìm ký tự ấy trong chuỗi ban đầu
- lấy kể từ vị trí ấy

Cho mình hỏi công thức này sao lại phải nối thêm dấu cách nhỉ

 

[tigertiger]

=RIGHT(A1,LEN(A1)-FIND(LEFT(SUBSTITUTE(A1&" ","0",""),1),A1&" ")+1)
Cái này không bẫy lỗi thì ra sao được nhỉ

Bài đã được tự động gộp: 24/11/20

Cho mình hỏi công thức này sao lại phải nối thêm dấu cách nhỉ

Nhằm để tránh trường hợp A1 là toàn số 0, ví dụ "000" chẳng hạn (dự là vậy)

 

[VetMini]

Cho mình hỏi công thức này sao lại phải nối thêm dấu cách nhỉ

Trường hợp chỉ toàn số 0's
Chú ý là hàm trên tôi làm theo sát đúng diễn giải lô gic của vấn đề. Nếu sửa một chút, dùng hàm MID sẽ ngắn hơn RIGHT.

 

[Phuocam]

Dùng REPLACE không cần để ý đến độ dài của chuỗi, không dùng hàm len():

=REPLACE(A1,1,FIND(LEFT(SUBSTITUTE(A1&" ","0","")),A1&" ")-1,"")