Tặng các bạn Unicode Menu trong Userform - UMU (SourceCode)

Nguyễn Duy Tuân

Nghị Hách
Thành viên danh dự
Tham gia ngày
13 Tháng sáu 2006
Bài viết
4,176
Được thích
9,668
Điểm
860
Nơi ở
Hà Nội
UMU - Unicode Menu In Userform Version 1.2.2
Gửi tặng các bạn mã nguồn về tạo Unicode Menu trong Userform.


UMU - Unicode Menu In Userform là bộ mã nguồn (OpenSource) tạo menu trên userform trong VBA (Excel, Word,,...) với chuẩn unicode. Bộ mã thiết kế một menu ngang chuẩn và mở, người dùng chỉ cần nhập nội dung menu vào sheet "data", khi chạy menu sẽ lấy dữ liệu từ đó để hiển thị. Menu cho phép hiển thị: Radio, Checkbook, Image (ảnh), Label, Label với tiêu đề và mô tả, hiển thị với kiểu chữ, màu sắc phong phú. Khi download về chạy chắc chắn bạn sẽ thực sự nhạc nhiên...

Kỹ thuật lập trình trong bộ code menu trong userform này là ứng dụng hệ thống các hàm Windows API theo hệ unicode. Kỹ thuật lập trình này hay và mạnh nhưng không phải dễ học. Các bạn có thể cứ đưa vào ứng dụng rồi học dần dần.

Rất mong nhận được ý kiến góp ý của các bạn để UMU được hoàn thiện hơn.

Phiên bản mới nhất UniMenuInUserform 1.2.2, ngày 26/10/2015.

Download UniMenuInUserform v1.2.2

[GPECODE=vb]
'MODULE MenuAPIs
Public Declare Function CreateMenu Lib "user32.dll" () As Long
Public Declare Function CreatePopupMenu Lib "user32" () As Long
Public Declare Function SetMenu Lib "user32.dll" (ByVal hwnd As Long, ByVal hMenu As Long) As Long

Public Declare Function SetMenuItemBitmaps Lib "user32.dll" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long, ByVal hBitmapUnchecked As Long, ByVal hBitmapChecked As Long) As Long
Public Declare Function SetMenuItemInfo Lib "user32.dll" Alias "SetMenuItemInfoW" (ByVal hMenu As Long, ByVal un As Long, ByVal BOOL As Boolean, ByRef lpcMenuItemInfo As MENUITEMINFO) As Long
Public Declare Function SetMenuItemInfoStr Lib "user32.dll" Alias "SetMenuItemInfoW" (ByVal hMenu As Long, ByVal un As Long, ByVal BOOL As Boolean, ByRef lpcMenuItemInfo As MENUITEMINFO_STRINGDATA) As Long
Public Declare Function SetMenuItemInfoDATA Lib "user32.dll" Alias "SetMenuItemInfoW" (ByVal hMenu As Long, ByVal un As Long, ByVal BOOL As Boolean, ByRef lpcMenuItemInfo As MENUITEMINFO_USERDATA) As Long
Public Declare Function SetMenuContextHelpId Lib "user32.dll" (ByVal hMenu As Long, ByVal dW As Long) As Long
Public Declare Function SetMenuDefaultItem Lib "user32.dll" (ByVal hMenu As Long, ByVal uItem As Long, ByVal fByPos As Long) As Long
Public Declare Function InsertMenu Lib "user32.dll" Alias "InsertMenuW" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long, ByVal wIDNewItem As Long, ByVal lpNewItem As Any) As Long
Public Declare Function InsertMenuItem Lib "user32.dll" Alias "InsertMenuItemW" (ByVal hMenu As Long, ByVal un As Long, ByVal BOOL As Boolean, ByRef lpcMenuItemInfo As MENUITEMINFO) As Long
Public Declare Function InsertMenuItemDATA Lib "user32.dll" Alias "InsertMenuItemW" (ByVal hMenu As Long, ByVal un As Long, ByVal BOOL As Boolean, ByRef lpcMenuItemInfo As MENUITEMINFO_USERDATA) As Long
Public Declare Function AppendMenu Lib "user32" Alias "AppendMenuW" (ByVal hMenu As Long, ByVal wFlags As Long, ByVal wIDNewItem As Long, ByVal lpNewItem As Any) As Long

Public Declare Function DrawMenuBar Lib "user32.dll" (ByVal hwnd As Long) As Long
Public Declare Function CheckMenuItem Lib "user32.dll" (ByVal hMenu As Long, ByVal wIDCheckItem As Long, ByVal wCheck As Long) As Long
Public Declare Function CheckMenuRadioItem Lib "user32.dll" (ByVal hMenu As Long, ByVal un1 As Long, ByVal un2 As Long, ByVal un3 As Long, ByVal un4 As Long) As Long
Public Declare Function EnableMenuItem Lib "user32.dll" (ByVal hMenu As Long, ByVal wIDEnableItem As Long, ByVal wEnable As Long) As Long

