Đếm số lượng theo từng TUẦN (2 người xem)

[ma_trix]

Mình giả sử có file bán hàng của các tháng,của từng nhân viên,của các ngày trong tháng luôn. Giờ mình muốn lấy tổng số lượng mặt hàng đã bán của nhân viên trong tuần 1, tuần 2,tuần 3, tuần 4...của tháng thì mình dùng hàm nào để tính,mới tập làm excel nên gà mờ quá,nếu bạn nào giúp làm macro luôn thì mình cám ơn nhiều
[WARNING1]
Lần sau phải ghi tiêu đề cho rõ ràng (lần đâu tiên bạn post bài nên tôi sửa lại tiêu đề cho bạn)
Cứ ghi tiêu đề chung chung, bị xóa bài ráng chịu nhé[/WARNING1]

 

[bebo021999]

Tại E2:
=(INT(DAY($D2)/7)=--RIGHT(E$1))*$B2
Copy sang phải và xuống dưới.

 

[ma_trix]

Tại E2:
=(INT(DAY($D2)/7)=--RIGHT(E$1))*$B2
Copy sang phải và xuống dưới.

Bạn giải thích giùm mình hàm đó được không? thanks

 

[Ba Tê]

Bạn giải thích giùm mình hàm đó được không? thanks

Hàm ra kết quả đúng thì xài, còn muốn hiểu các hàm thì vào đây nè:
http://www.giaiphapexcel.com/forum/showthread.php?7971-Tra-Cứu-Hàm-Excel&p=54708#post54708

 

[ma_trix]

MÌnh kiểm tra rồi,hàm cho kết quả không chính xác bạn ơi,những ngày đầu tháng thì không ra kết quả.

 

[ndu96081631]

MÌnh kiểm tra rồi,hàm cho kết quả không chính xác bạn ơi,những ngày đầu tháng thì không ra kết quả.

Nếu mà tôi làm bài này thì điều đầu tiên tôi phải hỏi lại bạn:
- Thế nào là 1 tuần? 7 ngày là 1 tuần chăng?
- Tuần của bạn bắt đầu từ ngày nào? Chủ nhật? Thứ hai... ?
- Nếu ngày đầu tháng là thứ 5 thì tuần 1 được tính gồm những ngày nào?
- Một tháng thường có hơn 4 tuần, vậy tuần 4 được tính gồm những ngày nào?
------------
Sau khi bạn trả lời những câu hỏi tôi đưa ở trên, chúng ta sẽ bàn tiếp
(nhiều người cứ hay nói đến khái niệm TUẦN mà chẳng định nghĩa được thế nào là TUẦN ---> Chán, hổng muốn làm)

 

[ma_trix]

Nếu mà tôi làm bài này thì điều đầu tiên tôi phải hỏi lại bạn:
- Thế nào là 1 tuần? 7 ngày là 1 tuần chăng?
- Tuần của bạn bắt đầu từ ngày nào? Chủ nhật? Thứ hai... ?
- Nếu ngày đầu tháng là thứ 5 thì tuần 1 được tính gồm những ngày nào?
- Một tháng thường có hơn 4 tuần, vậy tuần 4 được tính gồm những ngày nào?
------------
Sau khi bạn trả lời những câu hỏi tôi đưa ở trên, chúng ta sẽ bàn tiếp
(nhiều người cứ hay nói đến khái niệm TUẦN mà chẳng định nghĩa được thế nào là TUẦN ---> Chán, hổng muốn làm)

Mình xin trả lời bạn như sau:
- 1 tuần thì mính cứ tính là 7 ngày,
- Nếu ngày đầu tuần là thứ 5 thì mình cứ cộng tiếp cho đủ 7 ngày là 1 tuần.
- 1 tháng thì thường hơn 4 tuần thì tuần thứ 4 mình vẫn tính là 7 ngày, các ngày dư còn lại thì mình sẽ cho qua là tuần thứ 5.
Hiện tại mình đang làm file điều hành nhân viên bán hàng trong tháng,mỗi ngày nhân viên đó điều báo cáo về là hôm nay bán được gì, số lượng nhiêu nên mình muốn làm file để cuối tuần hay tháng có thể xem trong tuần 1,2,3,4.. nhân viên đó bán được bao nhiêu, có đủ số lượng mình yêu cầu ko. Nếu bạn làm đươc giúp mình thì mình cảm ơn nhiều.

 

[bebo021999]

Tại E2:
=(INT(DAY($D2)/7)=--RIGHT(E$1))*$B2
Copy sang phải và xuống dưới.

Bạn giải thích giùm mình hàm đó được không? thanks

MÌnh kiểm tra rồi,hàm cho kết quả không chính xác bạn ơi,những ngày đầu tháng thì không ra kết quả.

Vậy sửa một chút:
=(INT(DAY($D2)/7)+1=--RIGHT(E$1))*$B2
Hàm DAY sẽ trả về thứ tự ngày trong tháng: VD: DAY(08/03/2013) =8
Lấy kết quả đó chia cho 7, dùng hàm INT sẽ ra số nguyên. VD: INT(8/7)=1
Vậy: INT(DAY($D2)/7)+1: trong ví dụ trên sẽ trả về 1+1=2 chính là tuần của ngày mùng 8 trong tháng đó.
Đem so sánh với số thứ tự tuần tại E1 (Hàm RIGHT để lấy số tuần dạng text, thêm 2 dấu -- đằng trước để chuyển sang dạng number), nếu bằng thì trả về 1, không bằng trả về 0, sau đó nhân với số lượng tại B2.

 

[hoangtuaotrang_hp_vn]

Chào các anh chị

Em có bảng theo dõi sản lượng cho từng ngày.
Nhưng gặp khó khăn khi đặt công thức tự động cộng sản lượng tuần (cho các ngày trong cùng 1 tuần)

