Các câu hỏi về hàm dò tìm dữ liệu (Lookup, Vlookup, Hlookup...) (1 người xem)

[anvinhlinh]

hàm hlookup

Cả nhà giúp em câu 2 với nhé. Em làm thế này nhưng mà không được
Công thức ô G4:
=IF(F4<=HLOOKUP(C4;$B$12:$D$13;2;0);
F4*500;HLOOKUP(C4;$B$12:$D$13;2;0)*500)
Công thức ô H4:
=IF(AND(F4>HLOOKUP(C4;$B$12:$D$13;2;0);
F4<=HLOOKUP(C4;$B$12:$D$13;2;0)*2);
(F4- HLOOKUP(C4;$B$12:$D$13;2;0))*820;0)
Công thức ô I4:
=IF(F4>=HLOOKUP(C4;$B$12:$D$13;2;0)*2;
(F4-HLOOKUP(C4;$B$12:$D$13;2;0))*1200;0)
cảm ơn cả nhà nhiều nhiều.

 

[viehoai]

cả nhà giúp em câu 2 với nhé. Em làm thế này nhưng mà không được
công thức ô g4:
=if(f4<=hlookup(c4;$b$12:$d$13;2;0);
f4*500;hlookup(c4;$b$12:$d$13;2;0)*500)
công thức ô h4:
=if(and(f4>hlookup(c4;$b$12:$d$13;2;0);
f4<=hlookup(c4;$b$12:$d$13;2;0)*2);
(f4- hlookup(c4;$b$12:$d$13;2;0))*820;0)
công thức ô i4:
=if(f4>=hlookup(c4;$b$12:$d$13;2;0)*2;
(f4-hlookup(c4;$b$12:$d$13;2;0))*1200;0)
cảm ơn cả nhà nhiều nhiều.

Bạn xem công thức này thử xem nhé
G4: =IF($F4<HLOOKUP($C4;$B$13:$D$14;2;0);$F4*500;HLOOKUP($C4;$B$13:$D$14;2;0)*$F4)
H4: =IF(AND($F4>HLOOKUP($C4;$B$13:$D$14;2;0);$F4<2*HLOOKUP($C4;$B$13:$D$14;2;0));(F4-HLOOKUP($C4;$B$13:$D$14;2;0))*820;0)
I4: =IF($F4>=2*HLOOKUP($C4;$B$13:$D$14;2;0);($F4-HLOOKUP($C4;$B$13:$D$14;2;0))*1200;0)

 

[ndu96081631]

Bạn xem công thức này thử xem nhé
G4: =IF($F4<HLOOKUP($C4;$B$13:$D$14;2;0);$F4*500;HLOOKUP($C4;$B$13:$D$14;2;0)*$F4)
H4: =IF(AND($F4>HLOOKUP($C4;$B$13:$D$14;2;0);$F4<2*HLOOKUP($C4;$B$13:$D$14;2;0));(F4-HLOOKUP($C4;$B$13:$D$14;2;0))*820;0)
I4: =IF($F4>=2*HLOOKUP($C4;$B$13:$D$14;2;0);($F4-HLOOKUP($C4;$B$13:$D$14;2;0))*1200;0)

Hình như không đúng nha
Tôi nghĩ là vầy:
- Công thức cho G4:

=MIN(HLOOKUP($C4,$B$13:$D$14,2,0),$F4)*500

- Công thức cho H4:

=(MIN(MAX(HLOOKUP($C4,$B$13:$D$14,2,0),$F4)-HLOOKUP($C4,$B$13:$D$14,2,0),HLOOKUP($C4,$B$13:$D$14,2,0)))*820

- Công thức cho I4:

=1200*MAX($F4-2*HLOOKUP($C4,$B$13:$D$14,2,0),0)

 

[ngthuyson]

các bác giúp em về hàm vlookup!

em muốn tìm kh tai i2, i3 mà có mã kh và có mã mua hàng như trong file đính kèm. cảm ơn các bác trước.

 

[viendo]

Bạn dùng công thức sau xem sao

I2 = SUMPRODUCT(($A$2:$A$7=G2)*($D$2:$D$7=1)*$C$2:$C$7)

 

[nguyenquoc1609]

vlookup

giúp dùm mình bài này...yêu cầu hơi dài nên mình gửi file ( phần bôi màu ấy)

 

[Ba Tê]

giúp dùm mình bài này...yêu cầu hơi dài nên mình gửi file ( phần bôi màu ấy)

Thử nhập công thức này cho ô I5:

=$J$1*VLOOKUP(C5;IF(D5="Cấp III";$K$6:$O$9;IF(D5="Cấp II";$K$14:$O$17;$K$22:$O$25));E5+2;0)

Chú ý dấu Chấm phẩy hay dấu Phẩy là tùy máy của bạn.

 

[tvxdgt]

giúp dùm mình bài này...yêu cầu hơi dài nên mình gửi file ( phần bôi màu ấy)

Bạn dùng công thức này, tại ô I5 còn lại fill xuống

=VLOOKUP(C5,IF(D5="Cấp III",$K$6:$O$9,IF(D5="Cấp II",$K$14:$O$17,$K$22:$O$25)),MATCH("Hạng " &E5,$K$5:$O$5,0),0)*$J$1

 

[PHONGGANHHAO]

Hàm Vlookup

Nhờ quý anh chị giúp em file này nhe. Khả năng của em chỉ tới đây.
Em cám ơn nhiều lắm

 

[mhung12005]

Nhờ quý anh chị giúp em file này nhe. Khả năng của em chỉ tới đây.
Em cám ơn nhiều lắm

Bạn xem file đính kèm nhé.

 

[hophoang]

Nhờ quý anh chị giúp em file này nhe. Khả năng của em chỉ tới đây.
Em cám ơn nhiều lắm

Xem thử cái này có đúng không nha

 

[ndu96081631]

Nhờ quý anh chị giúp em file này nhe. Khả năng của em chỉ tới đây.
Em cám ơn nhiều lắm

Bạn đã hỏi bao nhiêu bài rồi mà cái TIÊU ĐỀ cũng viết không ra hồn là sao thế nhỉ?

 

[PHONGGANHHAO]

muốn ẩn hoặc hiện dòng trống