Public Declare Function GetMenu Lib "user32" (ByVal hwnd As Long) As Long
Public Declare Function GetMenuItemCount Lib "user32" (ByVal hMenu As Long) As Long
Public Declare Function GetMenuString Lib "user32" Alias "GetMenuStringW" (ByVal hMenu As Long, ByVal wIDItem As Long, ByVal lpString As String, ByVal nMaxCount As Long, ByVal wFlag As Long) As Long
Public Declare Function GetMenuItemID Lib "user32" (ByVal hMenu As Long, ByVal nPos As Long) As Long
Public Declare Function GetSubMenu Lib "user32" (ByVal hMenu As Long, ByVal nPos As Long) As Long
Public Declare Function GetMenuItemInfo Lib "user32" Alias "GetMenuItemInfoW" (ByVal hMenu As Long, ByVal un As Long, ByVal b As Long, lpMenuItemInfo As MENUITEMINFO) As Long
Public Declare Function GetMenuItemInfoDATA Lib "user32" Alias "GetMenuItemInfoW" (ByVal hMenu As Long, ByVal un As Long, ByVal b As Long, lpMenuItemInfo As MENUITEMINFO_USERDATA) As Long
Public Declare Function GetMenuItemInfoStr Lib "user32" Alias "GetMenuItemInfoW" (ByVal hMenu As Long, ByVal un As Long, ByVal b As Long, lpMenuItemInfo As MENUITEMINFO_STRINGDATA) As Long
Public Declare Function GetMenuState Lib "user32" (ByVal hMenu As Long, ByVal wID As Long, ByVal wFlags As Long) As Long
Public Declare Function GetMenuItemRect Lib "user32" (ByVal hwnd As Long, ByVal hMenu As Long, ByVal uItem As Long, lprcItem As RECT) As Long
Public Declare Function GetMenuDefaultItem Lib "user32" (ByVal hMenu As Long, ByVal fByPos As Long, ByVal gmdiFlags As Long) As Long
Public Declare Function GetMenuContextHelpId Lib "user32" (ByVal hMenu As Long) As Long
Public Declare Function GetMenuCheckMarkDimensions Lib "user32" () As Long
Public Declare Function GetSystemMenu Lib "user32.dll" (ByVal hwnd As Long, ByVal bRevert As Long) As Long

Public Declare Function ModifyMenu Lib "user32.dll" Alias "ModifyMenuW" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long, ByVal wIDNewItem As Long, ByVal lpString As Any) As Long
Public Declare Function RemoveMenu Lib "user32.dll" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long
Public Declare Function DeleteMenu Lib "user32.dll" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long
Public Declare Function DestroyMenu Lib "user32" (ByVal hMenu As Long) As Long
Public Declare Function MenuItemFromPoint Lib "user32" (ByVal hwnd As Long, ByVal hMenu As Long, ByVal ptScreen As POINTAPI) As Long
Public Declare Function HiliteMenuItem Lib "user32" (ByVal hwnd As Long, ByVal hMenu As Long, ByVal wIDHiliteItem As Long, ByVal wHilite As Long) As Long
'CODE
Function ShortcutMenu(ByVal hSubMenu As Long) As Long 'OnRightClick
On Error GoTo EndFunc
Dim IDM&, UMU_MII As UMU_MenuItemInfo
Dim pt As POINTAPI, rc As RECT
Dim rngMenu As Range

If hSubMenu = 0 Then GoTo EndFunc

GetCursorPos pt
IDM = TrackPopupMenu(hSubMenu, TPM_RETURNCMD, pt.X, pt.Y, 0, GetActiveWindow, rc)
'Debug.Print IDM
If IDM = 0 Then GoTo EndFunc

OnCommand IDM

EndFunc:
ShortcutMenu = IDM
If Err.Number Then Debug.Print Err.Number, Err.Description
End Function

Function OnMeasureItemMenu(ByVal hwnd As Long, MI As MEASUREITEMSTRUCT) As Long

On Error GoTo EndFunc

Dim hdc&
Dim wstr1$, wstr2$, UMU_MII As UMU_MenuItemInfo
Dim Pic As StdPicture, sz As Size

'Get the information of menuitem
If GetMenuItemByID(MI.itemID, UMU_MII) < 0 Then
GoTo EndFunc
End If

'wstr1 = StrConv(UMU_MII.lpName, vbFromUnicode)
'wstr2 = StrConv(UMU_MII.lpDetails, vbFromUnicode)
wstr1 = UMU_MII.lpName
wstr2 = UMU_MII.lpDetails

If UMU_MII.BITMAP <> "" Then
Set Pic = GetPicture(UMU_MII.BITMAP) 'Picture
End If

hdc = GetDC(hwnd)
If (Not Pic Is Nothing) Then
MI.ItemWidth = Pic.Width \ DeltaScrX 'PicWidth
MI.ItemHeight = Pic.Height \ DeltaScrY 'PicHeight

