Xin hỏi mọi người cách đếm chuỗi số. (2 người xem)

[Khanhvu25]

Trước tiên em xin gửi lời chào lời chúc sức khỏe đến các bác quản trị Web: www.giaiphapexcel.com. và toàn thể thành viên.
Em có một câu hỏi về cách đếm số không liền kề . Em có dòng gồm các số 1011100001100 kéo dài . em muốn hỏi cách có thể đếm được trong chuỗi số trên bao nhiêu lần xuất hiện 0 , 00 ,000 ,....
Em xin cảm ơn mọi người một lần nữa . Chúc mọi người giữ sức khỏe chiến thắng covid.

 

[Phuocam]

Trước tiên em xin gửi lời chào lời chúc sức khỏe đến các bác quản trị Web: www.giaiphapexcel.com. và toàn thể thành viên.
Em có một câu hỏi về cách đếm số không liền kề . Em có dòng gồm các số 1011100001100 kéo dài . em muốn hỏi cách có thể đếm được trong chuỗi số trên bao nhiêu lần xuất hiện 0 , 00 ,000 ,....
Em xin cảm ơn mọi người một lần nữa . Chúc mọi người giữ sức khỏe chiến thắng covid.

A1 có giá trị là 1011100001100, bạn muốn kết quả trong B1, C1 .. là gì?

.

 

[SA_DQ]

B1=> 7;
C1 => 4 hay 3 tùy bạn;
D1 => 2 hay 1 tùy!
. . . .
Chúc mọi người vui & khỏe!

 

[Khanhvu25]

A1 có giá trị là 1011100001100, bạn muốn kết quả trong B1, C1 .. là gì?

.

xin cảm ơn bạn đã quan tâm chủ đề mình đặt ra ,ý mình là chuỗi 1011100001100 , mỗi ký tự nằm 1 ô , A1 , B1 , C1 , D1 ,...Ởô A2 mình ra kết quả số trường hợp chỉ 1 số 0 xuất hiện 1, A3 trường hợp có 2 số 0đứng kề nhau , A4 trường hợp có 3 số 0 đứng cạnh nhau ...

 

[Phuocam]

xin cảm ơn bạn đã quan tâm chủ đề mình đặt ra ,ý mình là chuỗi 1011100001100 , mỗi ký tự nằm 1 ô , A1 , B1 , C1 , D1 ,...Ởô A2 mình ra kết quả số trường hợp chỉ 1 số 0 xuất hiện 1, A3 trường hợp có 2 số 0đứng kề nhau , A4 trường hợp có 3 số 0 đứng cạnh nhau ...

Tải file mẫu lên, ghi rõ kết quả mong đợi vào A2,A3,A4,A5, ...


.

 

[CHAOQUAY]

xin cảm ơn bạn đã quan tâm chủ đề mình đặt ra ,ý mình là chuỗi 1011100001100 , mỗi ký tự nằm 1 ô , A1 , B1 , C1 , D1 ,...Ởô A2 mình ra kết quả số trường hợp chỉ 1 số 0 xuất hiện 1, A3 trường hợp có 2 số 0đứng kề nhau , A4 trường hợp có 3 số 0 đứng cạnh nhau ...

Tại A2, copy xuống dưới

=(LEN(A$1)+2-LEN(SUBSTITUTE(1&A$1&1,1&REPT("0",ROW()-1)&1,"")))/(ROW()+1)

 

[Khanhvu25]

Tải file mẫu lên, ghi rõ kết quả mong đợi vào A2,A3,A4,A5, ...


.

Mình có đính kèm file ví dụ mình dùng tay để đếm , bạn xem giúp mình nhé

Bài đã được tự động gộp: 16/7/21

Tại A2, copy xuống dưới

=(LEN(A$1)+2-LEN(SUBSTITUTE(1&A$1&1,1&REPT("0",ROW()-1)&1,"")))/(ROW()+1)

 

[Phuocam]

Mình có đính kèm file ví dụ mình dùng tay để đếm , bạn xem giúp mình nhé

Lần sau nhớ đính kèm file trong bài 1.

Thử công thức mảng này trong B2 và copy xuống:

=SUM(--(FREQUENCY(IF($A$1:$Z$1=0,COLUMN($A$1:$Z$1)),IF($A$1:$Z$1<>0,COLUMN($A$1:$Z$1)))=ROWS($B$2:B2)))

Nhớ kết thúc bằng Ctrl+Shift+Enter.

.

 

[Phan Thế Hiệp]

Lần sau nhớ đính kèm file trong bài 1. Thử công thức mảng này trong B2 và copy xuống:

=SUM(--(FREQUENCY(IF($A$1:$Z$1=0,COLUMN($A$1:$Z$1)),IF($A$1:$Z$1<>0,COLUMN($A$1:$Z$1)))=ROWS($B$2:B2)))

Nhớ kết thúc bằng Ctrl+Shift+Enter. .

Trường hợp của 'em' cũng muốn đếm như vậy, nhưng thay vì hiện số theo từng cột, dữ liệu của em gom chung vào ô A2 như vầy: '101110000110011110000100000111100010000011000000000011111110010101100
Và thống kê theo tiêu đề từ B1:AE1--> 1(số 0), 2(số 0),....,30(số 0). Với lại 'em' chưa biết dùng hàm Frequency()!? anh chơi hàm khác dùm em nha!