gởi anh hophoang
EM muốn số dòng sẽ tự 'xuất hiện' khi có số chứng từ phát sinh thì làm sao. (file đính kèm)

 

[PHONGGANHHAO]

Bạn đã hỏi bao nhiêu bài rồi mà cái TIÊU ĐỀ cũng viết không ra hồn là sao thế nhỉ?

Em xin lỗi Thầy. em cứ nghỉ là sẽ ghi nội dung trong File

 

[PHONGGANHHAO]

Muốn ẩn dòng trống

Ở sheet CHITIET em muốn nó Ẩn những dòng còn dư (nghĩa là khi nào có số liệu thì nó tự động nhảy thêm dòng. thì làm cách nào hả anh??? (file đính kèm)

 

[leuktuananh]

Cho em hỏi về hàm vlookup

Exel của em khi nhập hạch toán vào sổ NKC thì tự nó nhảy vào các sổ khác như sổ cái nhưng lại ko có đc số dư đầu kỳ được ,sổ cái của em thì là sổ chung tức là chỉ cần ấn vào chọn TK và hiện ra sổ vì thế cũng ko viêt trực tiếp số dư ĐK vào được .Các anh chị giúp em viêt hàm vlookup để sổ cái tự tìm SD với ạ

 

[songqueqb]

tốt nhất bạn up file lên để anh em giúp
nói vậy sao mà hiểu được !

 

[quanghiengtvt]

Hàm Vlookup

Cho mình hỏi muốn dò 2 giá trị cùng một lúc thì phải làm sao? không dùng if. Ví dụ muốn dò "tên"+"giới tính" trong bảng để tìm tiền phụ cấp.xin cảm ơn mọi người...Mình có gởi file đi kèm. có gì gởi lại mình theo mail quanghiengtvt@gmail.com. nick mình là riengmotgoctroi1987.

 

[mhung12005]

Cho mình hỏi muốn dò 2 giá trị cùng một lúc thì phải làm sao? không dùng if. Ví dụ muốn dò "tên"+"giới tính" trong bảng để tìm tiền phụ cấp.xin cảm ơn mọi người...Mình có gởi file đi kèm. có gì gởi lại mình theo mail quanghiengtvt@gmail.com. nick mình là riengmotgoctroi1987.

Bạn dùng SUMPRODUCT nhé:

Tại C2:

=SUMPRODUCT(($K$8:$K$14=A2)*($L$8:$L$14=B2),$M$8:$M$14)

 

[vietvan]

Cho em hỏi muốn điền tên hàng từ mã hàng mà SJC, 24k và 18K đều là "vàng" làm thế nào để gộp lại được ạ? Các loại khác là ngoại tệ.
Cảm ơn mọi người!

 

[Quang_Hải]

Cho mình hỏi muốn dò 2 giá trị cùng một lúc thì phải làm sao? không dùng if. Ví dụ muốn dò "tên"+"giới tính" trong bảng để tìm tiền phụ cấp.xin cảm ơn mọi người...Mình có gởi file đi kèm. có gì gởi lại mình theo mail quanghiengtvt@gmail.com. nick mình là riengmotgoctroi1987.

Gởi cho bạn 2 cách dò, có thể phát triển thêm nhiều dk tuỳ ý

 

[phihndhsp]

Cho em hỏi muốn điền tên hàng từ mã hàng mà SJC, 24k và 18K đều là "vàng" làm thế nào để gộp lại được ạ? Các loại khác là ngoại tệ.
Cảm ơn mọi người!

thử cái này nha
C3=IF(ISERROR(MATCH(LEFT(B3,3),$A$13:$A$15,0)),"Ngoại tệ", "vàng")

 

[cavangpro]

Giúp về hàm vlookup

Xin chào các bạn ! Mình có một thắc mắc mong ae giúp đỡ.
Mình có 1 file và dùng công thức vlookup để tìm kiếm giá trị. nhưng từ 1 điều kiện tìm kiếm lại có 2 giá trị.
VD: MT 120516 có 2 giá trị tìm kiếm là : HD 1614
và SFTP 15487
vì giá trị SFTP ở trên nên giá trị tìm được sẽ là: SFTP 15478. NHưng mình chỉ muốn lấy giá trị HD 1614.
Vậy mong các bạn giúp đỡ. Vì bảng đó kích thước khá lớn nên mình ko thể up lên được

 

[ndu96081631]

Xin chào các bạn ! Mình có một thắc mắc mong ae giúp đỡ.
Mình có 1 file và dùng công thức vlookup để tìm kiếm giá trị. nhưng từ 1 điều kiện tìm kiếm lại có 2 giá trị.
VD: MT 120516 có 2 giá trị tìm kiếm là : HD 1614
và SFTP 15487
vì giá trị SFTP ở trên nên giá trị tìm được sẽ là: SFTP 15478. NHưng mình chỉ muốn lấy giá trị HD 1614.
Vậy mong các bạn giúp đỡ. Vì bảng đó kích thước khá lớn nên mình ko thể up lên được

Tức là bạn muốn lấy giá trị phía dưới, đúng không?
Nếu thế thì dùng LOOKUP nhé
Cứ pháp thế này: =LOOKUP(2, 1/(Vùng tìm kiếm = điều kiện tìm), Vùng kết quả)
Ví dụ:
- Giá trị MT 120516 nằm tại cell A1
- Bảng dò tìm nằm tại H1:I10, trong đó cột H chứa các giá trị lookup và cột I là cột muốn lấy kết quả
- Vậy ta sẽ áp dụng cú pháp trên như sau:

=LOOKUP(2,1/($H$1:$H$10=A1),$I$1:$I$10)

 

[cavangpro]

cám ơn anh nhiều. dựa vào cấu trúc của anh em đã làm và thấy đúng vs giá trị em cần tìm.

 

[phihndhsp]

Lỗi hàm Lookup

Không hiểu vì sao trong mục này hàm lookup bị lỗi
ở Sheet Ngaymua_Hang_cuoi_cung tại ô A15, A17, A18 bị lỗi khi dùng hàm Lookup, mong được sự giúp đỡ của các cao thủ

 

[ndu96081631]

Không hiểu vì sao trong mục này hàm lookup bị lỗi
ở Sheet Ngaymua_Hang_cuoi_cung tại ô A15, A17, A18 bị lỗi khi dùng hàm Lookup, mong được sự giúp đỡ của các cao thủ

Bạn dùng LOOKUP vậy đâu có được (kiểm tra lại kết quả xem ---> đâu có đúng)
Nên nhớ rằng muốn dùng LOOKUP là dữ liệu nhập phải được sort trước
Trường hợp dữ liệu lộn xộn, phải thay đổi cách khác, chẳng hạn là:

=LOOKUP(2,1/(A15=DanhSach!$A$2:$A$25),DanhSach!$B$2:$B$25)

 

[Trang Trinh 2903]

Gởi cho bạn 2 cách dò, có thể phát triển thêm nhiều dk tuỳ ý

Anh ơi, file download bị lỗi ạ.

 

[Quang_Hải]

Anh ơi, file download bị lỗi ạ.

Có thể máy tính của bạn không có cài phần mềm win.rar

 

[iphone_ipad]

Xin giúp đỡ về hàm Vlookup !!

Mình có 1 câu hỏi trong bài là:
Điểm ưu tiên đc tính như sau:
Dựa vào bảng khu vực dự thi
Điểm ưu tiên chỉ được tính khi ko có môn thi nào là điểm 0
Vậy ở câu này mình dùng hàm vlookup có kết hợp hàm if thì có đc ko? mình up file là book12 !!
* Ngoài ra nhờ bạn giúp thêm dùm mình 1 câu hỏi ở book11 lun nha !!

 

[buithinhvan77]

Mình có 1 câu hỏi trong bài là:
Điểm ưu tiên đc tính như sau:
Dựa vào bảng khu vực dự thi
Điểm ưu tiên chỉ được tính khi ko có môn thi nào là điểm 0
Vậy ở câu này mình dùng hàm vlookup có kết hợp hàm if thì có đc ko? mình up file là book12 !!
* Ngoài ra nhờ bạn giúp thêm dùm mình 1 câu hỏi ở book11 lun nha !!

Lần sau bạn nên tiếp tục với chủ đề do mình mở: http://www.giaiphapexcel.com/forum/showthread.php?69308-Hướng-dẫn-về-hàm-Vlookup&p=425817#post425817
Không nên chen sang chủ đề này!
Book12! Cong thức tại I3

=IF(COUNTIF(D3:G3,0)<1,VLOOKUP(RIGHT(B3,2),$A$15:$C$18,3,0),0)

 

[quangthanhdu]

Công thức dò tìm trong Excel???

Mọi người giúp em, lập công thức dò tìm tên sheet và ô, như file đính kèm

 

[ndu96081631]

Mọi người giúp em, lập công thức dò tìm tên sheet và ô, như file đính kèm

Công thức cho cell B7:

=VLOOKUP(B$5,INDIRECT("'"&$A7&"'!B1:C100"),2,0)

Kéo fill sang phải và xuống dưới
Nếu làm luôn vụ bẫy lỗi khi không tìm thấy thì vầy:

=IF(COUNTIF(INDIRECT("'"&$A7&"'!B1:B100"),B$5),VLOOKUP(B$5,INDIRECT("'"&$A7&"'!B1:C100"),2,0),"")

 

[nguyendinhphi2708]

Lỗi #Value trong hàm Vlookup

Nhờ Anh chị hỗ trợ giúp :
1> Về hàm vlookup
2> 2 File (tong ket & du lieu )
Làm thế nào để thao tác trên 2 file khác nhau (nhưng nếu trường hợp move file "dữ liệu" sang địa chỉ khác thì vẫn có thể hiển thị kết quả vừa tìm được )
Cám ơn anh chị chúc ngày làm việc vui vẻ .

 

[khaosattraitim]

Bài tập VLOOKUP, HLOOKUP

Mong anh chị chỉ giùm. ( yêu cầu 2)

 

[nhat chi mai]

cái loại file này sao tải về máy được nhỉ??? mà bị ẩn chưa đọc hết yêu cầu được bạn à, gửi lại file đi cho tớ tải với hihi

 

[tranhoang852400]

Hỏi về hàm dò tìm vlookup , và hàm match trong excel

Em đang gặp khó khăn về hàm vlookup trong phần bài tập này mong các anh chị trên diễn đàn giúp giùm em nhất là phần hàm vlookup 2 chiều theo nhiều điều kiện . Em cảm ơn rất nhiều !

 

[Ba Tê]

Em đang gặp khó khăn về hàm vlookup trong phần bài tập này mong các anh chị trên diễn đàn giúp giùm em nhất là phần hàm vlookup 2 chiều theo nhiều điều kiện . Em cảm ơn rất nhiều !

Kiểm tra lại kết quả của công thức này xem:

D16=VLOOKUP(LEFT(A16;2)&RIGHT(A16);$H$17:$N$22;MONTH(B16)+1;0)
E16=C16*D16*(1+((MONTH(B16)=3)+(MONTH(B16)=4))*0,05)

 

[cocongmaisat]

Hỏi về hàm tìm kiếm

Nhờ các bạn chỉ mình dùng công thức trong ví dụ sau nhé! Nếu có gửi bài sai chổ thì xin admin chuyển giùm. xin đừng xóa! cảm ơn tất cả

 

[phihndhsp]

Không biết làm như vậy có đúng ý bạn không?

 

[cocongmaisat]

Nhờ các bạn chỉ mình dùng công thức trong ví dụ sau nhé! Nếu có gửi bài sai chổ thì xin admin chuyển giùm. xin đừng xóa! cảm ơn tất cả

Không có ai giúp mình sao?

 

[dongducnhiem]

Không có ai giúp mình sao?

1/ Đã có bạn phihndhsp giúp bạn ở bài #2 rồi? đúng hay sai so với ý đồ thì fải fản hồi chứ
2/

giả sử bây giờ mình cần tìm hóa đơn số 1017026 nằm trong hàng nào (ví dụ này là nằm ở hàng 4 ), thì mình dùng công thức nào để tìm?

Tôi đố bạn tìm được số nói trên ở hàng số 4 đó?
3/ Lấy File của bạn phihndhsp giúp bạn ở bài #2
Đặt cthức này ở cell H3

=MATCH(G3,$A$1:$A$15)

 

[kjttj]

Hàm Vlookup Hlookup giúp mình với (hàm này khó quá)?

Câu 6 trong FIle baitest này khó quá, mọi người ai biết giải giúp mình với nha bằng 2 cách luôn, mình xin cảm ơn!

 

[manuchungtinh]

Câu 6 trong FIle baitest này khó quá, mọi người ai biết giải giúp mình với nha bằng 2 cách luôn, mình xin cảm ơn!

Làm với Vlookup, Hlookup mà k có bảng tham chiếu thì tìm sao bạn, giáo viên bắt bạn tự tạo bảng tham chiếu rồi làm????
Bạn xem thử file này nhé!

 

[kjttj]

Mình cũng nghĩ như bạn manuchungtinh nhưng thằng bạn mình nó lại bảo là nếu làm bảng tham chiếu thì chắc là không phải theo yêu cầu của thầy ra, nếu không lập lập bảng thì không còn cách nào khác nữa sao bạn

 

[hoamattroicoi]

Mình cũng nghĩ như bạn manuchungtinh nhưng thằng bạn mình nó lại bảo là nếu làm bảng tham chiếu thì chắc là không phải theo yêu cầu của thầy ra, nếu không lập lập bảng thì không còn cách nào khác nữa sao bạn

Vậy bạn hỏi thầy xem dùng Lookup có được không nhé, cũng là nhóm hàm tìm kiếm đó, không cần bảng tham chiếu nữa. Công thức tại I13 :

=LOOKUP(--RIGHT(B13,1),{1;2;3},{"Chính";"Biên Hòa";"Quảng Ngãi"})

 

[manuchungtinh]

Mình cũng nghĩ như bạn manuchungtinh nhưng thằng bạn mình nó lại bảo là nếu làm bảng tham chiếu thì chắc là không phải theo yêu cầu của thầy ra, nếu không lập lập bảng thì không còn cách nào khác nữa sao bạn

Mình nghĩ nếu không lập bảng tham chiếu thì khó có thể dùng Vlookup lắm bởi vì cột mình cần dò tìm là giá trị của Cột B, cần phải có 1 bảng để nó đi dò tìm (bảng đó gồm 2 cột là giá trị dò tìm và giá trị trả về cái này không tạo trực tiếp được trong công thức. nếu không có bảng dò tìm thì sao mà tìm ra được. Bạn thử hỏi lại thầy xem sao nhé. Còn nếu thấy làm được mà không có bảng tham chiếu nhớ nhắn tin cho mình học hỏi với nha. hihi

 

[kjttj]

woa bạn hoamattroicoi hay quá, cảm ơn bạn nhiều lắm, nhưng chắc là không dùng hàm vlookup và hlookup cho đơn giảm được sao bạn?

 

[vodoi2x]

Mình nghĩ nếu không lập bảng tham chiếu thì khó có thể dùng Vlookup lắm bởi vì cột mình cần dò tìm là giá trị của Cột B, cần phải có 1 bảng để nó đi dò tìm (bảng đó gồm 2 cột là giá trị dò tìm và giá trị trả về cái này không tạo trực tiếp được trong công thức. nếu không có bảng dò tìm thì sao mà tìm ra được. Bạn thử hỏi lại thầy xem sao nhé. Còn nếu thấy làm được mà không có bảng tham chiếu nhớ nhắn tin cho mình học hỏi với nha. hihi

Tạo được, giống như tạo bảng trong LOOKUP của hoamattroicoi đó bạn (thêm dấu "," phân cách hàng / cột của bảng thôi mà) - hỏi hoamattroicoi đi xem sao(?)

Nên có thể dùng Vlookup, hay Hlookup được

 

[kjttj]

Tạo được, giống như tạo bảng trong LOOKUP của hoamattroicoi đó bạn (thêm dấu "," phân cách hàng / cột của bảng thôi mà) - hỏi hoamattroicoi đi xem sao(?)

Nên có thể dùng Vlookup, hay Hlookup được

oh, vậy bạn vodoi2x giải vào file rồi post lên cho mình xem thử đi, vậy là không cần lập bảng tham chiếu vẫn dùng vlookup và hlookup đư sao bạn?

 

[vodoi2x]

oh, vậy bạn vodoi2x giải vào file rồi post lên cho mình xem thử đi, vậy là không cần lập bảng tham chiếu vẫn dùng vlookup và hlookup đư sao bạn?

Được cớ sao không?

Thì cũng lập bảng hằng số - giống ở Lookup của hoamattroicoi đó , bạn thử xem sao? phải bắt tay thử mới là cùng giải bài tập ?

 

[hoamattroicoi]

Được cớ sao không?

Thì cũng lập bảng hằng số - giống ở Lookup của hoamattroicoi đó , bạn thử xem sao? phải bắt tay thử mới là cùng giải bài tập ?

Anh Vodoi2x chuyền bóng ghê quá, hihi. Bạn thử với công thức này (ý tưởng của anh Vodoi2x) bạn nhớ cảm ơn anh ý nhé

=VLOOKUP(--RIGHT(B13,1),{1,"Chính";2,"Biên Hòa";3,"Quảng Ngãi"},2,0)

 

[lq177]

Vậy bạn hỏi thầy xem dùng Lookup có được không nhé, cũng là nhóm hàm tìm kiếm đó, không cần bảng tham chiếu nữa. Công thức tại I13 :

=LOOKUP(--RIGHT(B13,1),{1;2;3},{"Chính";"Biên Hòa";"Quảng Ngãi"})

Dùng công thức này cũng được đó.

=CHOOSE(VALUE(RIGHT(B13)),"Chính","Biên Hòa","Quảng Ngãi")

 

[vodoi2x]

Dùng công thức này cũng được đó.

Vấn đề là đề bài yêu cầu dung Vlookup hoặc Hlookup (file kèm) -
Nếu không thì dùng IF, CHOOSE,... đều được

 

[Good-Luck]

Anh Vodoi2x chuyền bóng ghê quá, hihi. Bạn thử với công thức này (ý tưởng của anh Vodoi2x) bạn nhớ cảm ơn anh ý nhé

=VLOOKUP(--RIGHT(B13,1),{1,"Chính";2,"Biên Hòa";3,"Quảng Ngãi"},2,0)

nếu chỉ 3 vấn đề phát sinh thôi thì dùng hàm IF thôi cũng xong vấn đề mà (nếu thầy không cho lập bảng)

 

[manuchungtinh]

nếu chỉ 3 vấn đề phát sinh thôi thì dùng hàm IF thôi cũng xong vấn đề mà (nếu thầy không cho lập bảng)

File mẫu người ta làm bằng IF rồi , quan trọng là cái yêu cầu của đề bài cơ :

(Làm bằng cách dùng hàm VLOOKUP, HLOOKUP)

Thế mới có chuyện để bàn, chứ cách thì có nhiều lắm đâu chỉ có mỗi IF (hình như bạn chả đọc gì các bài viết người ta thắc mắc ở trên, viết bài vu vơ)

 

[nhocon]

vlookup

bài này mình phai dùng hàm vlookup vs hàm if vì mình đang học 2 hàm này

 

[phihndhsp]

bài này mình phai dùng hàm vlookup vs hàm if vì mình đang học 2 hàm này

G7=VLOOKUP(B7,$B$20:$F$23,MONTH(D7)+1,0)
nhớ sửa lại cách nhập ngày tháng đi nha, trong file bạn nhập ngày tháng bị sai rồi

 

[nhocon]

cảm ơn bạn,còn thành tiên với rút trích sao bạn
G7=VLOOKUP(B7,$B$20:$F$23,MONTH(D7)+1,0) vì sao +1,0 vây ,vi` mình chưa học cái này

nghiaphuc: Bạn hãy nhấn nút Sửa bài viết và gõ lại nội dung nhé. Cần phải sử dụng ngôn từ nghiêm túc trong các bài viết chuyên môn.

 

[nhocon]

help

hlep............hlephlephlephlephlephlep

 

[Hoàng Trọng Nghĩa]

hlep............hlephlephlephlephlephlep

Bạn không cần thiết phải "gào" lên như vậy đâu!

cảm ơn bạn,còn thành tiên với rút trích sao bạn
G7=VLOOKUP(B7,$B$20:$F$23,MONTH(D7)+1,0) vì sao +1,0 vây ,vi` mình chưa học cái này

nghiaphuc: Bạn hãy nhấn nút Sửa bài viết và gõ lại nội dung nhé. Cần phải sử dụng ngôn từ nghiêm túc trong các bài viết chuyên môn.

Đơn giản thôi, trong bảng tham chiếu của bạn ($B$20:$F$23) có 5 cột, điều kiện là tính theo tháng, các cột tháng bắt đầu từ cột 3, 4 và 5. Vì hàm VLOOKUP nó bắt buộc phải có tham chiếu số cột (column Index number), ở đây, người ta khéo lợi dụng số tháng ví dụ là tháng 2 mà tháng 2 ở cột thứ 3, nên MONTH(D7) = 2 , mà 2 + 1 thì tham số cột phải là 3 rồi đúng không? Từ từ nghiền ngẫm bạn sẽ hiểu.

Số 0 có nghĩa là FALSE, tham chiếu chính xác, nếu không có sẽ phát sinh lỗi, còn số khác là TRUE không có kết quả, nó sẽ cho ra kết quả gần nhất.

 

[ctlong1991]

Hướng dẫn sửa lại hàm VLOOKUP

Các bạn xem giúp cho mình cột tính H mình dùng hàm vlookup như sau
=VLOOKUP(H13;$O$1:$P$682;1)
Nhưng nó cứ ra kết quả là 0 hết. Các bạn xem mình viết sai ở đâu.
Cảm ơn mọi người đã giúp ^:^
Mình xin lỗi các bạn nhiều nhé. Lần đầu nên lỗi nhiều quá à ^:^

 

[Hong.Van]

Các bạn xem giúp cho mình cột tính H mình dùng hàm vlookup như sau
=VLOOKUP(H13;$O$1:$P$682;1)
Nhưng nó cứ ra kết quả là 0 hết. Các bạn xem mình viết sai ở đâu.
Cảm ơn mọi người đã giúp ^:^

Bạn kg có file đính kèm thì làm sao giúp được!

 

[ctlong1991]

Oh xin lỗi bạn
Mình đính kém rồi nhưng chưa đc. Mình mới dùng lần đầu nên ko bit ^:^

 

[kyo]

Bạn ơi, kyo không hề thấy công thức VLOOKUP của bạn ở đâu trong bảng tính cả

 

[hoamattroicoi]

Oh xin lỗi bạn
Mình đính kém rồi nhưng chưa đc. Mình mới dùng lần đầu nên ko bit ^:^

Xem file rồi nhưng hỏng biết bạn dò tìm cái gì ở cột nào nữa? Mà cũng chẳng thấy có cái công thức nào giống cái công thức mà bạn mô tả ở trên để mà tìm lỗi, túm lại là hỏng hiểu gì, hic!!!

 

[Hong.Van]

Oh xin lỗi bạn
Mình đính kém rồi nhưng chưa đc. Mình mới dùng lần đầu nên ko bit ^:^

Bạn kg cho biết cthức trên đặt ở cell nào
Mặt khác, hàm VLookup, của bạn còn thiếu 1 đối số
Bạn xem lại cú fáp
Cú pháp: VLOOKUP(lookup_value, table_array, col_index_num [, range_lookup])
Bvn thiếu đối số này
range_lookup___Là một giá trị kiểu Borlean, để chỉ kiểu tìm kiếm: chính xác hay tương đối. (-1;0;1)

 

[tranhoang852400]

MÌnh rất cảm ơn các anh chị trên diễn đàn rất nhiều !

 

[sao]

Sử dụng hàm Vlookup

Anh chị nào giúp mình với , mình có một sheet gía , một sheet tên hàng,dùng hàm Vlookup đưa giá vào nhưng không được, chỉ dùm mình cám ơn rất nhiều, File đính kèm.

 

[leonguyenz]

Anh chị nào giúp mình với , mình có một sheet gía , một sheet tên hàng,dùng hàm Vlookup đưa giá vào nhưng không được, chỉ dùm mình cám ơn rất nhiều, File đính kèm.

Bạn tham khảo Hàm VLOOKUP như sau:

Hàm VLOOKUP

Chức năng: Hàm VLOOKUP là hàm dò tìm theo cột, sẽ trả về giá trị của một ô nằm trên một cột nào đó nếu thỏa mãn điều kiện dò tìm.

Cú pháp hàm: VLOOKUP(lookup_value,table_array,col_index_num,option_lookup)

- Lookup_value: là giá trị dùng để dò tìm, giá trị này sẽ được dò tìm trong cột đầu tiên của bảng dữ liệu dò tìm. Giá trị dò tìm có thể là một số, một chuỗi, một công thức trả về giá trị hay một tham chiếu đến một ô nào đó dùng làm giá trị dò tìm.

- Table_array: là bảng dùng để dò tìm, bảng dò tìm có thể là tham chiếu đến một vùng nào đó hay Name trả về vùng dò tìm. Bảng dò tìm gồm có Rj hàng và Ci cột (I,j >=1), trong đó cột thứ nhất của bảng dò tìm sẽ được dùng để dò tìm.

- Col_index_num: là số thứ tự của cột (tính từ trái qua phải) trong bảng dò tìm chứa giá trị mà ta muốn trả về. Col_index_num phải >=1 và <= số cột lớn nhất có trong bảng dò tìm, ngược lại hàm sẽ trả về #VALUE! hoặc #REF.

- Option_lookup: là tùy chọn xác định kiểu dò tìm, có 2 kiểu dò tìm:

• True hoặc 1 hoặc để trống: là kiểu dò tìm tương đối, hàm sẽ lấy giá trị đầu tiên mà nó tìm được trên cột đầu tiên trong bảng dò tìm. Trong trường hợp tìm không thấy, nó sẽ lấy giá trị lớn nhất mà có giá trị nhỏ hơn giá trị dò tìm.
  
• False hoặc 0: là kiểu dò tìm chính xác, hàm sẽ lấy giá trị đầu tiên mà nó tìm được trên cột đầu tiên trong bảng dò tìm. Trong trường hợp tìm không thấy, hàm sẽ trả về #N/A.
  

 

[hoamattroicoi]

P/S : Bạn post bài sai box.

Hoặc bạn tham khảo các bài viết trong link này nhé.

http://www.giaiphapexcel.com/forum/showthread.php?35494-Ca%CC%81c-c%C3%A2u-h%E1%BB%8Fi-v%E1%BB%81-ha%CC%80m-d%C3%B2-t%C3%ACm-d%E1%BB%AF-li%E1%BB%87u-%28Lookup-Vlookup-Hlookup-%29

 

[sao]

mình muốn gửi file đính kèm xem dùm mình thử nhưng không biết gửi ở đâu, giúp mình nha

 

[hoamattroicoi]

mình muốn gửi file đính kèm xem dùm mình thử nhưng không biết gửi ở đâu, giúp mình nha

Bạn xem cách đính kèm file trong link này nhé :

http://www.giaiphapexcel.com/forum/showthread.php?33633-Hướng-dẫn-gửi-bài-và-đính-kèm-tập-tin

Nhờ MODS phụ trách chuyến giúp bài này của bạn ấy vào đúng box.

Gửi bạn Sao : Bạn nên đọc kỹ nội quy diễn đàn trước khi post bài nhé, bài viết của bạn đang sai box, bạn nên post câu hỏi của bạn vào link bài #3 mình gửi đó.
Xin cảm ơn!

 

[d05403054]

giải hộ hàm vlookup

hi mọi người, mình có bài tập này đang bị bí hàm vlookup, mong người hướng dẫn. Cần giải ở cột hãng SX ở mã SP cos STT là 6

 

[le tin]

hi mọi người, mình có bài tập này đang bị bí hàm vlookup, mong người hướng dẫn. Cần giải ở cột hãng SX ở mã SP cos STT là 6

Tìm không có nên nó báo lỗi #N/A

 

[d05403054]

Tìm không có nên nó báo lỗi

Bạn đọc kỹ phần yêu cầu số 2 trong trang đó đi, phải có hàm If vào nữa, mà mình thì ko biết lồng như thế nào cho dung CT nên nhờ các bạn

 

[leonguyenz]

=IF(ISNA(VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0)),"Hàng trong nước",VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0))
Hoặc
=IFERROR(VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0),"Hàng trong nước")

 