MI.ItemHeight = MI.ItemHeight + 4
Else
If wstr2 <> "" Then 'MultiRow
MI.ItemHeight = PicHeight + 4 'The same pic's width
Else 'single row
MI.ItemHeight = mvarItemHeight
End If
End If

'Reset
If UMU_MII.ImgWidth > 0 Then
MI.ItemWidth = UMU_MII.ImgWidth 'PicWidth
End If
If UMU_MII.ImgHeight > 0 Then
MI.ItemHeight = UMU_MII.ImgHeight + 4 'PicHeight + 4
End If

If MI.ItemWidth < mvarItemHeight Then MI.ItemWidth = mvarItemHeight

If UMU_MII.lpName = "-" Then
If Theme = ThemeSystem Or Theme = ThemeOffice2000 Then
MI.ItemHeight = 11
Else
MI.ItemHeight = 5
End If
Else
If MI.ItemHeight < mvarItemHeight Then MI.ItemHeight = mvarItemHeight
End If
'Convert to unicode string
'wstr1 = StrConv(wstr1, vbUnicode)

GetTextExtentPointStr32 hdc, wstr1, Len(wstr1), sz
'Debug.Print wstr1, Len(wstr1) \ 2, sz.cx, mi.ItemWidth
MI.ItemWidth = MI.ItemWidth + sz.cx \ 2 + GetSystemMetrics(SM_CXMENUCHECK) + IIf(Pic Is Nothing, 24, 0)
ReleaseDC hwnd, hdc
Set Pic = Nothing
Exit Function
EndFunc:

If Err.Number <> 0 Then
Debug.Print "Error in OnMeasureItem Function: ", Err.Number, Err.Description
End If

End Function

Function OnDrawItemMenu(ByVal hwnd As Long, di As DRAWITEMSTRUCT) As Long

On Error GoTo EndFunc

Dim rc As RECT
Dim bSelected As Boolean, bEnabled As Boolean, bChecked As Boolean
Dim uflagDT&, clText&, hBr&, bmpHDC&, oldPic&, hFont&, hPrevFont&
Dim wstr1$, wstr2$, UMU_MII As UMU_MenuItemInfo
Dim Pic As StdPicture, br As LOGBRUSH, sz As Size, iArrMenu&

'Get the information of menuitem
iArrMenu = GetMenuItemByID(di.itemID, UMU_MII)
If iArrMenu < 0 Then
GoTo EndFunc
End If

wstr1 = UMU_MII.lpName
wstr2 = UMU_MII.lpDetails

'Convert to unicode string
'wstr1 = StrConv(wstr1, vbUnicode)
'wstr2 = StrConv(wstr2, vbUnicode)
UMU_MII.ImgWidth = UMU_MII.ImgWidth * DeltaScrX
UMU_MII.ImgHeight = UMU_MII.ImgHeight * DeltaScrY
If UMU_MII.BITMAP <> "" Then
Set Pic = GetPicture(UMU_MII.BITMAP) 'Picture
If Not Pic Is Nothing Then
If UMU_MII.ImgWidth <= 0 Then
UMU_MII.ImgWidth = Pic.Width
End If
If UMU_MII.ImgHeight <= 0 Then
UMU_MII.ImgHeight = Pic.Height
End If
End If
End If

'Set color
If DrawStyle = dsOwnerdraw Then
If UMU_MII.BkColor = 0 Or (mvarResetColors And UMU_MII.BkColor <> mvarBkColor) Then UMU_MII.BkColor = mvarBkColor
If UMU_MII.SelBkColor = 0 Or (mvarResetColors And UMU_MII.SelBkColor <> mvarSelBkColor) Then UMU_MII.SelBkColor = mvarSelBkColor
If UMU_MII.TextColor = 0 Or (mvarResetColors And UMU_MII.TextColor <> mvarTextColor) Then UMU_MII.TextColor = mvarTextColor
If UMU_MII.SelTextColor = 0 Or (mvarResetColors And UMU_MII.SelTextColor <> mvarSelTextColor) Then UMU_MII.SelTextColor = mvarSelTextColor
ElseIf DrawStyle = dsAuto Then
If UMU_MII.oldBkColor = 0 Then UMU_MII.BkColor = mvarBkColor
If UMU_MII.oldSelBkColor = 0 Then UMU_MII.SelBkColor = mvarSelBkColor
If UMU_MII.oldTextColor = 0 Then UMU_MII.TextColor = mvarTextColor
If UMU_MII.oldSelTextColor = 0 Then UMU_MII.SelTextColor = mvarSelTextColor
End If

bEnabled = Not ((di.itemState And ODS_DISABLED) = ODS_DISABLED)
bSelected = (di.itemState And ODS_SELECTED) = ODS_SELECTED
bChecked = (di.itemState And ODS_CHECKED) = ODS_CHECKED

