Tính tổng công bằng cách tổng hợp ký tự (1 người xem)

[lehuong1409]

Em có 1 file tổng hợp công như file đính kèm. Với chữ x thể hiện cho 1 ngày công, dấu / thể hiện cho nửa ngày công
trong tháng sẽ phát sinh xx là 2 công, x/ hoặc /x là 1,5 công do vậy em muốn tìm 1 công thức để đếm trong dãy đó có bao nhiêu chữ x và bao nhiêu dấu / thay vì làm hàm countif từng đoạn như file đính kèm. Mong các anh chị và các bạn giúp đỡ ạ. Em cảm ơn ạ

T6	T7	CN	T2	T3	T4
x	x	x/	x	x	x
x	x	x	x	x	x
x	x	x/	x	x	x
x	x	x/	x	x	x
/	x	x/	x	x	x
x	x	x	/	/	x
5,5	6	8	5,5	5,5	6

 

[SA_DQ]

Em có 1 file tổng hợp công như file đính kèm. Với chữ . . . xx là 2 công, . . . . .

Cơ quan bạn đang vi phạm Bộ Luật LĐ & ai giúp bạn là dung dưỡng cho hành vi sai luật!

 

[vu_tuan_manh_linh]

Cơ quan bạn đang vi phạm Bộ Luật LĐ & ai giúp bạn là dung dưỡng cho hành vi sai luật!

xxx thì còn mệt nữa bác ạ, vi phạm khá nhiều luật!!

 

[huuthang_bd]

Bạn thử vầy xem

=COUNTIF(C7:AG7,"*x*")+COUNTIF(C7:AG7,"*/*")/2+COUNTIF(C7:AG7,"xx")

 

[lehuong1409]

Cơ quan bạn đang vi phạm Bộ Luật LĐ & ai giúp bạn là dung dưỡng cho hành vi sai luật!

Dạ cái này là do cháu viết thế cho dễ hiểu thôi ạ. Đây là cách tính hệ số của từng công việc ạ. đơn giá 1 công không đổi nhưng công việc hoặc thời gian làm việc sẽ ảnh hưởng tới hệ số được tính ạ. Cháu làm giúp bằng Countif rồi nhưng muốn tìm hiểu thêm có cách nào hay hơn không thôi ạ

Bạn thử vầy xem

=COUNTIF(C7:AG7,"*x*")+COUNTIF(C7:AG7,"*/*")/2+COUNTIF(C7:AG7,"xx")

Dạ countif thì em làm được rồi ạ. em đang muốn tìm hàm nào hay hơn ý mà ạ

 

[huuthang_bd]

Dạ countif thì em làm được rồi ạ. em đang muốn tìm hàm nào hay hơn ý mà ạ

Theo tôi COUNTIF là hiệu quả nhất rồi còn bạn muốn hay hơn thì phải định nghĩa như thế nào là hay đối với bạn.
Công thức sau áp dụng được nếu dữ liệu chỉ bao gồm những trường hợp mà bạn mô tả.

=SUMPRODUCT(LEN(SUBSTITUTE(C7:AG7,"x","xx")))/2

 

[lehuong1409]

Theo tôi COUNTIF là hiệu quả nhất rồi còn bạn muốn hay hơn thì phải định nghĩa như thế nào là hay đối với bạn.
Công thức sau áp dụng được nếu dữ liệu chỉ bao gồm những trường hợp mà bạn mô tả.

=SUMPRODUCT(LEN(SUBSTITUTE(C7:AG7,"x","xx")))/2

Em cảm ơn anh ạ. Vì trong suy nghĩ thì em đang muốn tính x =1, /=0.5 mà chưa tìm được phương án nào đối với các ô riêng lẻ mà không sử dụng VBA nên em đưa lên xem sao ạ.

 

[hocexcel_1991]

Em có 1 file tổng hợp công như file đính kèm. Với chữ x thể hiện cho 1 ngày công, dấu / thể hiện cho nửa ngày công
trong tháng sẽ phát sinh xx là 2 công, x/ hoặc /x là 1,5 công do vậy em muốn tìm 1 công thức để đếm trong dãy đó có bao nhiêu chữ x và bao nhiêu dấu / thay vì làm hàm countif từng đoạn như file đính kèm. Mong các anh chị và các bạn giúp đỡ ạ. Em cảm ơn ạ

T6	T7	CN	T2	T3	T4
x	x	x/	x	x	x
x	x	x	x	x	x
x	x	x/	x	x	x
x	x	x/	x	x	x
/	x	x/	x	x	x
x	x	x	/	/	x
5,5	6	8	5,5	5,5	6

Bạn thử công thức này

=SUM(COUNTIFS(C7:AG7,{"X","X/","/","XX"})*{1,1.5,0.5,2})

 

[Nhattanktnn]

Góp vui:

=SUMPRODUCT(1.5*LEN(C7:AG7)-LEN(SUBSTITUTE(C7:AG7,"x",""))-LEN(SUBSTITUTE(C7:AG7,"/",""))/2)

 

[HieuCD]

Em có 1 file tổng hợp công như file đính kèm. Với chữ x thể hiện cho 1 ngày công, dấu / thể hiện cho nửa ngày công
trong tháng sẽ phát sinh xx là 2 công, x/ hoặc /x là 1,5 công do vậy em muốn tìm 1 công thức để đếm trong dãy đó có bao nhiêu chữ x và bao nhiêu dấu / thay vì làm hàm countif từng đoạn như file đính kèm. Mong các anh chị và các bạn giúp đỡ ạ. Em cảm ơn ạ

T6	T7	CN	T2	T3	T4
x	x	x/	x	x	x
x	x	x	x	x	x
x	x	x/	x	x	x
x	x	x/	x	x	x
/	x	x/	x	x	x
x	x	x	/	/	x
5,5	6	8	5,5	5,5	6

AH7 =SUMPRODUCT((C7:AG7={"x";"xx";"x/";"/"})*{1;2;1.5;0.5})

C14 =SUMPRODUCT((C7:C13={"x","xx","x/","/"})*{1,2,1.5,0.5})

 

[lehuong1409]

Bạn thử công thức này

=SUM(COUNTIFS(C7:AG7,{"X","X/","/","XX"})*{1,1.5,0.5,2})

Góp vui:

=SUMPRODUCT(1.5*LEN(C7:AG7)-LEN(SUBSTITUTE(C7:AG7,"x",""))-LEN(SUBSTITUTE(C7:AG7,"/",""))/2)

AH7 =SUMPRODUCT((C7:AG7={"x";"xx";"x/";"/"})*{1;2;1.5;0.5})

C14 =SUMPRODUCT((C7:C13={"x","xx","x/","/"})*{1,2,1.5,0.5})

Em cảm ơn mọi người ạ. sumproduct thần thánh thật ạ