[d05403054]

=IF(ISNA(VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0)),"Hàng trong nước",VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0))
Hoặc
=IFERROR(VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0),"Hàng trong nước")

ra dc rồi, thank kiuf bạn

mà cho mình hỏi ý nghĩa của hàm ISNA là gì thế nhỉ ?

IF(ISNA(VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0)),"Hàng trong nước",VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0)) --> hàm này đúng nè

IFERROR(VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0),"Hàng trong nước") -> hàm này sai toét tòe loe, nó show lỗi NAME gì đó

@leonguyenz : bạn cho mình hỏi thêm, nếu trong trường hợp yêu cầu số 2 đó có thêm ý là "nếu là TN là hàng trong nước, nếu là DN là hàng ngoài nước", ... thì CT nó ra sao nhỉ ?

 

[leonguyenz]

Vậy bạn đặt 2 điều kiện đó trước: =IF(RIGHT(B8,2)="TN","Hàng trong nước",IF(RIGHT(B8,2)="DN","Hàng ngoài nước",VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0)))
Ý nghĩa Hàm ISNA là kiểm tra giá trị có lỗi #N/A hay không.

 

[d05403054]

Vậy bạn đặt 2 điều kiện đó trước: =IF(RIGHT(B8,2)="TN","Hàng trong nước",IF(RIGHT(B8,2)="DN","Hàng ngoài nước",VLOOKUP(RIGHT(B8,2),$F$13:$G$17,2,0)))
Ý nghĩa Hàm ISNA là kiểm tra giá trị có lỗi #N/A hay không.