Nếu làm thủ công thì mất thời gian xác định những ngày nào thuộc tuần 1 rồi gõ hàm sum và kéo chuột, có cách nào để excel tự động xác định ngày nào thuộc tuần nào rồi tự cộng số liệu ko ạ? (khi sang tháng mới lại cũng phải tìm đâu là ngày thuộc tuần 1, tuần 2,...)

Mong anh/chị giúp đỡ

 

[nghiaphuc]

Chào các anh chị

Em có bảng theo dõi sản lượng cho từng ngày.
Nhưng gặp khó khăn khi đặt công thức tự động cộng sản lượng tuần (cho các ngày trong cùng 1 tuần)

Nếu làm thủ công thì mất thời gian xác định những ngày nào thuộc tuần 1 rồi gõ hàm sum và kéo chuột, có cách nào để excel tự động xác định ngày nào thuộc tuần nào rồi tự cộng số liệu ko ạ? (khi sang tháng mới lại cũng phải tìm đâu là ngày thuộc tuần 1, tuần 2,...)

Mong anh/chị giúp đỡ

Ở trường hợp 1, tôi nghĩ là toàn bộ dữ liệu chỉ ở trong cùng 1 tháng. Khi đó, bạn sử dụng công thức sau cho ô C6 rồi copy qua phải, xuống dưới:

=SUMPRODUCT((DAY($H$5:$AK$5)<=RIGHT(C$5)*7)*($H6:$AK6))-SUM($B6:B6)

Còn ở trường hợp 2, tôi nghĩ cần dùng hàm SUMPRODUCT và hàm WEEKNUM để tính nhưng mà hình như hàm WEEKNUM lại không làm việc với mảng nên chưa biết xử lý sao, nếu dùng hàng phụ để xử lý thì được nhưng mà cách này dở ẹc.

 

[hoangtuaotrang_hp_vn]

Em xin cảm ơn a đã giúp đưa ra giải pháp, tuy nhiên kết quả vẫn chưa đúng như mong đợi.



Có lẽ t.h2 mới có thể đưa ra giải pháp như mong đợi của em.

Mong các anh chị giúp đỡ thêm (nhất là câu hỏi của t.h 2 ạ)

 

[nghiaphuc]

Em xin cảm ơn a đã giúp đưa ra giải pháp, tuy nhiên kết quả vẫn chưa đúng như mong đợi.

View attachment 158229

Có lẽ t.h2 mới có thể đưa ra giải pháp như mong đợi của em.

Mong các anh chị giúp đỡ thêm (nhất là câu hỏi của t.h 2 ạ)

Vậy thì có lẽ phải dùng đến cách dở ẹc rồi: Dùng hàng phụ để xác định tuần (hàng 15) rồi dùng SUMIF để tính tổng. Bạn xem trong file nhé.

 

[lenongree]

Chào các anh chị

Em có bảng theo dõi sản lượng cho từng ngày.
Nhưng gặp khó khăn khi đặt công thức tự động cộng sản lượng tuần (cho các ngày trong cùng 1 tuần)

Nếu làm thủ công thì mất thời gian xác định những ngày nào thuộc tuần 1 rồi gõ hàm sum và kéo chuột, có cách nào để excel tự động xác định ngày nào thuộc tuần nào rồi tự cộng số liệu ko ạ? (khi sang tháng mới lại cũng phải tìm đâu là ngày thuộc tuần 1, tuần 2,...)

Mong anh/chị giúp đỡ

Công thức tại ô C6:

=SUM(($H$5:$AK$5<=SMALL(IF(WEEKDAY($H$5:$AK$5)=7,$H$5:$AK$5,""),RIGHT(C$5)))*$H6:$AK6)-SUM($B6:B6)

Ctrl+Shift+Enter rồi fill qua phải, fill xuống

Trường hợp 2, nếu dùng Weeknum thì dùng cột phụ bạn ơi!!!

 

[hoangtuaotrang_hp_vn]

@ anh lenongree

khi em đổi sang tháng 3, thì tuần 5 bị lỗi #NUM!



anh chỉ thêm cho em với

 

[lenongree]

@ anh lenongree

khi em đổi sang tháng 3, thì tuần 5 bị lỗi #NUM!
View attachment 158247

anh chỉ thêm cho em với

Uh, mình thấy rồi, bạn sửa lại CT dùm mình:

C6=IFERROR(SUM(($H$5:$AL$5<=SMALL(IF(WEEKDAY($H$5:$AL$5)=7,$H$5:$AL$5,""),RIGHT(C$5)))*$H6:$AL6),SUM($H6:$AL6))-SUM($B6:B6)

Ctrl+Shift+Enter rồi fill qua phải, fill xuống

 

[hoangtuaotrang_hp_vn]

@ anh lenongree

Khi em áp dụng thực tế thì bị phát sinh vấn đề ở tháng 6.

Mong anh và mọi người cùng giúp tháo gỡ ạ

 

[lenongree]

@ anh lenongree

Khi em áp dụng thực tế thì bị phát sinh vấn đề ở tháng 6.

Mong anh và mọi người cùng giúp tháo gỡ ạ

View attachment 158524

Bạn ơi, mình sài hàm weekday thì từ I5:AM5 bạn phải để kiểu ngày chứ 1/6/2016->30/6/2016 sao bạn lại để 1->30 vậy bạn, để vậy sao phân biệt được ngày nào là ngày chủ nhật!!!!

 

[HieuCD]

Nhập CT ô C6 và copy cho các ô còn lại
=SUM(OFFSET($I6,,,,(8-WEEKDAY($C$1))+7*(RIGHT(C$5,1)-1)))-SUM($B6:B6)