If bSelected Then
br.lbColor = UMU_MII.SelBkColor 'GetSysColor(COLOR_HIGHLIGHT)
clText = UMU_MII.SelTextColor ' GetSysColor(COLOR_HIGHLIGHTTEXT) 'vbYellow '
Else
br.lbColor = UMU_MII.BkColor
If UMU_MII.lpName <> "" And UMU_MII.lpDetails <> "" Then
clText = UMU_MII.TextColor 'vbBlue
Else
clText = UMU_MII.TextColor 'GetSysColor(COLOR_MENUTEXT)
End If
End If

If Not bEnabled Then
clText = GetSysColor(COLOR_GRAYTEXT)
End If

rc = di.rcItem
SetTextColor di.hdc, clText
hBr = CreateBrushIndirect(br)

If bSelected Then
If bEnabled Then
If (Theme = ThemeOffice2000) Then

End If
FillRect di.hdc, rc, hBr
End If
Else
FillRect di.hdc, rc, hBr
End If

rc = di.rcItem
If Not Pic Is Nothing Then
bmpHDC = CreateCompatibleDC(di.hdc)
oldPic = SelectObject(bmpHDC, Pic.Handle)

'Debug.Print Err
'Debug.Print "pic.Handle", pic.Handle
'BitBlt di.hdc, di.rcItem.Left, di.rcItem.Top, pic.Width, pic.Height, bmpHDC, 0, 0, SRCCOPY 'NOTSRCCOPY
If Theme = ThemeOffice2000 Then
End If

StretchBlt di.hdc, di.rcItem.Left + 2, di.rcItem.Top + 2, UMU_MII.ImgWidth, _
UMU_MII.ImgHeight, bmpHDC, 0, 0, Pic.Width, Pic.Height, SRCCOPY

'SelectObject bmpHDC, oldPic
DeleteDC bmpHDC
DeleteObject oldPic
rc.Left = rc.Left + UMU_MII.ImgWidth \ DeltaScrX + 4
End If
DeleteObject hBr
SetBkMode di.hdc, Transparent
If Pic Is Nothing Then
rc.Left = rc.Left + GetSystemMetrics(SM_CXMENUCHECK) + 2
End If

rc.Left = rc.Left + 5
rc.Right = rc.Right - 1
If bChecked Or UMU_MII.GroupID > -1 Or UMU_MII.CtrlType = UMU_CtrlCheckBox Then
rc.Left = rc.Left + 5
End If
If wstr2 <> "" Then
rc.Top = rc.Top + 2
hFont = CreateFont(-MulDiv(8, GetDeviceCaps(di.hdc, LOGPIXELSY), 72), 0, 0, 0, FW_EXTRABOLD, 0, 0, 0, 0, 0, 0, 0, 0, StrPtr("Tahoma"))
hPrevFont = SelectObject(di.hdc, hFont)
If Pic Is Nothing Then
DrawText di.hdc, StrPtr(wstr1), Len(wstr1), rc, DT_LEFT
Else
DrawText di.hdc, StrPtr(wstr1), Len(wstr1), rc, DT_CENTER
End If
GetTextExtentPoint32 di.hdc, wstr1, Len(wstr1), sz
If hPrevFont <> 0 Then
SelectObject di.hdc, hPrevFont
End If
DeleteObject hFont '//DeleteObject SelectObject (di.hdc, hPrevFont)
Else 'Single line
DrawText di.hdc, StrPtr(wstr1), Len(wstr1), rc, DT_LEFT Or DT_SINGLELINE Or DT_VCENTER
End If

If wstr2 <> "" Then
rc.Top = rc.Top + sz.cy + 3
rc.Left = rc.Left + IIf(Pic Is Nothing, 0, 2)
DrawText di.hdc, StrPtr(wstr2), Len(wstr2), rc, DT_LEFT Or DT_WORDBREAK
End If

' Separator:
If UMU_MII.bSeparator Then
rc = di.rcItem
rc.Top = (rc.Bottom - rc.Top - 2) \ 2 + rc.Top
rc.Bottom = rc.Top + 2
If (Theme = ThemeOffice2000) Then
End If
DrawEdge di.hdc, rc, BDR_SUNKENOUTER, BF_TOP Or BF_BOTTOM
End If

If (Theme = ThemeOffice2000) Then
End If

If bChecked Then
rc = di.rcItem
rc.Right = 20
If Pic Is Nothing Then
If Not bEnabled Then
SetTextColor di.hdc, GetSysColor(COLOR_GRAYTEXT)
ElseIf Theme = ThemeOffice2000 Then
End If
hFont = CreateFont(-MulDiv(10, GetDeviceCaps(di.hdc, LOGPIXELSY), 72), 0, 0, 0, FW_SEMIBOLD, 0, 0, 0, SYMBOL_CHARSET, 0, 0, 0, 0, StrPtr("Marlett"))
hPrevFont = SelectObject(di.hdc, hFont)
If UMU_MII.GroupID > -1 Then 'Radio
DrawText di.hdc, StrPtr("h"), Len("h"), rc, DT_CENTER Or DT_VCENTER Or DT_SINGLELINE
Else
DrawText di.hdc, StrPtr("a"), Len("a"), rc, DT_CENTER Or DT_VCENTER Or DT_SINGLELINE
End If
DeleteObject SelectObject(di.hdc, hPrevFont)
End If
End If

