Đếm số trong 1 ô (1 người xem)

[vietcong1980]

Mình có 1 file theo mẫu như thế này, các bạn làm sao giúp mình đếm số vào cuối tháng với. Cuối tháng mình muốn đếm các ô từ F5 đến F9, có bao nhiêu số 4, số 5, số 6, số 7... Cám ơn các bạn

 

[HieuCD]

Mình có 1 file theo mẫu như thế này, các bạn làm sao giúp mình đếm số vào cuối tháng với. Cuối tháng mình muốn đếm các ô từ F5 đến F9, có bao nhiêu số 4, số 5, số 6, số 7... Cám ơn các bạn

Tùy bạn chọn 1 trong 2 công thức khác nhau tí xíu

E12 =COUNTIF($F$5:$F$9,"*"&C12&"*")
E12 =COUNTIF($F$5:$F$9,"*"&C12)+COUNTIF($F$5:$F$9,C12&"*")

 

[moctriet]

Rất tiếc công thức của bạn đếm không đúng cho trường hợp giá trị 5. Cái này dùng macro thì dễ, nhưng để viết công thức thì cần xử lý thêm chút ở lựa chọn 2

Tùy bạn chọn 1 trong 2 công thức khác nhau tí xíu

E12 =COUNTIF($F$5:$F$9,"*"&C12&"*")
E12 =COUNTIF($F$5:$F$9,"*"&C12)+COUNTIF($F$5:$F$9,C12&"*")

 

[HieuCD]

Rất tiếc công thức của bạn đếm không đúng cho trường hợp giá trị 5. Cái này dùng macro thì dễ, nhưng để viết công thức thì cần xử lý thêm chút ở lựa chọn 2

Bạn xem file, các giá trị cột F là chuổi

 

[bebanhbeo]

Rất tiếc công thức của bạn đếm không đúng cho trường hợp giá trị 5. Cái này dùng macro thì dễ, nhưng để viết công thức thì cần xử lý thêm chút ở lựa chọn 2

???

 

[Mộng Thường 2001]

Bạn xem file, các giá trị cột F là chuổi

hàm của anh gọn quá hén! cần gì phải viết mặt rô ta!!
hihi ^o^

 

[moctriet]

Dư liệu input
5,6
4,5, 4
5,7
5,6
4,7

Với công thức 1
Output
2
4
2
2
Sau cho đếm số 4

Với công thức 2
3
3
2
2

Sai cho đếm số 5

 

[bebo021999]

Dãy số có thể từ 1 tới 10, nên sẽ có trường hợp 1 và 10 sẽ đếm trùng số 1 (Xem sheet tháng 2 trở đi)
Do đó dùng cái này thì chính xác hơn:
Tại E12:

=(SUMPRODUCT(LEN(","&$F$5:$F$9&","))-SUMPRODUCT(LEN(SUBSTITUTE(","&$F$5:$F$9&",",","&C12&",",""))))/(LEN(C12)+2)

 

[Phan Thế Hiệp]

Mình có 1 file theo mẫu như thế này, các bạn làm sao giúp mình đếm số vào cuối tháng với. Cuối tháng mình muốn đếm các ô từ F5 đến F9, có bao nhiêu số 4, số 5, số 6, số 7... Cám ơn các bạn

E12=SUMPRODUCT(LEN($F$5:$F$9)-LEN(SUBSTITUTE($F$5:$F$9,C12,"")))

dán xuống dưới
Thân!

 

[moctriet]

Giải thuật cách của bạn Hiệp ở trên
Bước 1: Đếm số ký tự đã có trong cell bằng hàm LEN(Range)
Bước 2: Đếm số ký tự sau khi repalce Số cần đếm với hàm LEN(SUBSTITUTE(Range, Số cần đếm,""))
Bước 3: Sử dụng SUMPRODUCT để cộng các kết quả lại.

 

[HieuCD]

Chỉnh lại công thức loại bỏ trùng số 1 và 10

=COUNTIF($F$5:$F$9,"*"&C12&"*")-(C12=1)*COUNTIF($F$5:$F$9,"*10*")

Các số là lý do chưa đăng ký nên nhập trùng trong 1 ô không tính

 

[bebo021999]

Chỉnh lại công thức loại bỏ trùng số 1 và 10

=COUNTIF($F$5:$F$9,"*"&C12&"*")-(C12=1)*COUNTIF($F$5:$F$9,"*10*")

Các số là lý do chưa đăng ký nên nhập trùng trong 1 ô không tính

Lỡ dãy số thế này : 10,1,4,5
Tức là số 1 nằm giữa thì sao?

 

[excel_lv1.5]

Mình có 1 file theo mẫu như thế này, các bạn làm sao giúp mình đếm số vào cuối tháng với. Cuối tháng mình muốn đếm các ô từ F5 đến F9, có bao nhiêu số 4, số 5, số 6, số 7... Cám ơn các bạn

Cho bạn thêm một cách đưa vào mảng không cần ràng buộc:

=COUNT((1/(--MID(SUBSTITUTE($F$5:$F$9,",",REPT(" ",100)),(COLUMN($A$1:$Z$1)-1)*100+1,100)=C12)))

Yêu cầu bấm Ctrl+Shift+Enter rồi fill xuống!!!

 

[Phan Thế Hiệp]

Lỡ dãy số thế này : 10,1,4,5
Tức là số 1 nằm giữa thì sao?

Chắc chỉnh vầy: công thức mảng Ctrl+Shift+Enter

E12=COUNT(1/(--MID(SUBSTITUTE($F$5:$F$9,",",REPT(" ",100)),(COLUMN($A:$J)-1)*100+1,100)=C12))

Thân!

 

[HieuCD]

Lỡ dãy số thế này : 10,1,4,5
Tức là số 1 nằm giữa thì sao?

Dùng công thức mảng

=SUMPRODUCT(IFERROR(--(FIND(","&C12&",",","&$F$5:$F$9&",")>0),0))

nhấn Ctrl+Shift+Enter

 

[vietcong1980]

Lỡ dãy số thế này : 10,1,4,5
Tức là số 1 nằm giữa thì sao?

Số của mình cũng có thể đúng vậy. Và con số trong ô là từ 1 đến 10, trật tự các con số cũng lung tung. Mình chưa thử hết công thức trong mọi trường hợp, nhưng thấy công thức của các bạn rất tốt. Mình hỏi thêm 1 điều nữa là công thức của bạn HieuCD mình làm ở excel để trong máy tính thì được, nhưng làm trong google bảng tính sao toàn báo lỗi sai cú pháp là sao? Mình cám ơn