Tính tổng có điều kiện; cho từng vùng không đều nhau trong cùng một cột (2 người xem)

[le_vis]

Nhờ các bạn kết hợp với hàm có sẵn trong FIle và tính tổng phân đoạn không đều có điều kiện - Chi tiết tôi xin được trình bày trong File đính kèm
Trân trọng cảm ơn

 

[snow25]

Nhờ các bạn kết hợp với hàm có sẵn trong FIle và tính tổng phân đoạn không đều có điều kiện - Chi tiết tôi xin được trình bày trong File đính kèm
Trân trọng cảm ơn

Chỉ được dùng các hàm có sẵn thôi à bạn.Không dùng cái khác được à.

 

[le_vis]

Chỉ được dùng các hàm có sẵn thôi à bạn.Không dùng cái khác được à.

Có thể mình dùng từ hơi tối nghĩa. Mình muốn trong File đã có hàm cộng trừ nhân chia rồi. Muốn kết hợp thêm hàm nào để khi đến dòng có từ CỘNG thì nó tự động tính tổng Từ đó ngước lên gặp Chữ CỘNG phía trên là một vùng cần tính tổng (Các vùng tính tổng không đều nhau như File đính kèm) - Cảm ơn bạn đã quan tâm - Xem giúp mình nhé

 

[snow25]

Có thể mình dùng từ hơi tối nghĩa. Mình muốn trong File đã có hàm cộng trừ nhân chia rồi. Muốn kết hợp thêm hàm nào để khi đến dòng có từ CỘNG thì nó tự động tính tổng Từ đó ngước lên gặp Chữ CỘNG phía trên là một vùng cần tính tổng (Các vùng tính tổng không đều nhau như File đính kèm) - Cảm ơn bạn đã quan tâm - Xem giúp mình nhé

Vậy cách không dùng hàm được không bạn.

 

[le_vis]

Vậy cách không dùng hàm được không bạn.

Không dùng hàm mà dùng VBA cũng được bạn ạ

 

[chucuoi92]

Không dùng hàm mà dùng VBA cũng được bạn ạ

Bạn xem công thức mảng trong file có đúng ý bạn không

 

[snow25]

Không dùng hàm mà dùng VBA cũng được bạn ạ

Đây bạn xem

 

[befaint]

J4=IF(F4="",IF(G4/26*H4=0,"",G4/26*H4),SUM(OFFSET($J$4,AGGREGATE(14,6,(ROW($D$4:D4)-3)*(LEFT($D$4:D4,2)<>"NV"),2),,AGGREGATE(14,6,(ROW($D$4:D4)-3)*(LEFT($D$4:D4,2)<>"NV"),1)-1-AGGREGATE(14,6,(ROW($D$4:D4)-3)*(LEFT($D$4:D4,2)<>"NV"),2))))
'Enter
'Kéo tụt tận dưới

 

[Phan Thế Hiệp]

Nhờ các bạn kết hợp với hàm có sẵn trong FIle và tính tổng phân đoạn không đều có điều kiện - Chi tiết tôi xin được trình bày trong File đính kèm
Trân trọng cảm ơn

Góp vui thêm 1 công thức khác:

J4=IF(F4="cộng",SUM(INDEX($J3:J$4,IFERROR(LOOKUP(2,1/("Cộng"=$F3:F$4),ROW($1:$50))+1,)):J3),G4/26*H4)

Enter, fill xuống.

Thân

 

[excel_lv1.5]

Nhờ các bạn kết hợp với hàm có sẵn trong FIle và tính tổng phân đoạn không đều có điều kiện - Chi tiết tôi xin được trình bày trong File đính kèm
Trân trọng cảm ơn

Cách khác, dùng công mảng thức này J4:

J4=IF(F4=$F$7,SUM(IF($F$3:F3="",1,-1)*$J$3:J3),G4/26*H4)

Bấm Ctrl+Shift+Enter rồi copy xuống!!!

 

[Phan Thế Hiệp]

Cách khác, dùng công mảng thức này J4:

J4=IF(F4=$F$7,SUM(IF($F$3:F3="",1,-1)*$J$3:J3),G4/26*H4)

Bấm Ctrl+Shift+Enter rồi copy xuống!!!

Ý hay!
Dựa trên ý đó, góp thêm công thức không nhấn CSE cũng được:

J4=IF(F4=$F$7,SUM(SUMIF($F$3:F3,{"","Cộng"},$J$3)*{1,-1}),G4/26*H4)
Hoặc:
J4=IF(F4=$F$7,SUM(SUMIF($F$3:F3,{"","<>"},$J$3)*{1,-1}),G4/26*H4)

Chỉ Enter, fill xuống.

Chúc anh em ngày vui.
Thân

 

[le_vis]

Ý hay!
Dựa trên ý đó, góp thêm công thức không nhấn CSE cũng được:

J4=IF(F4=$F$7,SUM(SUMIF($F$3:F3,{"","Cộng"},$J$3)*{1,-1}),G4/26*H4)
Hoặc:
J4=IF(F4=$F$7,SUM(SUMIF($F$3:F3,{"","<>"},$J$3)*{1,-1}),G4/26*H4)

