Tìm khoảng giá trị trong 1 dãy số

[viendinhngoc]

Chào các bạn mình có vấn đề mong mọi ng giúp đỡ
Mình có cột x và y
giờ có giá trị X1 muốn tìm xem trong cột x nó thuộc khoảng nào thì có cách nào làm được mà đơn giản không
Ví dụ
có dãy số 1 3 6 8 9 15
thì số 5 sẽ thuộc vào (3,6)
mình xin cám ơn

 

[dhn46]

Với dữ lieu được sắp xếp tăng dần như File của bạn thì bạn tham khảo File. Còn không được sắp xếp thì tính cách khác

 

[viendinhngoc]

ah mình ngĩ có the dùng thêm hàm Match tìm ra vị trí < số cần tìm. và lớn hơn số càn tìm
rồi dùng Hlookup lấy ra giá trị thế có vẻ hoi lằng nhằng nhỉ
(dãy của mình là tăng hoặc giảm dần)

 

[mhung12005]

ah mình ngĩ có the dùng thêm hàm Match tìm ra vị trí < số cần tìm. và lớn hơn số càn tìm
rồi dùng Hlookup lấy ra giá trị thế có vẻ hoi lằng nhằng nhỉ
(dãy của mình là tăng hoặc giảm dần)

Bạn dùng thử cái này xem. Dữ liệu không cần sort cung được.

 

[huuthang_bd]

Giả sử dãy số ở vùng A1:A5, số cần tìm khoảng ở B1 thì:
Cận dưới

=SMALL(A1:A5,COUNTIF(A1:A5,"<="&B1))

Cận trên:

=LARGE(A1:A5,COUNTIF(A1:A5,">="&B1))

 

[viendinhngoc]

thank bạn nahs
àh mình có thắc mắc khi nào dùng dấu ngoặc kéo """ bạn nhỉ

 

[hungpecc1]

thank bạn nahs
àh mình có thắc mắc khi nào dùng dấu ngoặc kéo """ bạn nhỉ

Dùng ngoặc kép " " để đưa một string ( chuỗi ) vào công thức "

Cụ thể ở công thức :

=SMALL(A1:A5,COUNTIF(A1:A5,"<="&B1))

Trong hàm countif có vùng tiêu chuẩn (Ciriteria range) vùng điều khiện này có thể là số , văn bản , có thể kết hợp các phép toán >,< ,>=,<=

" < = " & B1 để excel hiểu được Ciriteria là <= giá trị ở ô B1

 

[tux_hn]

Nhờ các bác chỉ giúp, cũng bài toán trên nhưng có bổ sung thêm rất nhiều mã đơn vị thì dùng công thức thế nào ah.
Ví dụ như sau:
STT Họ và tên Mức 1 Mức 2 Mức 3 Mức 4 Mức 5
1 Oanh 10 12 14 16 18
2 Cường 11 13 15 17 19
3 Lan 10 12 14 16 18
.........
Dùng công thức nào để tìm dấu ?

STT Họ và tên Thực hiện Mức thấp Mức Cao
1 Oanh 12 ? ?
2 Cường 15,5 ? ?
3 Lan 14,1 ? ?
..........
Để cho kết quả như sau:

STT Họ và tên Thực hiện Mức thấp Mức Cao
1 Oanh 12 10 14
2 Cường 15,5 15 17
3 Lan 14,1 14 16

Trân trọng cảm ơn.

 

[quocgiacan]

Nhờ các bác chỉ giúp, cũng bài toán trên nhưng có bổ sung thêm rất nhiều mã đơn vị thì dùng công thức thế nào ah.
Ví dụ như sau:
STT Họ và tên Mức 1 Mức 2 Mức 3 Mức 4 Mức 5
1 Oanh 10 12 14 16 18
2 Cường 11 13 15 17 19
3 Lan 10 12 14 16 18
.........
Dùng công thức nào để tìm dấu ?

STT Họ và tên Thực hiện Mức thấp Mức Cao
1 Oanh 12 ? ?
2 Cường 15,5 ? ?
3 Lan 14,1 ? ?
..........
Để cho kết quả như sau:

STT Họ và tên Thực hiện Mức thấp Mức Cao
1 Oanh 12 10 14
2 Cường 15,5 15 17
3 Lan 14,1 14 16

Trân trọng cảm ơn.

Thử:

C9=LOOKUP($B9,OFFSET($B$1:$F$1,MATCH($A9,$A$2:$A$4,0),))
D9=C9+2

Chúc bạn ngày vui.

 

[tux_hn]

Cảm ơn bác.
C9=LOOKUP($B9,OFFSET($B$1:$F$1,MATCH($A9,$A$2:$A$4,0),)) đã tìm được giá trị nhỏ nhất, còn giá trị lớn nhất thì em không biết tìm thế nào. Ví dụ của em khoang cách là 2 nê D9=C9+2, nhưng thực tế nó không cách đều 2. Nhờ bác giúp em ah.

Cảm ơn bác

 

[quocgiacan]

Cảm ơn bác.
C9=LOOKUP($B9,OFFSET($B$1:$F$1,MATCH($A9,$A$2:$A$4,0),)) đã tìm được giá trị nhỏ nhất, còn giá trị lớn nhất thì em không biết tìm thế nào. Ví dụ của em khoang cách là 2 nê D9=C9+2, nhưng thực tế nó không cách đều 2. Nhờ bác giúp em ah.

Cảm ơn bác

Vậy đưa file thiệt lên đi bạn.

 

[tux_hn]

Dạ để em về nhà đưa lên ah. Ở cơ quan em mà đưa lên là ăn án kỷ luật luôn. Cảm ơn bác

 

[tux_hn]

Đây bác ah. Nhờ bác giúp đỡ.

 

[quocgiacan]

Đây bác ah. Nhờ bác giúp đỡ.

1. Tìm cận dưới:

D10=LOOKUP($C10,OFFSET($C$1:$G$1,MATCH($B10,$B$2:$B$4,0),))
Hoặc:
D10=AGGREGATE(14,6,ABS(((C10-OFFSET($C$1:$G$1,MATCH($B10,$B$2:$B$4,0),))^0.5)^2-C10),1)
Hoặc như:
D18=SMALL(OFFSET($C$1:$G$1,MATCH($B10,$B$2:$B$4,0),),COUNTIF(OFFSET($C$1:$G$1,MATCH($B10,$B$2:$B$4,0),),"<="&C18))

Enter fill xuống​

2. Tìm cận trên:

E10=AGGREGATE(15,6,((1/(1/(OFFSET($C$1:$G$1,MATCH($B10,$B$2:$B$4,0),)-C10)))^0.5)^2+C10,1)
Hoặc:
E10=OFFSET($B$1,MATCH($B10,$B$2:$B$4,0),MATCH($C10,OFFSET($C$1:$G$1,MATCH($B10,$B$2:$B$4,0),),1)+1)
Hoặc như:
E18=LARGE(OFFSET($C$1:$G$1,MATCH($B10,$B$2:$B$4,0),),COUNTIF(OFFSET($C$1:$G$1,MATCH($B10,$B$2:$B$4,0),),">="&C18))

Enter fill xuống​

Chúc bạn ngày vui.

 

[tux_hn]

Cảm ơn bác rất nhiều. Chúc bác cuối tuần vui vẻ ah.