Tính tổng số ngày trong năm tính từ ngày thứ năm thứ 3 đến cuối tháng (2 người xem)

[bebo021999]

Trên 1 trang web Excel nước ngoài, có người hỏi như sau:
Hàng tháng công ty sẽ bán hàng ưu đãi từ ngày thứ năm thứ 3 tính từ đầu tháng cho đến cuối tháng. Vậy trong 1 năm, VD: năm 2020, tổng số ngày ưu đãi là bao nhiêu ngày? (Đáp số 145 ngày)
Yêu cầu: Không dùng VBA, không dùng cột phụ.
Tôi chi tiết ra cho rõ:
VD:
Tháng 1: Thứ năm thứ 3 là ngày 16/1/2020, tính đến cuối tháng là 16 ngày
Tháng 2:....
Tháng 12: ...
Cả năm: 145 ngày

Mời các bạn tham gia.

 

[Mộng Thường 2001]

Trên 1 trang web Excel nước ngoài, có người hỏi như sau:
Hàng tháng công ty sẽ bán hàng ưu đãi từ ngày thứ năm thứ 3 tính từ đầu tháng cho đến cuối tháng. Vậy trong 1 năm, VD: năm 2020, tổng số ngày ưu đãi là bao nhiêu ngày? (Đáp số 145 ngày)
Yêu cầu: Không dùng VBA, không dùng cột phụ.
Tôi chi tiết ra cho rõ:
VD:
Tháng 1: Thứ năm thứ 3 là ngày 16/1/2020, tính đến cuối tháng là 16 ngày
Tháng 2:....
Tháng 12: ...
Cả năm: 145 ngày

Mời các bạn tham gia.

A1=01/01/2018

=SUMPRODUCT(EOMONTH(EDATE(A1,ROW(1:12)-1),0)-WORKDAY.INTL(EDATE(A1,ROW(1:12)-1)-1,3,"1110111")+1)

hihi ^o^

 

[bebo021999]

Mình là ra rồi mà dài quá. Kết quả của bác trừ đi 12 là OK.

Chắc của bác là ngắn nhất rồi. Không biết còn cao thủ nào tham gia nữa không?

 

[Mộng Thường 2001]

Mình là ra rồi mà dài quá. Kết quả của bác trừ đi 12 là OK.

Chắc của bác là ngắn nhất rồi. Không biết còn cao thủ nào tham gia nữa không?

Vẫn chưa hiểu tại sao phải trừ 12!?
Nếu chỉ trừ cách khoảng thì xóa +1.
=SUMPRODUCT(EOMONTH(EDATE(A1,ROW(1:12)-1),0)-WORKDAY.INTL(EDATE(A1,ROW(1:12)-1)-1,3,"1110111"))
hihi ^o^

 

[dazkangel]

Vẫn chưa hiểu tại sao phải trừ 12!?
Nếu chỉ trừ cách khoảng thì xóa +1.
=SUMPRODUCT(EOMONTH(EDATE(A1,ROW(1:12)-1),0)-WORKDAY.INTL(EDATE(A1,ROW(1:12)-1)-1,3,"1110111"))
hihi ^o^

khúc đầu bỏ edate ngắn đc chút nữa anh

 

[Mộng Thường 2001]

khúc đầu bỏ edate ngắn đc chút nữa anh

Bỏ EDATE() khúc đầu thì lấy đâu 12 ngày cuối tháng bù vô đủ! em trai! hihi ^o^.
Công thức gồm: 12 ngày cuối tháng trừ 12 ngày thứ 5, lần 3, trong tháng, xong cộng lại.
Có cột diễn giải E, F của 24 ngày đó em!

 

[Mộng Thường 2001]

khúc đầu bỏ edate ngắn đc chút nữa anh

À! còn 1 cách nữa:
=EOMONTH(A1,11)-A1+1-SUMPRODUCT(DAY(WORKDAY.INTL(EDATE(A1,ROW(1:12)-1)-1,3,"1110111")))
hihi ^o^

 

[ndu96081631]

Với A1 là ngày bất kỳ thì ngày thứ năm đầu tiên của tháng là:

=A1-DAY(A1)+7-MOD(A1-DAY(A1)-5,7)

Vậy ngày thứ năm lần thứ 3 là cộng thêm 14 vào kết quả trên:

=A1-DAY(A1)+7-MOD(A1-DAY(A1)-5,7) +14

(Ngày cuối tháng thì ta biết cách tính rồi)
Vậy nếu cho trước cell E4 là năm thì tổng số ngày ưu đãi theo yêu cầu bài 1 là:

=SUMPRODUCT(DATE(E4,ROW(2:13),0)-DATE(E4,ROW(1:12),1)+MOD(DATE(E4,ROW(1:12),1)-6,7)-20)

Công thức áp dụng cho mọi phiên bản Excel (vì WORKDAY.INTL gì gì đó chỉ áp dụng được từ Excel 2010)

 

[huuthang_bd]

Mình xài đồ cũ

=EDATE(A1,12)-A1-SUMPRODUCT(14+MOD(12-WEEKDAY(EDATE(A1,ROW(1:12)-1)),7))

 

[dazkangel]

Bỏ EDATE() khúc đầu thì lấy đâu 12 ngày cuối tháng bù vô đủ! em trai! hihi ^o^.
Công thức gồm: 12 ngày cuối tháng trừ 12 ngày thứ 5, lần 3, trong tháng, xong cộng lại.
Có cột diễn giải E, F của 24 ngày đó em!

Là dư lày

=SUMPRODUCT(EOMONTH(A1,ROW(1:12)-1)-WORKDAY.INTL(EDATE(A1,ROW(1:12)-1)-1,3,"1110111")+1)