ặc, vậy thì lúc nãy bạn nên đưa cho mình cái ct này dùng cho ngắn gọn, dễ hiểu. Tự nhiên đưa cái hàm ISNA vào làm mình khó hiểu

Thank kiu bạn nha !

 

[sao]

Sử dụng hàm Vlookup

Anh chị nào giúp mình với, mình có 1 sheet đơn giá và sheet tổng , lấy dữ liệu từ đơn giá qua nhưng không được, cám ơn anh chị hướng dẫn, file đính kèm

 

[xuan.nguyen82]

Bạn phải đưa file ví dụ lên mọi người mới giúp bạn được chứ?
File đính kèm mà có thấy file đâu?

 

[cavangpro]

Anh chị nào giúp mình với, mình có 1 sheet đơn giá và sheet tổng , lấy dữ liệu từ đơn giá qua nhưng không được, cám ơn anh chị hướng dẫn, file đính kèm

Với những câu hỏi thế này thì thật là bó tay. Mình nhớ lại mấy hôm trước có ra bài test cho những ứng viên có dùng hàm vlookup. Các bạn ý không ai biết hàm này dùng như thế nào và mở ngay GPE để hỏi cũng như tra cứu. Thời buổi này chất lượng sinh viên mới ra trường kém quá.

 

[sao]

