Đếm có điều kiện không trùng (1 người xem)

[keditimladieubong]

Xin chào cả nhà, em có vấn đề như sau.
em cần đếm có bao nhiêu xe ( không kể xe trùng của một đại lý trong bảng, em đã nêu vấn đề và kết quả mong muốn trong file đính kèm, mong mọi người giúp đỡ, cảm ơn mọi người !

đại lý	xe	Kết quả mong muốn
Đại Lý a	xe 1		Đại Lý a	2​
Đại Lý b	xe 2		Đại Lý b	3​
Đại Lý a	xe 1		Đại Lý c	1​
Đại Lý b	xe 1		Đại Lý d	1​
Đại Lý c	xe 2		Đại Lý g	1​
Đại Lý a	xe 3
Đại Lý g	xe 1
Đại Lý d	xe 2
Đại Lý b	xe 3
Đại Lý a	xe 1
Đại Lý g	xe 1

 

[Phuocam]

=SUMPRODUCt(($A$2:$A$12=D2)/COUNTIFS($A$2:$A$12,$A$2:$A$12,$B$2:$B$12,$B$2:$B$12))

 

[Phan Thế Hiệp]

em cần đếm có bao nhiêu xe ( không kể xe trùng của một đại lý trong bảng, em đã nêu vấn đề và kết quả mong muốn trong file đính kèm, mong mọi người giúp đỡ, cảm ơn mọi người !

Thêm 1 cách:

E2=COUNT(1/(MATCH($B$2:$B$100,IF($A$2:$A$100=D2,$B$2:$B$100),)=ROW($1:$100)))

Kết thúc bằng Ctrl+Shift+Enter.

Thân

 

[huonglien1901]

Thêm 1 cách:

E2=COUNT(1/(MATCH($B$2:$B$100,IF($A$2:$A$100=D2,$B$2:$B$100),)=ROW($1:$100)))

Kết thúc bằng Ctrl+Shift+Enter.

Thân

Bài này sử dụng pivot được không Anh?
Dọt lẹ....

 

[hocexcel_1991]

Bài này sử dụng pivot được không Anh?
Dọt lẹ....

Chắc là được

 

[dazkangel]

Không biết sao bạn biết mình luôn.

 

[keditimladieubong]

Không biết sao bạn biết mình luôn.

cảm ơn bạn nhiều

Bài đã được tự động gộp: 9/10/19

Thêm 1 cách:

E2=COUNT(1/(MATCH($B$2:$B$100,IF($A$2:$A$100=D2,$B$2:$B$100),)=ROW($1:$100)))

Kết thúc bằng Ctrl+Shift+Enter.

Thân

cảm ơn anh nhiều

Bài đã được tự động gộp: 9/10/19

=SUMPRODUCt(($A$2:$A$12=D2)/COUNTIFS($A$2:$A$12,$A$2:$A$12,$B$2:$B$12,$B$2:$B$12))

cảm ơn anh nhiều

 

[Trannhat301190]

=SUMPRODUCt(($A$2:$A$12=D2)/COUNTIFS($A$2:$A$12,$A$2:$A$12,$B$2:$B$12,$B$2:$B$12))

Cho mình hỏi trong trường hợp trong bảng này có ô trống, thì công thức sửa như nào bạn nhỉ

 

[Phuocam]

Cho mình hỏi trong trường hợp trong bảng này có ô trống, thì công thức sửa như nào bạn nhỉ

=SUMPRODUCt(($A$2:$A$12=D2)/COUNTIFS($A$2:$A$12,$A$2:$A$12&"",$B$2:$B$12,$B$2:$B$12&""))

 

[Trannhat301190]

=SUMPRODUCt(($A$2:$A$12=D2)/COUNTIFS($A$2:$A$12,$A$2:$A$12&"",$B$2:$B$12,$B$2:$B$12&""))

Mình thử công thức này thì công thức vẫn đếm ô trống, coi như vẫn là 1 giá trị bạn ạ. Làm sao để không đếm ô trống không bạn

 

[hoangtuaotrang_hp_vn]

Mình thử công thức này thì công thức vẫn đếm ô trống, coi như vẫn là 1 giá trị bạn ạ. Làm sao để không đếm ô trống không bạn

Vì ô đó không trống thực sự (nó vẫn mang 1 giá trị vô hình nào đó), chuột phải vào những ô trống đó, chọn clear content

 

[Trannhat301190]

Đã thử clear content nhưng vẫn chưa được (

 

[Phuocam]

Đã thử clear content nhưng vẫn chưa được

Nhớ kết thúc bằng Ctrl+Shift+Enter.

=SUM(IF(($A$2:$A$12=D2)*($B$2:$B$12<>""),1/COUNTIFS($A$2:$A$12,$A$2:$A$12&"",$B$2:$B$12,$B$2:$B$12&"")))

 

[hoangtuaotrang_hp_vn]

Đã thử clear content nhưng vẫn chưa được (
View attachment 226384

bạn thử công thức này xem sao:

=COUNT(MATCH(ROW($1:$10000),MATCH($B$2:$B$15,$B$2:$B$15,0)*(($B$2:$B$15)<>"")*($A$2:$A$15=D2),0))
kết thúc: CSE

 

[Phan Thế Hiệp]

Mình thử công thức này thì công thức vẫn đếm ô trống, coi như vẫn là 1 giá trị bạn ạ. Làm sao để không đếm ô trống không bạn

Công thức bài #3 thêm 1 tí xíu:
E2=COUNT(1/(MATCH($B$2:$B$100&"",IF($A$2:$A$100=D2,$B$2:$B$100),)=ROW($1:$100)))

Thân