Nếu số nhỏ hơn 0 thì có chữ "Thiếu" (1 người xem)

[LuuAnh980]

Chào các anh!!!!
Mong các anh giúp em công thức cho cột I và cột K trong file ạ.
Nếu nhỏ hơn 0 thì có chữ "Thiếu", lớn hơn 0 thì có chữ "Dư".
Trong file em có diễn tả ạ.

 

[huonglien1901]

Cột I
=IF(H5+D5-G5=0,0,IF(H5+D5-G5<0,"Thiếu"&" "&-1*(H5+D5-G5),"Dư"&" "&H5+D5-G5))

 

[LuuAnh980]

Cám ơn anh @huonglien1901 nhiều ạ.

Bài đã được tự động gộp: 18/2/24

Công thức cột I đúng rồi, nhưng cột K thì bị Value anh @huonglien1901 ơi.

 

[LuuAnh980]

Vì lúc này cột I thành Text rồi nên không tính được phải không anh @huonglien1901 ???

 

[LuuAnh980]

Thôi chắc phải chuyển lại thành dấu âm thôi. Vì nếu để có chữ "Thiếu" và "Dư" thì cột K không tính được rồi.

 

[VetMini]

Custom number format:

"Thừa " #;"Thiếu" #;"Vừa"

 

[NguyenthiH]

Các anh dùng hàm If kết hợp ABS thử coi.

 

[VetMini]

Các anh dùng hàm If kết hợp ABS thử coi.

Bạn thử giùm đi. . .

 

[LuuAnh980]

Bác @VetMini đã chỉnh Custom number format rồi, thì công thức ở cột K sao bác @VetMini ???

 

[Nhattanktnn]

Bác @VetMini đã chỉnh Custom number format rồi, thì công thức ở cột K sao bác @VetMini ???

Công thức tại I5:

=TEXT(H5+D5-G5,"\Dư #;T\hi\ếu #;;")

 

[LuuAnh980]

Công thức cho K5 dùm luôn anh @Nhattanktnn

 

[Nhattanktnn]

Công thức cho K5 dùm luôn anh @Nhattanktnn

Không nên giùm nhiều thế, biết được hướng rồi thì bạn tự viết cho trường hợp tương tự

 

[NghiaKieu]

Bác @VetMini đã chỉnh Custom number format rồi, thì công thức ở cột K sao bác @VetMini ???

Rồi đã thử chưa? Cột K thì cũng Custom number format như cột I thôi chứ còn thế nào nữa?

 

[LmoovoenX]

Bác @VetMini đã chỉnh Custom number format rồi, thì công thức ở cột K sao bác @VetMini ???

Bạn cứ mò trong cái custom, có nhiều cái hay lắm.

 

[LuuAnh980]

Nếu chỉnh trong Custom, thì qua máy khác phải chỉnh 1 lần nữa phải không các anh????

 

[Hoàng Tuấn 868]

Nếu chỉnh trong Custom, thì qua máy khác phải chỉnh 1 lần nữa phải không các anh????

Cái nào có thể tự thử được thì không biết có nên hỏi không nhỉ.

 

[LuuAnh980]

đang máy nhà anh @Hoàng Tuấn 868 , mai mang file lên cty mới thử được anh.

Bài đã được tự động gộp: 19/2/24

Nếu dùng công thức thì công thức cho K5 sao các anh??? vì K5=J5-I5, mà I5 lúc này là chuỗi thì làm sao tính toán được nhỉ.

 

[cantl]

Nếu chỉnh trong Custom, thì qua máy khác phải chỉnh 1 lần nữa phải không các anh????

Cái này là đoán nhé: cứ cái gì cần save thì sẽ tác dụng trong mọi máy.
Nếu suỵt thì là đoán sai.

 

[hoangtuan.net]

Nếu chỉnh trong Custom, thì qua máy khác phải chỉnh 1 lần nữa phải không các anh????

Không phải chỉnh 1 lần nữa bạn nhé!

 

[LuuAnh980]

@NghiaKieu sao không thích vậy anh?????

 

[VetMini]

@NghiaKieu sao không thích vậy anh?????

...
Nếu dùng công thức thì công thức cho K5 sao các anh??? vì K5=J5-I5, mà I5 lúc này là chuỗi thì làm sao tính toán được nhỉ.

Nếu dùng công thức thì trong công thức có phép ghép chuỗi. Muốn tính toán thì loại những chỗ ghép chuỗi ra.

 