Sử dụng hàm Vlookup

Anh chị giúp mình, mình có 1 sheet giá và sheet tổng , lấy giá qua sheet tổng nhưng không được, mong anh chị giúp đỡ, Cám ơn rất nhiều. File đính kèm

 

[kjttj]

Thắc mắc hàm VLOOKUP tổng quát (rất khó)

Trong file đính kèm của em:
Ở cột đơn giá thầy em đặt vấn đề thế này:
Thay vì phải dùng hàm Vlookup ghép với 2 hàm If không hay cho lắm. Thầy em mới hướng dẫn hàm thế này
=VLOOKUP(LEFT(B3,2),$A$16:$F$22,MATCH("Tháng"&" "&RIGHT(B3,2)*1,$A$16:$F$16,0),0)
hàm trên khi dùng sẽ ra kết quả.
Nhưng thầy em lại đặt vấn đề, để hàm có tính tổng quát hơn, lấy ví dụ ở bảng danh mục hàng chỗ ô các tháng, nếu dùng nếu ghi "Tháng 1"(hàm sẽ hiểu) vì "Tháng"&" "&RIGHT(B3,2)*1 sẽ trả kết quả "Tháng 1". Nhưng đặt tình huống ai đó gõ vào "tháng 12" sẽ không cho kết quả vì có hai số:
Thầy em mới chỉ thế này Vào Format Cell --> Custom --> chỉnh lại thành "Tháng"00, rồi bỏ dòng "Tháng"&" "& ở hàm trên, thì sẽ cho kết quả đúng, nhưng tổng quát hơn.
Nhưng sao em làm không ra, mọi người xem giúp em, rồi hướng dẫn giúp em cách làm với, em xin cảm ơn trước

 