Chỉ Enter, fill xuống.

Chúc anh em ngày vui.
Thân

Xin cảm ơn tất cả các bạn đã trợ giúp - Các công thức và code của snow25 đều chuẩn
Bạn excel_cl1.5 ơi bạn xem lại công thức này IF(F4=$F$7,SUM(IF($F$3:F3="",1,-1)*$J$3:J3),G4/26*H4) xuống tới cộng lần 2 trở xuống báo lỗi #VALUE! bạn nhé - Cảm ơn tất cả - Xin cảm ơn

 

[excel_lv1.5]

Xin cảm ơn tất cả các bạn đã trợ giúp - Các công thức và code của snow25 đều chuẩn
Bạn excel_cl1.5 ơi bạn xem lại công thức này IF(F4=$F$7,SUM(IF($F$3:F3="",1,-1)*$J$3:J3),G4/26*H4) xuống tới cộng lần 2 trở xuống báo lỗi #VALUE! bạn nhé - Cảm ơn tất cả - Xin cảm ơn

Bạn bấm Ctrl+Shift+Enter chưa!

 

[Ba Tê]

Công thức "cùi bắp" dành cho những người như tui không biết xài {...}

J4 =IF(F4="";G4/26*H4;SUMIF($F$3:F3;"";$J$3:J3)-SUMIF($F$3:F3;"C*";$J$3:J3))

 

[Phan Thế Hiệp]

Công thức "cùi bắp" dành cho những người như tui không biết xài {...}

J4 =IF(F4="";G4/26*H4;SUMIF($F$3:F3;"";$J$3:J3)-SUMIF($F$3:F3;"C*";$J$3:J3))

Vậy em chơi "cùi thơm" vầy nhen anh Ba

J4=IF(F4="cộng",SUM($J$3:J3)-SUMIF($F$3:F3,"<>",$J$3)*2,G4/26*H4)

Chỉ Enter, và cũng hổng có ngoặc ngoặc {...}.

Khà khà khà
Chúc anh ngày vui

 

[le_vis]

Bạn bấm Ctrl+Shift+Enter chưa!

Đã Ctrl+Shift+Enter thì xuống tới cộng lần 2 trở xuống báo lỗi #VALUE! . Còn nếu không Ctrl+Shift+Enter thì tất cả dòng "CỘNG" đều bị lỗi #VALUE! bạn ạ - Bạn kiểm tra lại giúp nhé - Xin cảm ơn

 

[Phan Thế Hiệp]

Đã Ctrl+Shift+Enter thì xuống tới cộng lần 2 trở xuống báo lỗi #VALUE! . Còn nếu không Ctrl+Shift+Enter thì tất cả dòng "CỘNG" đều bị lỗi #VALUE! bạn ạ - Bạn kiểm tra lại giúp nhé - Xin cảm ơn

Xem file kèm, tổng hợp các công thức ở trên.

Thân

 

[le_vis]

Xem file kèm, tổng hợp các công thức ở trên.

Thân

Cảm ơn thầy . Tôi đã hiểu còn đôi điều chưa hiểu thầy giải thích giúp đoạn tôi đánh dấu mầu đỏ Công thức này ==> IF(F4=$F$7;SUM(SUMIF($F$3:F3;{""\"<>"};$P$3)*{1\-1});G4/26*H4) Xin cảm ơn thầy

 

[Phan Thế Hiệp]

Cảm ơn thầy . Tôi đã hiểu còn đôi điều chưa hiểu thầy giải thích giúp đoạn tôi đánh dấu mầu đỏ Công thức này ==> IF(F4=$F$7;SUM(SUMIF($F$3:F3;{""\"<>"};$P$3)*{1\-1});G4/26*H4) Xin cảm ơn thầy

Cái đó là do hệ thống của bạn đang mặc định theo hệ Việt Nam: tức dấu "," phân cách phần thập phân, và dấu "." phân cách nhóm đơn vị.
Vì vậy, nó cũng ảnh hưởng và thay đổi khi thể hiện 1 Mảng hàng ngang, thay vì trong hệ thống của USA sẽ dùng ký hiệu dấu "," để phân cách phần tử mảng, thì với hệ thống của bạn nó sẽ đổi dấu "," thành dấu gạch chéo "\"

• Ví dụ: {A1=1 , B1=-1} hoặc {A1="" , B1="<>"} , tôi ghi A1, B1 để bạn hình dung nó liệt kê theo chiều ngang, nếu ghi đúng phải là {1 , -1} hoặc {"" , "<>"}
• Nay hệ thống của bạn thay đổi, nên thành ra: {1 \ -1} hoặc {"" \ "<>"}

Với công thức trên bạn có thể điều chỉnh theo mảng dọc cũng được:

=IF(F4=$F$7;SUM(SUMIF($F$3:F3;{"";"<>"};$P$3)*{1;-1});G4/26*H4)

Thân