Lỗi Input past end of file (4 người xem)

Liên hệ QC

Người dùng đang xem chủ đề này

Đang trực tuyến: 1 (Thành viên: 0, Khách: 1)
Quang_Hải

Quang_Hải

Thành viên gạo cội
Tham gia
21/2/09
Bài viết
6,073
Được thích
8,004
Nghề nghiệp
Làm đủ thứ
Các anh chị xem giúp tại sao code này bị lỗi Input past end of file
Một số folder thì lấy được file, 1 số folder thì bị lỗi dù trong folder có chứa file. +-+-+-+
Không biết có phải vì sai câu lệnh Scomm
PHP: 
Sub GetFiles()
Dim sComm As String, tmpFile, path, Res, i
With Application.FileDialog(msoFileDialogFolderPicker)
   If .Show Then
      path = .SelectedItems(1)
      If Right(path, 1) <> "\" Then path = path & "\"
      With CreateObject("Scripting.FileSystemObject")
         tmpFile = "D:\" & .GetTempName
         sComm = "DIR " & path & "/A-D/B/C/D/O/N/S > " & tmpFile
         CreateObject("Wscript.Shell").Run "cmd /c " & sComm, 0, True
         Res = Split(.OpenTextFile(tmpFile, 1).ReadAll, vbCrLf)
         Kill tmpFile
      End With
      MsgBox UBound(Res)
   End If
End With
End Sub
 
Lần chỉnh sửa cuối:
Sắp xếp theo thời gian sắp xếp theo bầu chọn
Alo Alo
Vừa phát hiện 1 điều vô cùng kỳ cục là lạ
Khi chọn bất kỳ 1 thư mục nào mà chính nó hoặc thư mục mẹ, hoặc thư mục ông bà của nó có chứa 1 khoảng trắng thì code không chạy
Ví dụ ta có C:\Program Files\A\B\C thì khi ta chỉ vào thư mục nào code cũng không chạy, trừ khi ta chỉ vào ổ đĩa C.
Anh chị nào có biết nguyên nhân và cách khắc phục không?
PHP: 
Sub GetFiles()
Dim sComm As String, tmpFile As String, path As String, Res
With Application.FileDialog(msoFileDialogFolderPicker)
   If .Show Then
      path = .SelectedItems(1)
      If Right(path, 1) <> "\" Then path = path & "\"
      With CreateObject("Scripting.FileSystemObject")
         tmpFile = "D:\tmp.txt"
         .CreateTextFile tmpFile, True, True
         sComm = "DIR " & path & "/A-D/B/C/D/O/N/S > " & tmpFile
         CreateObject("Wscript.Shell").Run "cmd /c " & sComm, 0, True
         Res = Split(.OpenTextFile(tmpFile, 1).ReadAll, vbCrLf)
         Kill tmpFile
      End With
      MsgBox UBound(Res)
   End If
End With
End Sub
 
Upvote 0
quanghai1969 đã viết:
Alo Alo
Vừa phát hiện 1 điều vô cùng kỳ cục là lạ
Khi chọn bất kỳ 1 thư mục nào mà chính nó hoặc thư mục mẹ, hoặc thư mục ông bà của nó có chứa 1 khoảng trắng thì code không chạy
Ví dụ ta có C:\Program Files\A\B\C thì khi ta chỉ vào thư mục nào code cũng không chạy, trừ khi ta chỉ vào ổ đĩa C.
Anh chị nào có biết nguyên nhân và cách khắc phục không?
PHP: 
Sub GetFiles()
Dim sComm As String, tmpFile As String, path As String, Res
With Application.FileDialog(msoFileDialogFolderPicker)
   If .Show Then
      path = .SelectedItems(1)
      If Right(path, 1) <> "\" Then path = path & "\"
      With CreateObject("Scripting.FileSystemObject")
         tmpFile = "D:\tmp.txt"
         .CreateTextFile tmpFile, True, True
         sComm = "DIR " & path & "/A-D/B/C/D/O/N/S > " & tmpFile
         CreateObject("Wscript.Shell").Run "cmd /c " & sComm, 0, True
         Res = Split(.OpenTextFile(tmpFile, 1).ReadAll, vbCrLf)
         Kill tmpFile
      End With
      MsgBox UBound(Res)
   End If
