Tìm giờ công và giờ tăng ca trong bảng chấm công? (1 người xem)

[KhaNhu1999]

Chào anh chị ạ!
Em có bảng chấm công như thế này, anh chị giúp em công thức ở chỗ Giờ công (H5) và Giờ tăng ca (I5) với ạ!



Mỗi ngày làm 8h, con số tương ứng với số giờ làm
Ngày nào làm từ 8h trở xuống thì cộng vào giờ công
Ngày nào làm hơn 8h thì phần dư ra được tính là giờ tăng ca
(Ô màu đỏ là ngày có tăng ca)

Em ví dụ 7 ngày, nhưng thực tế có 31 ngày ạ!

Em cám ơn ạ!

 

[Phuocam]

Chào anh chị ạ!
Em có bảng chấm công như thế này, anh chị giúp em công thức ở chỗ Giờ công (H5) và Giờ tăng ca (I5) với ạ!

Mỗi ngày làm 8h, con số tương ứng với số giờ làm
Ngày nào làm từ 8h trở xuống thì cộng vào giờ công
Ngày nào làm hơn 8h thì phần dư ra được tính là giờ tăng ca
(Ô màu đỏ là ngày có tăng ca)

Em ví dụ 7 ngày, nhưng thực tế có 31 ngày ạ!

Em cám ơn ạ!

Thử công thức này trong H5:

=SUMIF(A5:G5,"<=8")+8*COUNTIF(A5:G5,">8")

.

 

[befaint]

Mỗi ngày làm 8h, con số tương ứng với số giờ làm

Cộng kiểu gì hay vậy nhỉ?



I5 =SUM(IFERROR(IF(B5:H5>8,8*(B5:H5)^0,B5:H5),0))
J5 =SUM(IFERROR(IF(B5:H5>8,B5:H5-8,0),0))
'Gõ CSE

 

[VetMini]

Công thức hơi rắc rối một chút: (Chỉ cốt tránh phải gõ CSE )

Giờ tăng ca: =SUMPRODUCT((N(+$B$5:$H$5)>8)*(N(+$B$5:$H$5)-8))
Giờ chính: =SUMPRODUCT(N(+$B$5:$H$5)) - giờ tăng ca

Chú: biểu thức N(+...) là mẹo vặt bảo Excel đặt 0 cho các trị không phải là số.

 

[Phan Thế Hiệp]

Còn ngày nghỉ có phép "P" nữa, thớt ơi! Muốn đi hầu kiện hay đền tiền hử!

Góp thêm cách cho vui:

I5=SUM(TEXT(N(+B5:H5)+8*(B5:H5="P"),"[<8]0;\8")*1)
J5=SUM(TEXT(N(+B5:H5)-8,"0;\0")*1)

Kết thúc bằng Ctrl+Shift+Enter. Hoặc thay Sum() bằng Sumproduct(), thì chỉ nhấn Enter.

Hoặc dùng công thức của anh @Phuocam:

I5=SUMIF(B5:H5,"<=8")+8*SUM(COUNTIF(B5:H5,{">8";"P"}))
J5=SUM(B5:H5,8*(B5:H5="P"))-I5

Thân

 

[KhaNhu1999]

Dạ em đã làm được rồi ạ!
Em cám ơn anh chị GPE rất nhiều !