[kjttj]

Hic hic mọi người giúp dùm em với! Nếu mọi người khó hiểu chỗ nào trong câu hỏi của em, thì cứ post lên rồi em giải thích cho nha!

 

[hoamattroicoi]

Trong file đính kèm của em:
Ở cột đơn giá thầy em đặt vấn đề thế này:
Thay vì phải dùng hàm Vlookup ghép với 2 hàm If không hay cho lắm. Thầy em mới hướng dẫn hàm thế này
=VLOOKUP(LEFT(B3,2),$A$16:$F$22,MATCH("Tháng"&" "&RIGHT(B3,2)*1,$A$16:$F$16,0),0)
hàm trên khi dùng sẽ ra kết quả.
Nhưng thầy em lại đặt vấn đề, để hàm có tính tổng quát hơn, lấy ví dụ ở bảng danh mục hàng chỗ ô các tháng, nếu dùng nếu ghi "Tháng 1"(hàm sẽ hiểu) vì "Tháng"&" "&RIGHT(B3,2)*1 sẽ trả kết quả "Tháng 1". Nhưng đặt tình huống ai đó gõ vào "tháng 12" sẽ không cho kết quả vì có hai số:
Thầy em mới chỉ thế này Vào Format Cell --> Custom --> chỉnh lại thành "Tháng"00, rồi bỏ dòng "Tháng"&" "& ở hàm trên, thì sẽ cho kết quả đúng, nhưng tổng quát hơn.
Nhưng sao em làm không ra, mọi người xem giúp em, rồi hướng dẫn giúp em cách làm với, em xin cảm ơn trước