Cảm ơn anh, chúc anh ngày vui

___________________________________

Úy! Câu hỏi này đã giải ở bài #6 rồi!!
Giữ file hỏi cho vui với anh em.

 

[Phan Thế Hiệp]

Tại A2, copy xuống dưới

=(LEN(A$1)+2-LEN(SUBSTITUTE(1&A$1&1,1&REPT("0",ROW()-1)&1,"")))/(ROW()+1)

Hình như 1(số 0) có vấn đề!!

Do tìm theo "1&...&1", nên nếu có nhiều số đứng kề nhau như:...1010101..; hoặc ...111000100010001... Nó sẽ đếm sai.

Xem file kèm.

Thân

 

[Phuocam]

chưa biết dùng hàm Frequency()

Thử công thức mảng này trong B2:

=COUNT(1/(FIND(1&REPT(0,B1)&1,1&$A$2&1,ROW(INDIRECT("1:"&LEN($A$2)+1)))=ROW(INDIRECT("1:"&LEN($A$2)+1))))

Nếu Excel 365, gọn hơn một chút:

=COUNT(1/(FIND(1&REPT(0,B1)&1,1&$A$2&1,SEQUENCE(LEN($A$2)+1))=SEQUENCE(LEN($A$2)+1)))

.

 

[CHAOQUAY]

Hình như 1(số 0) có vấn đề!!

Do tìm theo "1&...&1", nên nếu có nhiều số đứng kề nhau như:...1010101..; hoặc ...111000100010001... Nó sẽ đếm sai.

Xem file kèm.

Thân

Bài này viết xong cũng nhận ra tính thiếu trường hợp dãy số liền kề, định sửa nhưng đầu bài thay đổi nên thôi.

 

[Binbo2020]

Giữ file hỏi cho vui với anh em

Tham gia tí cho vui chẳng biết đúng không

=SUMPRODUCT(--(SUBSTITUTE("101";"0";REPT("0";COLUMN(A1)))=MID("1"&$A$2&"1";ROW($A$1:$A$100);COLUMN(C2))))

 

[Phan Thế Hiệp]

Tổng hợp các cách giải hay ở trên của anh em, lưu chung vào bài này cho thành viên khác muốn tìm hiểu sẽ dễ tham khảo:

@CHAOQUAY: (giải pháp: tính hiệu số chiều dài chuỗi trừ chiều dài đã xóa ký tự 0, tương ứng với số lượng của nó theo yêu cầu)

=(LEN(SUBSTITUTE($A2,"1","11"))+2-LEN(SUBSTITUTE(1&SUBSTITUTE($A2,"1","11")&1,1&REPT("0",B$1)&1,"")))/(B$1+2)

@Phuocam: (giải pháp: tìm ký tự 0 với số lượng theo yêu cầu, so khớp với thứ tự vị trí phát sinh, đếm giá trị thỏa điều kiện)

=COUNT(INDEX(1/(FIND(1&REPT(0,B1)&1,1&$A$2&1,ROW(INDIRECT("1:"&LEN($A$2)+1)))=ROW(INDIRECT("1:"&LEN($A$2)+1))),))

=COUNT(1/(FIND(1&REPT(0,B1)&1,1&$A$2&1,SEQUENCE(LEN($A$2)+1))=SEQUENCE(LEN($A$2)+1))) (Excel 365)

@Binbo2020: (giải pháp: cắt chuỗi số theo số lượng yêu cầu, tạo thành mảng, rồi so khớp ký tự quy định, cộng các giá trị thỏa)

=SUMPRODUCT(--(SUBSTITUTE("101","0",REPT("0",COLUMN(A1)))=MID("1"&$A$2&"1",ROW($A$1:$A$100),COLUMN(C2))))

'@PTH: góp vui thêm 2 giải pháp:
1/ (giải pháp loại bỏ toàn bộ số 1 để tạo khoảng trắng giữa các chuỗi ký tự 0, cắt tạo mảng, rồi đếm các chiều dài thỏa điều kiện)

=SUMPRODUCT(N(LEN(TRIM(MID(SUBSTITUTE(TRIM(SUBSTITUTE($A$2,1," "))," ",REPT(" ",100)),(ROW($1:$30)-1)*100+1,100)))=B$1))

2/ (giải pháp thay thế các chuỗi ký tự 0 theo vị trí tuần tự xuất hiện, tìm và đếm các giá trị thỏa điều kiện)

=COUNT(INDEX(FIND("|",SUBSTITUTE(1&$A2&1,1&REPT("0",B$1)&1,"|",ROW(OFFSET($A$1,,,LEN($A2))))),))

Toàn bộ các công thức trên đều nhấn Enter.

Chúc anh em ngày vui.

 

[dazkangel]

Chung vui với mọi người.

=SUM(--(MID(1&$A2&1,ROW(OFFSET(A1,,,LEN($A2))),2+B1)=1&REPT(0,B1)&1))