Nhờ hỗ trợ về hàm liên quan đến ngày giờ cutofftime (8 người xem)

[Phuocam]

Công thức càng lúc càng dài:

=IF(DAY(C2)>24,WORKDAY(EOMONTH(C2,0),1)+8/24,
IF(OR(MOD(C2,1)>16/24,WEEKDAY(C2,2)>5),
IF(DAY(WORKDAY(C2,1))<25,WORKDAY(C2,1),WORKDAY(EOMONTH(C2,0),1))+8/24,
MAX(C2,INT(C2)+8/24)))

 

[huuthang_bd]

Công thức càng lúc càng dài:

=IF(DAY(C2)>24,WORKDAY(EOMONTH(C2,0),1)+8/24,
IF(OR(MOD(C2,1)>16/24,WEEKDAY(C2,2)>5),
IF(DAY(WORKDAY(C2,1))<25,WORKDAY(C2,1),WORKDAY(EOMONTH(C2,0),1))+8/24,
MAX(C2,INT(C2)+8/24)))

Ngắn hơn xíu (Công thức mảng)

=IF(OR(DAY(C2)>24,MOD(C2-1/3,1)>1/3,WEEKDAY(C2,2)>5),WORKDAY(C2-1/3,1,ROW(INDIRECT(EOMONTH(C2,-1)+25&":"&EOMONTH(C2,0))))+1/3,C2)

 

[Phan Thế Hiệp]

Ngắn hơn xíu (Công thức mảng)

=IF(OR(DAY(C2)>24,MOD(C2-1/3,1)>1/3,WEEKDAY(C2,2)>5),WORKDAY(C2-1/3,1,ROW(INDIRECT(EOMONTH(C2,-1)+25&":"&EOMONTH(C2,0))))+1/3,C2)

Công thức Mảng ngắn thêm xíu nữa:
(Excel >= 2010)

=MAX(AGGREGATE(15,6,WORKDAY(C2-1,ROW($1:$31))/(DAY(WORKDAY(C2-1,ROW($1:$31)))<25)/SIGN(ROW($1:$31)-(MOD(C2,1)>2/3)),1)+1/3,C2)

Chỉ Enter.
Hoặc cho Excel 97-2003:

=MAX(SMALL(IF((DAY(WORKDAY(C2-1,ROW($1:$31)))<25)*SIGN(ROW($1:$31)-(MOD(C2,1)>2/3)),WORKDAY(C2-1,ROW($1:$31))),1)+1/3,C2)

Kết thúc bằng Ctrl+Shift+Enter.

Thân

 

[huuthang_bd]

Công thức Mảng ngắn thêm xíu nữa:
(Excel >= 2010)

=MAX(AGGREGATE(15,6,WORKDAY(C2-1,ROW($1:$31))/(DAY(WORKDAY(C2-1,ROW($1:$31)))<25)/SIGN(ROW($1:$31)-(MOD(C2,1)>2/3)),1)+1/3,C2)

Chỉ Enter.

Xài đồ cổ nên không test được

Hoặc cho Excel 97-2003:

=MAX(SMALL(IF((DAY(WORKDAY(C2-1,ROW($1:$31)))<25)*SIGN(ROW($1:$31)-(MOD(C2,1)>2/3)),WORKDAY(C2-1,ROW($1:$31))),1)+1/3,C2)

Kết thúc bằng Ctrl+Shift+Enter.

Sau 16:00:00 thứ 7 và chủ nhật kết quả sẽ không đúng.

 

[Phan Thế Hiệp]

Xài đồ cổ nên không test được

Sau 16:00:00 thứ 7 và chủ nhật kết quả sẽ không đúng.

Đã kiểm tra, vẫn chính xác mờ!



Thân

 

[Phuocam]

Đã kiểm tra, vẫn chính xác mờ!

Thử với 16/3/2019 9:00:00 PM

 

[Phan Thế Hiệp]

Thử với 16/3/2019 9:00:00 PM

Chắt chiu, dồn nén, lấy chày nện... nện... nện... mới được vầy:

=MAX(MIN(IF((DAY(WORKDAY(C2,ROW($1:$7)-1))<25)*(ROW($1:$7)-OR(MOD(C2,1)>2/3,WEEKDAY(C2,2)>5)>0),WORKDAY(C2,ROW($1:$7)-1)))+1/3,C2)

Kết thúc bằng Ctrl+Shift+Enter.

Riêng, vầy thì chỉ cần Enter mà thôi:

=MAX(MIN(IF((DAY(WORKDAY(C2,{0;1;2;3;4;5;6}))<25)*({1;2;3;4;5;6;7}-OR(MOD(C2,1)>2/3,WEEKDAY(C2,2)>5)>0),WORKDAY(C2,{0;1;2;3;4;5;6})))+1/3,C2)

Chúc anh em ngày vui