Làm thế này Kittj này, xem file đính kèm nhé, muốn biết định dạng thế nào thì chọn ô D16, bấm Ctrl+1 sau đó vào Custom xem :

Lần sau có câu hỏi nào liên quan đến Vlookup, Hlookup....Kittj post bài hỏi tại đây nhé.
http://www.giaiphapexcel.com/forum/...tìm-dữ-liệu-(Lookup-Vlookup-Hlookup-)/page215
Các MODS đỡ phải di chuyển bài của bạn vào TOPIC đó nữa, cảm ơn Kittj!

 

[kjttj]

Làm ơn chĩ rõ hộ mình cách định dạng trong file đính kèm với.
Theo HMTC, mình làm bằng cách chọn ba ô đã gõ là "Tháng 1", "Tháng 2", "Tháng 3", sau đó mình vào FOrmat cell, custom, rồi đổi ô type thành "Tháng "00, nhưng sao không làm được! Làm ơn chỉ cụ thể dùm mình tí nhé!

 

[hoamattroicoi]

Làm ơn chĩ rõ hộ mình cách định dạng trong file đính kèm với.
Theo HMTC, mình làm bằng cách chọn ba ô đã gõ là "Tháng 1", "Tháng 2", "Tháng 3", sau đó mình vào FOrmat cell, custom, rồi đổi ô type thành "Tháng "00, nhưng sao không làm được! Làm ơn chỉ cụ thể dùm mình tí nhé!

Ối giời ôi, nhắn tin qua diễn đàn hỏi mình rồi mà vẫn hỏi ở đây hả??? hix hix

Gõ số 1,2,3 vào 3 ô đó, đừng gõ chữ Tháng
Vào Format/ Cells/ Number/ Custom Trong Type gõ "Tháng "00 bấm OK.

 

[ndu96081631]