End With
End Sub
Nhấp chuột vào đây để mở rộng...

Cho đường dẫn vào cặp ngoặc ""
Tức
Mã: 
path = """" & .SelectedItems(1) & """"

Ở cửa sổ dòng lệnh (command line) tương tự. Ta không thể gõ:

Mã: 
dir C:\Program Files

mà phải gõ

Mã: 
dir "C:\Program Files"


--------------
Nếu vì một "cái gì đấy" mà tập tin tmpFile bị rỗng thì sẽ có lỗi như thế.

Tạo lỗi: phải chuột trên thư mục D:\ nà chọn New --> Text File --> đổi tên thành hichic.txt.
Rõ ràng tập tin hichic.txt rỗng. Bây giờ chạy code
Mã: 
Sub he()
Dim s As String
    s = CreateObject("Scripting.FileSystemObject").OpenTextFile("d:\hichic.txt", 1).ReadAll
End Sub

thì có lỗi "kia". Nhưng nếu hichic.txt có ít nhất 1 ký tự dấu cách chẳng hạn thì không còn lỗi.

Khi nào có lỗi tmpFile rỗng. Tôi không biết có tất cả những trường hợp nào nhưng chắc chắn tôi tin có 1 trường hợp. Vd. thư mục xyz có 1000 thư mục con và 1000 tập tin, và không thể truy cập xyz (access denied) - trên XP của tôi thì click "System Volume Information" = access denied. Nếu bạn chọn thư mục xyz thì tmpFile rỗng.
 
Lần chỉnh sửa cuối:
Upvote 0
quanghai1969 đã viết:
Alo Alo
Vừa phát hiện 1 điều vô cùng kỳ cục là lạ
Khi chọn bất kỳ 1 thư mục nào mà chính nó hoặc thư mục mẹ, hoặc thư mục ông bà của nó có chứa 1 khoảng trắng thì code không chạy
Nhấp chuột vào đây để mở rộng...