Set Pic = Nothing
Exit Function
EndFunc:

If Err.Number <> 0 Then
Debug.Print "Error in OnDrawItem Function: ", Err.Number, Err.Description
End If

End Function
[/GPECODE]

Nếu thấy hay xin đừng quên "Cảm ơn" %#^#$!
 

File đính kèm

Lần chỉnh sửa cuối:

sealand

Thành viên gạo cội
Tham gia ngày
16 Tháng năm 2008
Bài viết
4,877
Được thích
7,755
Điểm
860
Tuổi
60
Nơi ở
Hải Phòng
Mình sẽ cố vận dụng, thêm 1 bước hoàn thiện chức năng của Excel cho người SD đại chúng. (Rất tiếc là Dowmload Manager của mình quá 15 ngày dâng không down được)
 

tedaynui

(*_*)
Thành viên danh dự
Tham gia ngày
12 Tháng tám 2006
Bài viết
1,877
Được thích
2,454
Điểm
860
Nơi ở
TP.HCM
Chào Tuân,
Mình test trên máy của mình thấy chưa ổn lắm.

Cảm ơn
TDN
 

File đính kèm

Chỉnh sửa lần cuối bởi điều hành viên:

Nguyễn Duy Tuân

Nghị Hách
Thành viên danh dự
Tham gia ngày
13 Tháng sáu 2006
Bài viết
4,176
Được thích
9,668
Điểm
860
Nơi ở
Hà Nội
Chào Tuân,
Mình test trên máy của mình thấy chưa ổn lắm.

Cảm ơn
TDN
Như hình của anh thì có phải là lỗi hiện chữ unicode trên caption/title của form không anh ? Theo chế độ ngầm định của Windows XP thì font dùng cho caption của form không phải là font unicode, anh cần phải thay bằng các font unicode: Tahoma, Time New Roman, ... Để thay đổi, anh vào Control Pane->Display->Appearance->Advance...
 

Mr Okebab

Ngon Ngất Ngây
Thành viên đã mất
Tham gia ngày
6 Tháng tám 2006
Bài viết
3,262
Được thích
3,762
Điểm
0
Tuổi
42
Nếu để Font mặc định của Bill thì không được à bác??
Có cách nào theo Font mặc định của Bill không??
Hoặc là khi chương trình Active thì Wins theo Font Unicode, còn nếu Deactive thì trả lại cho Bill.

Cảm ơn bác.

Thân!
 

Nguyễn Duy Tuân

Nghị Hách
Thành viên danh dự
Tham gia ngày
13 Tháng sáu 2006
Bài viết
4,176
Được thích
9,668
Điểm
860
Nơi ở
Hà Nội
Nếu để Font mặc định của Bill thì không được à bác??
Có cách nào theo Font mặc định của Bill không??
Với font mặc định của Bill thì tất cả các chương trình viết chuẩn unicode, nếu caption với chữ có dấu đều không hiện được đúng, ngay cả Firefox, IE, Excel,... Bab cứ để ý sẽ thấy.

Nếu vẫn để font mặc định mà hiện được chữ có dấu trên caption thì có một cách là vẽ cấy một control lên đó, ví dụ tạo một control label, sau đó đặt nó lên caption. Cái này tớ có thể làm được nhưng có lẽ không cần (?).

Hoặc là khi chương trình Active thì Wins theo Font Unicode, còn nếu Deactive thì trả lại cho Bill.

Cảm ơn bác.

Thân!
Cái này làm được nhưng tiến trình thay đổi sẽ mất vài giây, điều này có thể gây sự khó chịu cho người dùng? Thời gian phải đợi giống như người dùng làm bằng tay để thay đổi. Mà việc này nên xử lý trong một ứng dụng hơn là làm trong form để tất cả các form của chương trình được thừa hưởng.

Mã:
Sub Main()
     
      If Not IsUniCaptionFont() Then
             SetUniCaptionFont("Tahoma")
      End If

      '..............Các lệnh, các form trong quá trình chạy của chương trình

      If CaptionFontChanged() Then
             RestoreCaptionFont()
      End If
     
End Sub
 

trungnt

Thành viên hoạt động
Tham gia ngày
2 Tháng hai 2007
Bài viết
135
Được thích
87
Điểm
680
Tuổi
43
Em cũng đã text thử và đã chuyển qua Font Unicode rồi mà sao Form vẫn hiện lên chưa ổn...... Nhờ a Tuấn xem giúp!

 

File đính kèm

Chỉnh sửa lần cuối bởi điều hành viên:

cavoi

Thành viên mới
Tham gia ngày
29 Tháng mười 2008
Bài viết
43
Được thích
5
Điểm
0
Tuổi
29
CV download về sử dụng tốt, không có trục trặc gì hết
cám ơn anh TuanVNUNI nhe
 