Làm thế này Kittj này, xem file đính kèm nhé, muốn biết định dạng thế nào thì chọn ô D16, bấm Ctrl+1 sau đó vào Custom xem :

Lần sau có câu hỏi nào liên quan đến Vlookup, Hlookup....Kittj post bài hỏi tại đây nhé.
http://www.giaiphapexcel.com/forum/showthread.php?35494-Ca%CC%81c-c%C3%A2u-h%E1%BB%8Fi-v%E1%BB%81-ha%CC%80m-d%C3%B2-t%C3%ACm-d%E1%BB%AF-li%E1%BB%87u-%28Lookup-Vlookup-Hlookup-%29/page215
Các MODS đỡ phải di chuyển bài của bạn vào TOPIC đó nữa, cảm ơn Kittj!

Công thức:

=VLOOKUP(LEFT(B3,2),$A$16:$F$22,MATCH(RIGHT(B3,2)*1,$A$16:$F$16,0),0)

Sao không ghi thành vầy cho khỏe:

=VLOOKUP(LEFT(B3,2),$A$16:$F$22,RIGHT(B3,2)+3,0)

Ẹc... Ẹc...

 

[hoamattroicoi]

Tại ông THẦY giáo của bạn ấy ông muốn vậy đó đó sư phụ ạ, với lại ông THẦY đang muốn bạn ấy tổng quát chỗ :

Nhưng đặt tình huống ai đó gõ vào "tháng 12" sẽ không cho kết quả vì có hai số:

Thế nên dù biết khỏe nhưng không thể dùng thuốc đó đc ạ, Ẹc Ẹc...

 

[ndu96081631]

Tại ông THẦY giáo của bạn ấy ông muốn vậy đó đó sư phụ ạ, với lại ông THẦY đang muốn bạn ấy tổng quát chỗ :


Thế nên dù biết khỏe nhưng không thể dùng thuốc đó đc ạ, Ẹc Ẹc...

Nhưng cách dùng RIGHT(...) + 3 lại chẳng liên quan gì đến việc gõ Tháng 1 hay Tháng 12 cả. Cũng không cần phải Custom Format ---> Nói chung là muốn gõ gì cứ gõ, miễn sao sắp xếp tháng nhỏ đúng trước, tháng lớn đứng sau (đồng thời các tháng liên tục nhau)
Giới thiệu 1 cách khác tác giả thấy rằng: BỐ TRÍ DỮ LIỆU HỢP LÝ CŨNG LÀ CÁCH TIẾT KIỆM THỜI GIAN
Ẹc... Ẹc...

 

[hoamattroicoi]

Nhưng cách dùng RIGHT(...) + 3 lại chẳng liên quan gì đến việc gõ Tháng 1 hay Tháng 12 cả. Cũng không cần phải Custom Format ---> Nói chung là muốn gõ gì cứ gõ, miễn sao sắp xếp tháng nhỏ đúng trước, tháng lớn đứng sau (đồng thời các tháng liên tục nhau)
Giới thiệu 1 cách khác tác giả thấy rằng: BỐ TRÍ DỮ LIỆU HỢP LÝ CŨNG LÀ CÁCH TIẾT KIỆM THỜI GIAN
Ẹc... Ẹc...

Đi học nó khổ thế đấy sư phụ ạ, lúc nào thầy cũng bảo các em phải chọn cách nào nó tổng quát vì đề thi thì lắm dạng lắm nhỡ tháng nó không liên tục đúng lúc đang trong phòng thi lúc ấy không Right cộng cộng được nữa thì chắc tèo mất vì làm gì có thầy giáo và GPE trong phòng thi .....hix hix

 

[hunglankt]

các pro giúp em về vlookup với

Mấy anh chị ơi, giúp em bài excel với, em đang làm kế toán cho 1 cty, có 1 vấn đề là: điền các số hóa đơn, ngày hđ,tên đối tượng vào nhật ký chứng từ. mà số liệu ở báo cáo thuế, giờ em muốn lookup để tìm nhưng ko dc? em mong anh chị giúp em vấn đề này ạ, em thank nhiều, thứ 2 em nộp rồi ạ

 

[cavangpro]

Mấy anh chị ơi, giúp em bài excel với, em đang làm kế toán cho 1 cty, có 1 vấn đề là: điền các số hóa đơn, ngày hđ,tên đối tượng vào nhật ký chứng từ. mà số liệu ở báo cáo thuế, giờ em muốn lookup để tìm nhưng ko dc? em mong anh chị giúp em vấn đề này ạ, em thank nhiều, thứ 2 em nộp rồi ạ

nhìn vào bảng của bạn mình thật sự không biết dựa vào cái gì ( lookup_value ) để lấy số hóa đơn, ngày hđ, tên đối tượng trong sheet 1. Bạn nên để file của mình rõ ràng, như vậy mới dễ hiểu cho người nhận.

 

[meoden2291988]

hàm vlookup


Mọi người giúp em với. đây là bài tâp
Câu hỏi là tính thành tiền = đơn giá bậc nhân với thời gian
em không biết sử dụng hàm right trong bảng tham chiếu nhưng không biết đúng hay sai và làm thế nào
Mong mọi người giúp em

 

[lq177]

View attachment 90076
Mọi người giúp em với. đây là bài tâp
Câu hỏi là tính thành tiền = đơn giá bậc nhân với thời gian
em không biết sử dụng hàm right trong bảng tham chiếu nhưng không biết đúng hay sai và làm thế nào
Mong mọi người giúp em

Bạn dùng công thức này:

=C13*INDEX($B$6:$C$10,MATCH(B13,VALUE(RIGHT($B$6:$B$10)),0),2)

Rồi Ctrl+Shift+Enter

 

[ndu96081631]

Bạn dùng công thức này:
Rồi Ctrl+Shift+Enter

Công thức này là công thức bình thường, sao phải Ctrl+Shift+Enter hả đồng chí?

 

[lq177]

Công thức này là công thức bình thường, sao phải Ctrl+Shift+Enter hả đồng chí?

Bình thường sao em Enter nó #VALUE!
Phải Ctrl+Shift+Enter mý ra kết quả

 

[leonguyenz]

Sao không dùng VLOOKUP nhỉ?
=C13*VLOOKUP("*"&B13,$B$6:$C$10,2,0)