Thế sao không xem lại hàm người ta viết từ trước để nghiên cứu:
Mã: 
Function FilesFoldersList(ByVal RootFolder As String, ByVal ListType As Boolean, _
                          ByVal Search As String, ByVal InSub As Boolean)
  'ListType = True: Get Files list
  'ListType = False: Get Folders list
  Dim sComm As String, tmp As String, str As String, tmpFile, Arr
  On Error Resume Next
  If Right(RootFolder, 1) <> "\" Then RootFolder = RootFolder & "\"
  [COLOR=#ff0000]str = """" & RootFolder & Search & """"[/COLOR]
  
  With CreateObject("Scripting.FileSystemObject")
    tmpFile = .GetTempName
    sComm = "DIR " & str & " /ON /B /A" & IIf(ListType, "-", "") & "D-S" & IIf(InSub, "/S", " ") & " >" & tmpFile
    CreateObject("Wscript.Shell").Run "cmd /u /c " & sComm, 0, True
    With .OpenTextFile(tmpFile, 1, , -2)
      tmp = Trim(.ReadAll)
      If Right(tmp, 2) = vbCrLf Then tmp = Left(tmp, Len(tmp) - 2)
      If Len(tmp) Then
        If InSub = False Then tmp = RootFolder & Replace(tmp, vbCrLf, vbCrLf & RootFolder)
        FilesFoldersList = Split(tmp, vbCrLf)
      End If
      .Close
    End With
  End With
  Kill tmpFile
End Function
 
Upvote 0
ndu96081631 đã viết:
Thế sao không xem lại hàm người ta viết từ trước để nghiên cứu:
Nhấp chuột vào đây để mở rộng...
Nói thiệt cho anh biết là từ trước tới giờ xài ké hàm này của anh, nhưng có hiểu gì đâu mà nghiên mà cứu. Nay em liều mạng mổ nó ra thì mới té ra nhiều cái cần học. Trước giờ thấy mấy cặp nháy đó đôi lúc cũng thắc mắc nhưng chưa đủ kiến thức thì có hỏi cũng phí. Giờ thì hơi thấm chút ít rồi.

siwtom đã viết:
Cho đường dẫn vào cặp ngoặc ""
Tức
Mã: 
path = """" & .SelectedItems(1) & """"
Ở cửa sổ dòng lệnh (command line) tương tự. Ta không thể gõ:
Mã: 
dir C:\Program Files
mà phải gõ
Mã: 
dir "C:\Program Files"
--------------
Nếu vì một "cái gì đấy" mà tập tin tmpFile bị rỗng thì sẽ có lỗi như thế.
Tạo lỗi: phải chuột trên thư mục D:\ nà chọn New --> Text File --> đổi tên thành hichic.txt.
Rõ ràng tập tin hichic.txt rỗng. Bây giờ chạy code
Mã: 
Sub he()
Dim s As String
    s = CreateObject("Scripting.FileSystemObject").OpenTextFile("d:\hichic.txt", 1).ReadAll
End Sub
thì có lỗi "kia". Nhưng nếu hichic.txt có ít nhất 1 ký tự dấu cách chẳng hạn thì không còn lỗi.
Khi nào có lỗi tmpFile rỗng. Tôi không biết có tất cả những trường hợp nào nhưng chắc chắn tôi tin có 1 trường hợp. Vd. thư mục xyz có 1000 thư mục con và 1000 tập tin, và không thể truy cập xyz (access denied) - trên XP của tôi thì click "System Volume Information" = access denied. Nếu bạn chọn thư mục xyz thì tmpFile rỗng.
Nhấp chuột vào đây để mở rộng...

Bài giải của anh làm cho em sáng ra được chút nữa.

................................

Còn 2 vấn đề liên quan, mong các anh giải thích giúp:

1. Không thể lấy được tiếng việt có dấu, trong khi dùng FSO thì có dấu tiếng việt
2. Mình có thể nào chỉ định đuôi file hay không? Chẳng hạn như (*.xls* và *.doc*). Ý em là cùng 1 lúc mình yêu cầu tới 2 định dạng. Hiện tại em phải dùng vòng lặp để chạy riêng từng định dạng
 
Lần chỉnh sửa cuối:
Upvote 0
quanghai1969 đã viết:
Nói thiệt cho anh biết là từ trước tới giờ xài ké hàm này của anh, nhưng có hiểu gì đâu mà nghiên mà cứu. Nay em liều mạng mổ nó ra thì mới té ra nhiều cái cần học. Trước giờ thấy mấy cặp nháy đó đôi lúc cũng thắc mắc nhưng chưa đủ kiến thức thì có hỏi cũng phí. Giờ thì hơi thấm chút ít rồi.



Bài giải của anh làm cho em sáng ra được chút nữa.

................................

Còn 2 vấn đề liên quan, mong các anh giải thích giúp:

1. Không thể lấy được tiếng việt có dấu, trong khi dùng FSO thì có dấu tiếng việt
2. Mình có thể nào chỉ định đuôi file hay không? Chẳng hạn như (*.xls* và *.doc*). Ý em là cùng 1 lúc mình yêu cầu tới 2 định dạng. Hiện tại em phải dùng vòng lặp để chạy riêng từng định dạng
Nhấp chuột vào đây để mở rộng...

Đơn giản là do ở dòng lệnh không thể dùng được đường dẫn có dấu cách. Vì thế ở dòng lệnh phải cho đường dẫn vào cặp ngoặc "". Code của bạn kích hoạt dòng lệnh nên đương nhiên phải thêm cặp ngoặc "". Nguyên do của "" là thế.
Bạn luôn phải cho vào cặp ngoặc "" để lường được đường dẫn có dấu cách. Đường dẫn có dấu cách mà không có cặp ngoặc thì tèo trong khi đường dẫn không có dấu cách mà vẫn cho vào cặp ngoặc "" thì lại chả sao.
-----------------
Học trước quên sau, chán.

Tôi đã nói hơn 2 năm trước ở đây

http://www.giaiphapexcel.com/forum/...-1-folder-vào-Folder-khác&p=414950#post414950
 
Lần chỉnh sửa cuối:
Upvote 0
quanghai1969 đã viết:
1. Không thể lấy được tiếng việt có dấu, trong khi dùng FSO thì có dấu tiếng việt
Nhấp chuột vào đây để mở rộng...

Cũng hàm đó:
Mã: 
Function FilesFoldersList(ByVal RootFolder As String, ByVal ListType As Boolean, _
                          ByVal Search As String, ByVal InSub As Boolean)
  'ListType = True: Get Files list
  'ListType = False: Get Folders list
  Dim sComm As String, tmp As String, str As String, tmpFile, Arr
  On Error Resume Next
  If Right(RootFolder, 1) <> "\" Then RootFolder = RootFolder & "\"
  str = """" & RootFolder & Search & """"
  
  With CreateObject("Scripting.FileSystemObject")
    tmpFile = .GetTempName
    sComm = "DIR " & str & " /ON /B /A" & IIf(ListType, "-", "") & "D-S" & IIf(InSub, "/S", " ") & " >" & tmpFile
    CreateObject("Wscript.Shell").Run "cmd [B][COLOR=#ff0000]/u[/COLOR][/B] /c " & sComm, 0, True
    With .OpenTextFile(tmpFile, 1, , [B][COLOR=#ff0000]-2[/COLOR][/B])
      tmp = Trim(.ReadAll)
      If Right(tmp, 2) = vbCrLf Then tmp = Left(tmp, Len(tmp) - 2)
      If Len(tmp) Then
        If InSub = False Then tmp = RootFolder & Replace(tmp, vbCrLf, vbCrLf & RootFolder)
        FilesFoldersList = Split(tmp, vbCrLf)
      End If
      .Close
    End With
  End With
  Kill tmpFile
End Function
Chỗ màu đỏ để xử lý tiếng Việt Unicode
------------------------------------
quanghai1969 đã viết:
2. Mình có thể nào chỉ định đuôi file hay không? Chẳng hạn như (*.xls* và *.doc*). Ý em là cùng 1 lúc mình yêu cầu tới 2 định dạng. Hiện tại em phải dùng vòng lặp để chạy riêng từng định dạng
Nhấp chuột vào đây để mở rộng...
Thật ra DOS làm được. Xem câu lệnh này khi gõ trong lệnh DOS:
DIR D:\Excel\*.xls D:\Excel\*.doc /ON /B /A-D >C:\tmpFile.txt
Lấy 2 định dạng xls và doc ===> Tự suy luận nhé!
 
Upvote 0
siwtom đã viết:
Học trước quên sau, chán.

Tôi đã nói hơn 2 năm trước ở đây

http://www.giaiphapexcel.com/forum/...-1-folder-vào-Folder-khác&p=414950#post414950
Nhấp chuột vào đây để mở rộng...
Tội em quá mà. 2 năm trước em mới bập bẹ vba thì đọc có hiểu được tí nào đâu.

ndu96081631 đã viết:
Cũng hàm đó:
Thật ra DOS làm được. Xem câu lệnh này khi gõ trong lệnh DOS:
DIR D:\Excel\*.xls D:\Excel\*.doc /ON /B /A-D >C:\tmpFile.txt
Lấy 2 định dạng xls và doc ===> Tự suy luận nhé!
Nhấp chuột vào đây để mở rộng...
Chắc chắn là em sẽ suy luận được mà. Chỉ cần nhìn thấy là em bắt chước nhanh lắm.
 
Lần chỉnh sửa cuối:
Upvote 0
quanghai1969 đã viết:
Tội em quá mà. 2 năm trước em mới bập bẹ vba thì đọc có hiểu được tí nào đâu.
Nhấp chuột vào đây để mở rộng...

Êêê, vụng chèo khéo chống. Code có thể không hiểu nhưng tôi viết rõ mồn một
Ta chỉ cần trang điểm chút chút cho nó lộng lẫy hơn, tức hỗ trợ tiếng Việt. Ai thích tên thư mục, tên tập tin bằng tiếng Việt xin cứ mạnh dạn

...
"cmd /U
Nhấp chuột vào đây để mở rộng...

Chỗ /U có tô đỏ đàng hoàng




 
Lần chỉnh sửa cuối:
Upvote 0
Mình kết hợp võ công thâm hậu của Triển Chiêu và Bạch Ngọc Đường lại và cho ra 1 chiêu thức tạm gọi tên là Loạn Cào Cào. Coi như cũng là 1 thành quả.
PHP: 
Function GetAllFile(ByVal StrFolder As String, insub As Boolean)
On Error Resume Next
Dim sComm As String, tmpFile As String, Res
   With CreateObject("Scripting.FileSystemObject")
      tmpFile = "D:\" & .GetTempName
      sComm = "DIR " & StrFolder & " /B/O " _
      & IIf(insub, "/S", vbNullString) & " > " & tmpFile
      CreateObject("Wscript.Shell").Run "cmd /u/c " & sComm, 0, 1
      GetAllFile = Split(.OpenTextFile(tmpFile, 1, , -1).ReadAll, vbCrLf)
      Kill tmpFile
   End With
End Function
Nếu như Insub= False sẽ trả về tên file không kèm đường dẫn nên tạm thời mình thêm cái vòng lặp For Next để xử lý.
Không biết là có cách nào hay hơn không, và cách mình chỉ định đuôi file cần tìm như thế này có hợp lý chưa?
Nếu có phương án khác, các anh vui lòng góp ý giúp.
PHP: 
Sub Main()
On Error Resume Next
Dim i As Long, path As String, Sarr, Res(), insub As Boolean, tam As String
insub = 1
With Application.FileDialog(msoFileDialogFolderPicker)
   If .Show Then
      path = .SelectedItems(1)
      If Right(path, 1) <> "\" Then path = path & "\"
      tam = path
      path = """" & path & """"
      path = path & "*.xls " & path & "*.doc " & path & "*.pdf "
      Sarr = GetAllFile(path, insub)
      ReDim Res(1 To UBound(Sarr), 1 To 1)
      For i = LBound(Sarr) To UBound(Sarr) - 1
         If Not insub Then
            Res(i + 1, 1) = tam & Sarr(i)
         Else
            Res(i + 1, 1) = Sarr(i)
         End If
      Next
      [A1].Resize(i) = Res
   End If
End With
End Sub
 
Lần chỉnh sửa cuối:
Upvote 0
quanghai1969 đã viết:
Mình kết hợp võ công thâm hậu của Triển Chiêu và Bạch Ngọc Đường lại và cho ra 1 chiêu thức tạm gọi tên là Loạn Cào Cào. Coi như cũng là 1 thành quả.
PHP: 
Function GetAllFile(ByVal StrFolder As String, insub As Boolean)
On Error Resume Next
Dim sComm As String, tmpFile As String, Res
   With CreateObject("Scripting.FileSystemObject")
      tmpFile = "D:\" & .GetTempName
      sComm = "DIR " & StrFolder & " /B/O " _
      & IIf(insub, "/S", vbNullString) & " > " & tmpFile
      CreateObject("Wscript.Shell").Run "cmd /u/c " & sComm, 0, 1
      GetAllFile = Split(.OpenTextFile(tmpFile, 1, , -1).ReadAll, vbCrLf)
      Kill tmpFile
   End With
End Function
Nếu như Insub= False sẽ trả về tên file không kèm đường dẫn nên tạm thời mình thêm cái vòng lặp For Next để xử lý.
Không biết là có cách nào hay hơn không, và cách mình chỉ định đuôi file cần tìm như thế này có hợp lý chưa?
Nếu có phương án khác, các anh vui lòng góp ý giúp.
PHP: 
Sub Main()
On Error Resume Next
Dim i As Long, path As String, Sarr, Res(), insub As Boolean, tam As String
insub = 1
With Application.FileDialog(msoFileDialogFolderPicker)
   If .Show Then
      path = .SelectedItems(1)
      If Right(path, 1) <> "\" Then path = path & "\"
      tam = path
      path = """" & path & """"
      path = path & "*.xls " & path & "*.doc " & path & "*.pdf "
      Sarr = GetAllFile(path, insub)
      ReDim Res(1 To UBound(Sarr), 1 To 1)
      For i = LBound(Sarr) To UBound(Sarr) - 1
         If Not insub Then
            Res(i + 1, 1) = tam & Sarr(i)
         Else
            Res(i + 1, 1) = Sarr(i)
         End If
      Next
      [A1].Resize(i) = Res
   End If
End With
End Sub
Nhấp chuột vào đây để mở rộng...
Em test thấy tốc độ cực nhanh và lấy được cả file tiếng việt có dấu và không dấu chơi được láng. ..
nhưng phát sinh một cái khi kích đúp chuột vào mở với File .doc hay pdf thì lỗi font...kiểu này phải viết thêm một sub Open with file nọ file kia nữa thì hoàn hảo đó anh
 
Upvote 0
kieu manh đã viết:
Em test thấy tốc độ cực nhanh và lấy được cả file tiếng việt có dấu và không dấu chơi được láng. ..
nhưng phát sinh một cái khi kích đúp chuột vào mở với File .doc hay pdf thì lỗi font...kiểu này phải viết thêm một sub Open with file nọ file kia nữa thì hoàn hảo đó anh
Nhấp chuột vào đây để mở rộng...
Đang trên nền excel mà mở thứ khác sao được. Phải mở bằng cách khác.
 
Upvote 0
quanghai1969 đã viết:
Nếu như Insub= False sẽ trả về tên file không kèm đường dẫn nên tạm thời mình thêm cái vòng lặp For Next để xử lý.
Nhấp chuột vào đây để mở rộng...

Code hoàn chỉnh ngay ở trên sao không chịu nhìn vậy trời:
Mã: 
Function FilesFoldersList(ByVal RootFolder As String, ByVal ListType As Boolean, _
                          ByVal Search As String, ByVal InSub As Boolean)
  'ListType = True: Get Files list
  'ListType = False: Get Folders list
  Dim sComm As String, tmp As String, str As String, tmpFile, Arr
  On Error Resume Next
  If Right(RootFolder, 1) <> "\" Then RootFolder = RootFolder & "\"
  str = """" & RootFolder & Search & """"
  
  With CreateObject("Scripting.FileSystemObject")
    tmpFile = .GetTempName
    sComm = "DIR " & str & " /ON /B /A" & IIf(ListType, "-", "") & "D-S" & IIf(InSub, "/S", " ") & " >" & tmpFile
    CreateObject("Wscript.Shell").Run "cmd /u /c " & sComm, 0, True
    With .OpenTextFile(tmpFile, 1, , -2)
      tmp = Trim(.ReadAll)
      If Right(tmp, 2) = vbCrLf Then tmp = Left(tmp, Len(tmp) - 2)
      If Len(tmp) Then
        [COLOR=#ff0000]If InSub = False Then tmp = RootFolder & Replace(tmp, vbCrLf, vbCrLf & RootFolder)[/COLOR]
        FilesFoldersList = Split(tmp, vbCrLf)
      End If
      .Close
    End With
  End With
  Kill tmpFile
End Function
Xử lý từ trong text, chẳng có vòng lập nào cả
 
Upvote 0
ndu96081631 đã viết:
Code hoàn chỉnh ngay ở trên sao không chịu nhìn vậy trời:

Xử lý từ trong text, chẳng có vòng lập nào cả
Nhấp chuột vào đây để mở rộng...
Đúng là học 1 tháng không bằng hành 1 ngày.
Nếu không cày và thắc mắc thì anh cũng đâu có nói cái dòng đó là nó đó.
 
Upvote 0
ndu96081631 đã viết:
Cái này tôi không hiểu! Kích đúp chuột vào đâu? Lỗi font nghĩa là sao?
Nhấp chuột vào đây để mở rộng...
Ah vụ này thì em hiểu, hơi cá nhân 1 chút. Vì KieuManh ở có nhắn tin hỏi về sự kiện DoubleClick vào tên file để mở file sau khi liệt kê ra sheet. Vụ này em sẽ xử lý riêng để khỏi ảnh hưởng topic
 
Upvote 0
Bạn phải đăng nhập hoặc đăng ký để trả lời bài viết tại đây.
Web KT

Bài viết mới nhất

L
  • Question Question
Giải thích các sự kiện Private Sub Workbook_SheetActivate và Private Sub Workbook_SheetDeactivate (4 người xem)
Trả lời
0
Đọc
14
LienDong
L
O
XIN ANH CHỊ GIÚP ĐỠ HƯỚNG DẪN CHUYỂN VĂN BẢN THÀNH GIỌNG NÓI TRONG EXCEL Ạ.
Trả lời
4
Đọc
84
Trần Văn Bình
T
L
  • Question Question
Code tự động đặt pass protect sheet "DIEM", khi chuyển qua sheet khác (3 người xem)
Trả lời
2
Đọc
36
LienDong
L
L
nhờ a/c chỉ giúp e dùng hàm gì để tính doanh thu từng mã hàng trong bảng tính một loạt mã hàng ạ (2 người xem)
Trả lời
4
Đọc
39
Duy Tùng 9x
Duy Tùng 9x
S
Chức năng refresh trong Pivot khi thêm bớt dòng (1 người xem)
Trả lời
13
Đọc
164
ptm0412
ptm0412
K
Xử lý (tắt) đường link địa chỉ ô trong excel khi đăng nhập tài khoản MS. (1 người xem)
Trả lời
0
Đọc
24
khoak47
K
Nguyễn Duy Tuân
Dùng AI trên Excel bằng hàm BS_AI, BS_AI_CHAT của Add-in A-Tools v10 (1 người xem)
    • Yêu thích
Trả lời
0
Đọc
50
Nguyễn Duy Tuân
Nguyễn Duy Tuân
Anhhe
Em xin nhờ các cao nhân chỉ giáo em cách tính giờ làm việc của nhân viên với ạ Plz (2 người xem)
Trả lời
2
Đọc
57
HieuCD
H
ongke0711
  • Question Question
Tải hóa đơn điện tử (https://hoadondientu.gdt.gov.vn/) Excel Vba (1 người xem)
    • Thích
    • Yêu thích
    • Cảm ơn
16 17 18
Trả lời
351
Đọc
32K
Tuanba1992
Tuanba1992
M
Mọi người giúp e với lỗi này là gì ạ (1 người xem)
Trả lời
1
Đọc
53
SA_DQ
SA_DQ
E
Không cho người khác chỉnh sửa cố định dòng và cột trong google sheet
Trả lời
0
Đọc
57
Em khong biet
E
queluatb
  • Question Question
Lấy hóa đơn đầu vào cho hóa đơn đầu ra (1 người xem)
Trả lời
5
Đọc
335
queluatb
queluatb
Vu_Thi_Xuan
Lỗi tham chiếu khi dùng Vlookup trong VBA (2 người xem)
Trả lời
9
Đọc
376
Vu_Thi_Xuan
Vu_Thi_Xuan
6
  • Question Question
vba tự động lấy dữ liệu từ etabs
Trả lời
2
Đọc
289
VetMini
V
1
Vướng mắc về hàm lấy tên đăng nhập máy tính ạ
2
Trả lời
20
Đọc
727
198zxc
1
D
Nhờ anh chị xử lý giúp lỗi thực hiện lọc dữ liệu
Trả lời
2
Đọc
490
Hoàng Tuấn 868
H
Nguyễn Duy Tuân
Phiên bản mới Add-in A-Tools v10 (2024)
    • Thích
2 3
Trả lời
50
Đọc
5K
Nguyễn Duy Tuân
Nguyễn Duy Tuân
N
xin các cao thủ chỉ cách gỡ lỗi không khởi động được excel (1 người xem)
Trả lời
4
Đọc
269
bs2
B
H
Chuyển file *xml hóa đơn điện tử sang excel
    • Thích
Trả lời
10
Đọc
484
htrunga2
H
D
Nhờ anh chị trên diễn đàn dùng hàm dò tìm dữ liệu trong bảng gửi kèm giúp ạ!
Trả lời
4
Đọc
158
dangvanphu.it
D
Xem thêm…

Thành viên có số lượng bài viết cao nhất tháng

Thành viên có điểm tương tác cao nhất tháng

Đếm ngược thời gian

000
Ngày
00
Giờ
00
phút
00
giây
[GPE] HỘI THẢO POWER QUERY – CÔNG CỤ QUẢN LÝ DỮ LIỆU HCM
Back
Top Bottom