levanduyet

Thành viên gắn bó
Thành viên danh dự
Tham gia ngày
30 Tháng năm 2006
Bài viết
1,785
Được thích
4,533
Điểm
860
Nơi ở
HCM
To: Tuân,

Còn việc các cấp độ Menu thì như thế nào? Rồi còn cái Combobox trong Menu nữa !
Đã sử dụng, thấy không có bị lỗi. Cám ơn Tuân nhiều.

Lê Văn Duyệt
 

Nguyễn Duy Tuân

Nghị Hách
Thành viên danh dự
Tham gia ngày
13 Tháng sáu 2006
Bài viết
4,176
Được thích
9,668
Điểm
860
Nơi ở
Hà Nội
Em cũng đã text thử và đã chuyển qua Font Unicode rồi mà sao Form vẫn hiện lên chưa ổn...... Nhờ a Tuấn xem giúp!
Hiện tại, theo chế độ đặt Theme "Classic" thì font trên caption của form bị lỗi, lỗi này mình sẽ tìm hiểu thêm.

To: Tuân,

Còn việc các cấp độ Menu thì như thế nào? Rồi còn cái Combobox trong Menu nữa !
Đã sử dụng, thấy không có bị lỗi. Cám ơn Tuân nhiều.

Lê Văn Duyệt
Các cấp độ của menu có thể trong thời gian ngắn em sẽ gửi tiếp phiên bản mới của UMU. Việc gắn ComboBox trong các item của menu có lẽ hơi khó +-+-+-+ . Em sẽ tranh thủ time làm tiếp cho hoàn thiện.
 

ThuNghi

Hãy cho rồi sẽ nhận!
Thành viên danh dự
Tham gia ngày
16 Tháng tám 2006
Bài viết
3,814
Được thích
4,452
Điểm
860
Hôm qua có đụng gì trong phần About, không nhớ là double hay RC mà máy treo luôn. Phải thóat = 3 nút. Chắc là tràn bộ nhớ.
 

Nguyễn Duy Tuân

Nghị Hách
Thành viên danh dự
Tham gia ngày
13 Tháng sáu 2006
Bài viết
4,176
Được thích
9,668
Điểm
860
Nơi ở
Hà Nội
Hướng dẫn chỉnh sửa, thêm menu kiểu "About"

Hôm qua có đụng gì trong phần About, không nhớ là double hay RC mà máy treo luôn. Phải thóat = 3 nút. Chắc là tràn bộ nhớ.
Riêng menu "About..." là em sử dụng chế độ vẽ Custom ( có cờ hiệu MF_OWNERDRAW).

Mã:
Function CreateMenuInUserform(ByVal frm As UserForm) As Long

   ....

    'Menu "About"
    hPopUpMenu = CreatePopupMenu()
    mnErr = AppendMenu(hPopUpMenu, MF_BYCOMMAND Or MF_BITMAP Or MF_OWNERDRAW, 1000, ByVal 0&) [COLOR="SeaGreen"]'Sheet1.PicKhanh.Picture.Handle[/COLOR]
    mnErr = AppendMenu(hPopUpMenu, MF_BYCOMMAND Or MF_BITMAP Or MF_OWNERDRAW, 1001, ByVal 0&) [COLOR="SeaGreen"]'Sheet1.PicTuyet.Picture.Handle[/COLOR]
    mnErr = AppendMenu(hPopUpMenu, MF_BYCOMMAND Or MF_BITMAP Or MF_OWNERDRAW, 1003, ByVal 0&) [COLOR="SeaGreen"]'Sheet1.PicTuan.Picture.Handle[/COLOR]

   'Gắn menu "About..." lên menu bar
    mnErr = AppendMenu(hMenu, MF_BYPOSITION Or MF_POPUP, hPopUpMenu, StrPtr("[B]About...[/B]"))

    ...

End Function
Các con số 1000, 1001, 1002 là ID của menu item (hiểu như mã hàng hóa, mã nhân viên, số chứng minh), mã này là cơ sở để thực hiện việc vẽ và chạy lệnh sau này.

Việc vẽ được thực hiện trong hàm WinProc, trong nhánh code Case WM_DRAWITEM

Mã:
Private Function WinProc(ByVal hwnd As Long, ByVal uMsg As Long, _
                            ByVal wParam As Long, ByVal lParam As Long) As Long
   ...

                'Xác lập đối tượng vẽ theo từng menu item, mỗi đối tượng có 3 thông tin: Ảnh (Image), Tên, Sở thích.

                If di.itemID = 1000 Then [COLOR="SeaGreen"]'Nguyễn Duy Khánh[/COLOR]
                    Set pic = Sheet1.PicKhanh.Picture
                    wstr1 = Range("G17").Value
                    wstr2 = Range("H17").Value
                ElseIf di.itemID = 1001 Then[COLOR="SeaGreen"]'Nguyễn Thị Tuyết[/COLOR]
                    Set pic = Sheet1.PicTuyet.Picture
                    wstr1 = Range("G18").Value
                    wstr2 = Range("H18").Value
                Else '[COLOR="SeaGreen"]'Nguyễn Duy Tuân[/COLOR]
                    Set pic = Sheet1.PicTuan.Picture
                    wstr1 = Range("G19").Value
                    wstr2 = Range("H19").Value
                End If
   ...
