Làm thế nào để tính được tổng trong tuần (1 người xem)

[ngatran08]

Chào anh chị em!
Em có file như đính kèm, giờ em muốn đặt công thức tính tổng giờ làm thêm như sau:
- Từ thứ 2 đến thứ 6 trong tháng vào 1 cột AX
- Thứ 7 & chủ nhật trong tháng vào cột AZ
- Trong tháng nếu có ngày lễ thì tổng sẽ vào cột BB
ACE giúp em với, em cảm ơn!

 

[Phan Thế Hiệp]

Chào anh chị em!
Em có file như đính kèm, giờ em muốn đặt công thức tính tổng giờ làm thêm như sau:
- Từ thứ 2 đến thứ 6 trong tháng vào 1 cột AX
- Thứ 7 & chủ nhật trong tháng vào cột AZ
- Trong tháng nếu có ngày lễ thì tổng sẽ vào cột BB
ACE giúp em với, em cảm ơn!

Tạo thêm sheet DSNgayLe (xem file kèm)
Thử:

AX9=SUMPRODUCT((WEEKDAY($F$6:$AJ$6,2)<6)*(1-COUNTIF(DSNgayLe!$A$2:$A$12,'T11'!$F$6:$AJ$6))*$F10:$AJ10)
AZ9=SUMPRODUCT((WEEKDAY($F$6:$AJ$6,2)>5)*(1-COUNTIF(DSNgayLe!$A$2:$A$12,'T11'!$F$6:$AJ$6))*$F10:$AJ10)
BB9=SUMPRODUCT(COUNTIF(DSNgayLe!$A$2:$A$12,'T11'!$F$6:$AJ$6)*$F10:$AJ10)

Enter, rồi copy cả hàng xuống.

Thân

 

[SA_DQ]

Xài macro đi bạn, tiện gọn hơn.

 

[Lê Hồng Minh83]

Chào anh chị em!
Em có file như đính kèm, giờ em muốn đặt công thức tính tổng giờ làm thêm như sau:
- Từ thứ 2 đến thứ 6 trong tháng vào 1 cột AX
- Thứ 7 & chủ nhật trong tháng vào cột AZ
- Trong tháng nếu có ngày lễ thì tổng sẽ vào cột BB
ACE giúp em với, em cảm ơn!

Tham khảo

AX=SUMPRODUCT($F10:$AJ10,--(TEXT($F$6:$AJ$6,"ddd")<>"Sun")*(TEXT($F$6:$AJ$6,"ddd")<>"Sat"),--($F$5:$AJ$5<>1))
AZ=SUMPRODUCT($F10:$AJ10,--(TEXT($F$6:$AJ$6,"ddd")="Sun")+(TEXT($F$6:$AJ$6,"ddd")="Sat"),--($F$5:$AJ$5<>1))
BB=SUMPRODUCT($F10:$AJ10,--($F$5:$AJ$5=1))

Bạn đánh số 1 tại dòng 5 nếu nó là ngày lễ

 

[ngatran08]

Tạo thêm sheet DSNgayLe (xem file kèm)
Thử:

AX9=SUMPRODUCT((WEEKDAY($F$6:$AJ$6,2)<6)*(1-COUNTIF(DSNgayLe!$A$2:$A$12,'T11'!$F$6:$AJ$6))*$F10:$AJ10)
AZ9=SUMPRODUCT((WEEKDAY($F$6:$AJ$6,2)>5)*(1-COUNTIF(DSNgayLe!$A$2:$A$12,'T11'!$F$6:$AJ$6))*$F10:$AJ10)
BB9=SUMPRODUCT(COUNTIF(DSNgayLe!$A$2:$A$12,'T11'!$F$6:$AJ$6)*$F10:$AJ10)

Enter, rồi copy cả hàng xuống.

Thân

Đúng công thức em cần, em cảm ơn anh. Sáng giờ em loay hoay mãi hàm sumifs mà không ra kết quả.

Bài đã được tự động gộp: 8/11/18

Xài macro đi bạn, tiện gọn hơn.

Dạ, em vẫn chưa biết dùng mấy cái đó ạ.