[NghiaKieu]

@NghiaKieu sao không thích vậy anh?????

Cả cột I và cột K dùng Custom là được rồi, sao phải phức tạp lên làm gì? Hay bạn nghĩ custom ở cột I rồi thì cột I thành dạng text không dùng công thức ở cột K được nữa???

 

[LuuAnh980]

nếu không dùng custom, dùng công thức thì công thức cho K5 làm sao bác @VetMini
Ví dụ lấy công thức của anh @Nhattanktnn ở I5, thì công thức cho K5 là sao Bác.

 

[VetMini]

Công thức chuyển dạng chuỗi vừa rắc rối, vừa khó cho bảng tính sau này (*). Tại sao phải nhất định với nó vậy? Đừng nói với tôi là bạn muốn học hỏi. Trình độ Excel của bạn chưa đủ để hiểu những công thức này.

I5 = TEXT(H5+D5-G5, """Dư ""#;""Thiếu ""#;;")

Công thức lọc chuỗi ra khỏi ô hơi rắc rối. Vì trị I5 phải dùng nhiều lần trong K5 cho nên dùng name thì tốt hơn.
- Đặt con trỏ ở ô K5
- Formulas > Name
- Đăt một name tên là TRIO_I =IF($I5="",0,--SUBSTITUTE(SUBSTITUTE($I5,"Dư ",""),"Thiếu ","-"))

K5 = Text(TRIO_I + TRIO_I, """Dư ""#;""Thiếu ""#;;")

Không muốn dùng name thì:
K5 = Text(2*=IF($I5="",0,--SUBSTITUTE(SUBSTITUTE($I5,"Dư ",""),"Thiếu ","-")), """Dư ""#;""Thiếu ""#;;")

(*) Đây là điểm quan trọng. Trình độ Excel của bạn không đủ để bạn làm việc với chuỗi. Sử dụng chuỗi kiểu này là bạn mặc nhiên chấp nhận về sau này cứ đụng vào hai cột I, K lại phải hỏi.

 

[HieuCD]

Chào các anh!!!!
Mong các anh giúp em công thức cho cột I và cột K trong file ạ.
Nếu nhỏ hơn 0 thì có chữ "Thiếu", lớn hơn 0 thì có chữ "Dư".
Trong file em có diễn tả ạ.

Chỉnh tí

I5 =TEXT(H5+D5-G5,"   \Dư #;T\hi\ếu #;;")
K5 =IF(I5="",0,J5+MID(I5,6,9)*((LEFT(I5)=" ")*2-1))

 

[VetMini]

Chỉnh tí

I5 =TEXT(H5+D5-G5,"   \Dư #;T\hi\ếu #;;")
K5 =IF(I5="",0,J5+MID(I5,6,9)*((LEFT(I5)=" ")*2-1))

Đêm buồn ngủ quá. Tôi cũng đọc không rõ cái công thức trong cột K ra sao.

 

[LuuAnh980]

Cám ơn anh @HieuCD , nhưng công thức của anh ở K5 không có chữ "Dư" và "Thiếu" ạ.
Cám ơn bác @VetMini , công thức của bác sai ạ, ví dụ:
1/ I15 =Thiếu 17 mà J15 = 18, thì K15 phải là Dư 1 chứ sao = Thiếu 34
2/ I16 = Thiếu 4 mà J16 = 4, thì K16 phải là 0 chứ sao = Thiếu 8
Mong Bác xem giúp.

 

[HieuCD]

Cám ơn anh @HieuCD , nhưng công thức của anh ở K5 không có chữ "Dư" và "Thiếu" ạ.

Vậy à, thêm tí mắm muối

K5 =IF(I5="","",TEXT(J5+MID(I5,6,9)*((LEFT(I5)=" ")*2-1),"   \Dư #;T\hi\ếu #;"))

 

[LuuAnh980]

Oh!!!! Có vậy thôi à, vậy mà em ngu quá, đúng là quen copy và paste. Cám ơn anh Hiếu nhiều ạ.

 

[Phan Thế Hiệp]

nếu không dùng custom, dùng công thức thì công thức cho K5 làm sao bác @VetMini
Ví dụ lấy công thức của anh @Nhattanktnn ở I5, thì công thức cho K5 là sao Bác.

Chơi với!

Nếu không dùng 'custom' thì chuốc sự rắc rối chứ sao!

Tại K5:

=TEXT(LOOKUP(10^10,J5+SUBSTITUTE(I5&" ",{" ","Dư ","Thiếu "},{"0","","-"})),"""Dư ""#;""Thiếu ""#;")

Thân

 

[LuuAnh980]

Công thức của anh @HieuCD là quá chuẩn rồi ạ. Cám ơn anh @Phan Thế Hiệp nhiều.

 

[Phan Thế Hiệp]

Công thức của anh @HieuCD là quá chuẩn rồi ạ. Cám ơn anh @Phan Thế Hiệp nhiều.

Vd: I15 là "Dư 3" như file tôi đính kèm thì mần răng!?

Thân

 

[Nhattanktnn]

Em thấy I5 = H5+D5-G5, mà K5=J5+I5 => K5= J5+H5+D5-G5
Vậy nếu

I5 =TEXT(H5+D5-G5,"\Dư #;T\hi\ếu #;;")

thì

K5 =TEXT(J5+H5+D5-G5,"\Dư #;T\hi\ếu #;;")

chứ sao phải xử lý text gì nữa các bác?

 

[Phan Thế Hiệp]

Em thấy I5 = H5+D5-G5, mà K5=J5+I5 => K5= J5+H5+D5-G5
Vậy nếu

I5 =TEXT(H5+D5-G5,"\Dư #;T\hi\ếu #;;")

thì

K5 =TEXT(J5+H5+D5-G5,"\Dư #;T\hi\ếu #;;")

chứ sao phải xử lý text gì nữa các bác?

Em thẳng thắn quá, 'phá' hỏng cuộc vui của mấy anh!

Tại cái câu này nè!

Nếu dùng công thức thì công thức cho K5 sao các anh??? vì K5=J5-I5, mà I5 lúc này là chuỗi thì làm sao tính toán được nhỉ.

Quay mặt vào tường sám hối 3 ngày đi nha!

Khà khà khà

 

[Nhattanktnn]

Em thẳng thắn quá, 'phá' hỏng cuộc vui của mấy anh!

Tại cái câu này nè!

Quay mặt vào tường sám hối 3 ngày đi nha!

Khà khà khà

haha ra là vậy, em lại tưởng các anh không để ý nên mới lỡ 'phá' hỏng cuộc vui. Nếu không có gì bất tiện thì các lại cứ tiếp tiếp cuộc vui đi nhé, tội của em ăn năn sám hối 3 ngày liệu đủ không anh

 

[VetMini]

Em thấy I5 = H5+D5-G5, mà K5=J5+I5 => K5= J5+H5+D5-G5
Vậy nếu

I5 =TEXT(H5+D5-G5,"\Dư #;T\hi\ếu #;;")

thì

K5 =TEXT(J5+H5+D5-G5,"\Dư #;T\hi\ếu #;;")

chứ sao phải xử lý text gì nữa các bác?

Lô gic toán thì vậy. Nhưng lô gic quy trình thì khác. Làm như vậy sẽ cắt đứt sự liên hệ giữa cột I và cột K.

 

[Phan Thế Hiệp]

haha ra là vậy, em lại tưởng các anh không để ý nên mới lỡ 'phá' hỏng cuộc vui. Nếu không có gì bất tiện thì các lại cứ tiếp tiếp cuộc vui đi nhé, tội của em ăn năn sám hối 3 ngày liệu đủ không anh

Cái đơn giản là dùng 'Custom' để thêm 'text' trước 1 số, nó vẫn là 'dạng số' tính toán tiếp tục được. Ghép nối từa lưa thì có phải là khoái tìm sự rắc rối hay không!?

Như anh @VetMini có răn chủ thớt ở bài #24 trên:

Công thức chuyển dạng chuỗi vừa rắc rối, vừa khó cho bảng tính sau này (*). Tại sao phải nhất định với nó vậy? Đừng nói với tôi là bạn muốn học hỏi. Trình độ Excel của bạn chưa đủ để hiểu những công thức này.
.................................
(*) Đây là điểm quan trọng. Trình độ Excel của bạn không đủ để bạn làm việc với chuỗi. Sử dụng chuỗi kiểu này là bạn mặc nhiên chấp nhận về sau này cứ đụng vào hai cột I, K lại phải hỏi.

Ba ngày là đủ, nhớ gõ mõ nữa nha!