End Function
Nếu anh muốn thêm hay sửa kiểu menu "About..." thì hãy chỉ quan tâm tới những hướng dẫn trên của em là được. Lưu ý các lệnh trong hàm WinPro phải được viết tuyêt đối chính xác, chỉ cần một lỗi nhỏ là phải nhấn 3 nút đó! **~** Vì form, mất quyền điều khiển. Cái này có thể trong phiên bản sau em bổ sung việc bẫy lỗi.

Tạm thời mọi người chưa nên nhúng vào ứng dụng của mình ngay mà nên đọc code để tìm hiểu, trong tuần này tôi sẽ hoàn thiện về cấu trúc dữ liệu cho menu, để sau này chúng ta có thể áp dụng cho các trường hợp tổng quát, khi đó các bạn có thể yên tâm nhúng vào ứng dụng của mình.
 
Lần chỉnh sửa cuối:

sealand

Thành viên gạo cội
Tham gia ngày
16 Tháng năm 2008
Bài viết
4,877
Được thích
7,755
Điểm
860
Tuổi
60
Nơi ở
Hải Phòng
Đã tải về mở thử thấy hoạt động khá linh hoạt, nhưng lỗi font trên menu.
Xem nội dung thì thực sự giật mình chắc là phải lâu lâu mới thấm được, mong các bạn hợp tác trao đổi, các Mod. chỉ bảo để dần nắm được cơ bản. Đây là kỹ thuật quá cao so với VBA.
Nhưng cái gì cũng có giá của nó, làm chủ được thì tiếp tục đẩy Excel thoát xa phần mềm bảng tính. Mình cho đây thực sự là "Giải pháp Excel"
 

Mr Okebab

Ngon Ngất Ngây
Thành viên đã mất
Tham gia ngày
6 Tháng tám 2006
Bài viết
3,262
Được thích
3,762
Điểm
0
Tuổi
42
Cái này làm được nhưng tiến trình thay đổi sẽ mất vài giây, điều này có thể gây sự khó chịu cho người dùng? Thời gian phải đợi giống như người dùng làm bằng tay để thay đổi. Mà việc này nên xử lý trong một ứng dụng hơn là làm trong form để tất cả các form của chương trình được thừa hưởng.
[/code]
Đúng đó, mình đang nói đến là một chương trình (tạm gọi ở đây chương trình của bác chỉ có 1 form--=0)
Mấy giây không quan trọng bằng việc gây khó dễ cho người sử dụng.
Nếu có Code để Set cái đó thì Code như thế nào nhỉ ?? Có thể chia sẻ được không ??

Thực ra làm 1 File .reg để chạy luôn cũng được, mỗi lần SET thì chỉ việc chạy file đó để nó chỉnh trong registry.
Tuy nhiên muốn thực hiện hoàn toàn bằng VBA thì như thế nào ?? (Dĩ nhiên không phải lệnh chạy file .reg đó--=0)

Thân!
 

hai2hai

VNUNi®
Thành viên danh dự
Tham gia ngày
14 Tháng sáu 2006
Bài viết
1,138
Được thích
2,396
Điểm
860
Nơi ở
ĐT: 024-2242 5829
Nếu có Code để Set cái đó thì Code như thế nào nhỉ ?? Có thể chia sẻ được không ??

Thực ra làm 1 File .reg để chạy luôn cũng được, mỗi lần SET thì chỉ việc chạy file đó để nó chỉnh trong registry.
Tuy nhiên muốn thực hiện hoàn toàn bằng VBA thì như thế nào ?? (Dĩ nhiên không phải lệnh chạy file .reg đó--=0)

Thân!
Ví dụ về thay đổi font hệ thống (tiếng Việt hẳn hoi nhé :-=):

http://www.ddth.com/showthread.php?t=27279
http://www.ddth.com/showthread.php?t=16687
 
Lần chỉnh sửa cuối:

levanduyet

Thành viên gắn bó
Thành viên danh dự
Tham gia ngày
30 Tháng năm 2006
Bài viết
1,785
Được thích
4,533
Điểm
860
Nơi ở
HCM
Việc thay đổi font hệ thống, theo ý kiến của cá nhân tôi thì không nên.
Trước đây tôi cũng viết theo dạng:
Bước 1: Trước khi thực hiện ứng dụng của mình thì mình đổi font.
Bước 2: Thực hiện ứng dụng.
Bước 3: Trả lại font cho hệ thống.

Nhưng như vậy, đôi lúc người dùng sử dụng một lúc nhiều ứng dụng thì có thể việc đổi font này sẽ gây khó chịu cho người dùng.

LVD
 

hai2hai

VNUNi®
Thành viên danh dự
Tham gia ngày
14 Tháng sáu 2006
Bài viết
1,138
Được thích
2,396
Điểm
860
Nơi ở
ĐT: 024-2242 5829
Việc thay đổi font hệ thống, theo ý kiến của cá nhân tôi thì không nên
....

Nhưng như vậy, đôi lúc người dùng sử dụng một lúc nhiều ứng dụng thì có thể việc đổi font này sẽ gây khó chịu cho người dùng.

LVD
Nên hay ko nên là do chủ ý của từng người về cách viết ứng dụng mà. Em thì ko làm cái việc thay đổi font hệ thống (hay bất cứ cái gì của Windows) bao giờ vì như anh nói, nếu giả sử thay đổi font khi bắt đầu khởi động phần mềm, sau đó mình vào Appearance để đổi lại như cũ trong khi ứng dụng của mình vẫn đang hoạt động thì chả có ý nghĩa gì.

Tóm lại, 1 bước đơn giản: Nếu muốn thì người dùng tự đổi hoặc có chỗ trong phần mềm giúp người dùng làm việc đó chứ ko automatic.

Còn như ở trên là do Bab hỏi việc đó thực hiện trong code như thế nào thì em chỉ tìm hộ code thôi (hỏi súng hỏi dao thì tìm hộ, còn sử dụng thế nào, giết ai thì ...kệ :-=). Vậy code đó dùng như thế nào thì ... kệ bắb (chắc Bab chả care tới chuyện này làm gì đâu nhỉ)
 
Lần chỉnh sửa cuối:

Nguyễn Duy Tuân

Nghị Hách
Thành viên danh dự
Tham gia ngày
13 Tháng sáu 2006
Bài viết
4,176
Được thích
9,668
Điểm
860
Nơi ở
Hà Nội
Phiên bản mới UMU v1.1.0, ngày 15/12/08

UMU - Unicode Menu In Userform
Phiên bản mới 1.1.0
Ngày cập nhật: 15-12-2008



Tính năng mới:

+ Sửa lại cấu trúc bảng dữ liệu cho menu trong sheet "Menu Data".
+ Thêm sheet "Images" để chứa các đối tượng ảnh: Image(trong Control Toolbox), ImageList (trong MSCOMCTL.OCX).
+ Toàn bộ mã nguồn được tinh chỉnh lại, viết trong Class Module, làm việc tốt hơn.
+ Nâng cấp, cho phép tạo menu nhiều cấp (không giới hạn) nhờ vào cấu trúc bảng dữ liệu tổng thể.
+ Thêm, tạo ảnh trong các menu item, các popup menu, kích cỡ ảnh người dùng có thể tùy ý thiết lập.
Lưu ý, ảnh được đưa vào đối tượng Image (trong Control Toolbox) hoặc ImageList (trong MSCOMCTL.OCX).
Nếu ảnh trong ImageList, hãy nhập số Index của ảnh vào cột BITMAP, còn nếu dùng ảnh của Image thì dùng tên của nó (Image.Name).
+ Thêm, xử lý các menu item loại CheckBox, Radio.
+ Thêm, cho phép tùy biến về màu sắc của menu.
+ Thêm, tùy biến để menu cho Windows vẽ hoặc để chương trình tự vẽ thông qua tùy chọn của cột OWNERDRAW
Nếu là FALSE thì Windows tự quản lý việc vẽ (giống như các menu cơ bản của các ứng dụng trong Windows)
Nếu là TRUE thì chương trình quản lý và vẽ toàn bộ menu item, nhờ tùy chọn này mà các menu item sẽ được tô điểm đẹp hơn.
Menu có thể được vẽ đẹp hay không là do các lệnh vẽ trong hàm OnDrawItemMenu.
+ Thêm kiểu vẽ cho menu:
System (default): Để Windows vẽ theo chế độ thường
OwnerDrawL: chương trình vẽ lại toàn bộ
Auto: chương trình tự nhận biết để vẽ,...
+ Thêm, cho phép thêm menu vào menu hệ thống (System Menu).
+ Thêm, cho phép đặt menu bên phải của form.
+ Có thể thay đổi thiết lập cho menu trong chế độ chạy.

Thông tin chi tiết mời các bạn xem tại website: http://www.bluesofts.net

Tác giả rất mong các bạn góp ý thêm để chương trình được hoàn thiện hơn.

Các bạn có thể download phiên bản v1.1.0 tại trang đầu.
 

anhthuan

Thành viên hoạt động
Tham gia ngày
10 Tháng mười hai 2006
Bài viết
106
Được thích
264
Điểm
695
Tuổi
39
Quá tuyệt vời. Xin cảm ơn tác giả nhiều. Và cũng xin mạn phép tác giả cho em xử dụng miễn phí chương trình này vào ứng dụng của em nhé.

Cảm ơn,
 
Top Bottom