Sắp xếp và tính tổng (2 người xem)

[hngiatuong]

Nhờ các A/C nghĩ cách giùm Sắp xếp và tính tổng sau khi sắp xếp

 

[hoamattroicoi]

Nhờ các A/C nghĩ cách giùm Sắp xếp và tính tổng sau khi sắp xếp

Tôi thấy bạn đặt vùng dữ liệu từ A5 :A23 là data vậy công thức tại D5 :

=INDEX(data,MATCH(1,INDEX((COUNTIF($D$4:D4,data)=0)*(data<>""),0),0))

Kết thúc bằng phím Enter và copy xuống cho các ô còn lại
Công thức tại E5 :

=SUMIF(data,D5,$B$5:$B$23)

Copy xuống.
Nếu muốn loại bỏ lỗi khi hết giá trị cần lọc thì có thể dùng công thức này cho D5 :

=LOOKUP(REPT("z",255),CHOOSE({1;2},"",INDEX(data,MATCH(1,INDEX((COUNTIF($D$4:D4,data)=0)*(data<>""),0),0))))

 

[siwtom]

Nhờ các A/C nghĩ cách giùm Sắp xếp và tính tổng sau khi sắp xếp

Tôi nhìn bảng 2 chỉ thấy lọc duy nhất chứ có thấy sắp xếp đâu?
Hay bây giờ bạn muốn vừa lọc vừa sắp xếp? Nếu thế thì:

1. Đặt name data

=$A$5:$A$23

2. Chọn ô D5, đặt name arr

=IF((data<>"")*(COUNTIF($D$4:$D4;data)=0);COUNTIF(data;"<"&data);"")

3. công thức cho D5

=IFERROR(INDEX(data;MATCH(SMALL(arr;1);arr;0));"")

kéo xuống dưới.

4. công thức cho E5

=IF($D5<>"";SUMIF(data;$D5;OFFSET(data;;1));"")

kéo xuống dưới.

 

[hngiatuong]

Cảm ơn 2 bạn: siwtom, hoamattroicoi
Mình làm theo hoamattroicoi thì kết quả thấy đúng còn làm theo siwtom lại ko được nhỉ. Mình chưa hiểu nhiều lắm về công thức này, nên mình sẽ nghiên cứu kỹ để tìm hiểu xem tại sao. Cảm ơn 2 bạn nhé.

 

[dhn46]

Cảm ơn 2 bạn: siwtom, hoamattroicoi
Mình làm theo hoamattroicoi thì kết quả thấy đúng còn làm theo siwtom lại ko được nhỉ. Mình chưa hiểu nhiều lắm về công thức này, nên mình sẽ nghiên cứu kỹ để tìm hiểu xem tại sao. Cảm ơn 2 bạn nhé.

Công thức bài #3 là đúng.
Bạn đọc thật kỹ hướng dẫn đặc biệt là mục số 2

2. Chọn ô D5, đặt name arr

Ngoài ra bạn thay thế toàn bộ dấu chấm phảy ; bằng dấu phảy ,

 

[siwtom]

Công thức bài #3 là đúng.
Bạn đọc thật kỹ hướng dẫn đặc biệt là mục số 2

Ngoài ra bạn thay thế toàn bộ dấu chấm phảy ; bằng dấu phảy ,

Cám ơn dhn46 đã tiếp sức.

@chủ chủ đề: nếu bài của hoamattroicoi đúng ý bạn thì bạn viết "sắp xếp" ở tiêu đề và nội dung làm gì?
Bài của tôi là vừa lọc vừa sắp xếp. Nếu bạn chỉ cần lọc thôi thì dùng code của hoamattroicoi nhé.

 

[hungpa]

Cái này công thức làm gì cho mệt đầu, dùng Pivot Table 5 giây là xong mà.

 

[hngiatuong]

@chủ chủ đề: nếu bài của hoamattroicoi đúng ý bạn thì bạn viết "sắp xếp" ở tiêu đề và nội dung làm gì?
Bài của tôi là vừa lọc vừa sắp xếp. Nếu bạn chỉ cần lọc thôi thì dùng code của hoamattroicoi nhé.[/QUOTE]

Thật là xin lỗi. Không biết nên nói thể nào cả ... Mình nhập vào thì cứ báo lỗi, trong khi về vấn đề này minh lại chưa hiểu biết nhiều. Thật lòng cảm ơn mọi người trên diễn đàn, mình sẽ nghiên cứu thử lại thêm nhiều lần nữa để tìm hiểu tại sao.
Tuy nhiên cách này mình thấy bảng tính chạy lâu quá, không biết có cách nào nhanh hơn không. Đặc biệt khi thay đổi 1 số dòng nào đó thì hơi mất thời gian. ở đây mình mới thử có khoảng 600 dòng. Hay do máy tính mình kém quá.

 

[Let'GâuGâu]

Thật là xin lỗi. Không biết nên nói thể nào cả ... Mình nhập vào thì cứ báo lỗi, trong khi về vấn đề này minh lại chưa hiểu biết nhiều. Thật lòng cảm ơn mọi người trên diễn đàn, mình sẽ nghiên cứu thử lại thêm nhiều lần nữa để tìm hiểu tại sao.
Tuy nhiên cách này mình thấy bảng tính chạy lâu quá, không biết có cách nào nhanh hơn không. Đặc biệt khi thay đổi 1 số dòng nào đó thì hơi mất thời gian. ở đây mình mới thử có khoảng 600 dòng. Hay do máy tính mình kém quá.

số liệu của bạn quá lớn nên việc sử dụng cthức mảng làm tốc độ tính ko nhanh được,
bạn có thể đưa vào name để tăng tốc phần nào
tại F2 đặt name

dk=MATCH(0,COUNTIF(XL!$F$1:F1,Data)*(Data<>""),0)

cthức tại

F2=INDEX(Data,DK)

ngoài ra bạn có thể sử dụng các cách khác nhanh hơn như remove duplicated hay pivot table và nhờ các thầy viết code vba

 

[hngiatuong]

Cảm ơn Let'GâuGâu.Quả đúng là chạy nhanh hơn nhiều đấy. cảm ơn, cảm ơn nhé. Nhưng cho hỏi thêm nếu mình muốn gộp cột F vào cột G để đỡ mất thêm 1 cột thì nên sửa công thức thế nào.http://www.giaiphapexcel.com/forum/member.php?875733-Let-GâuGâu

 

[hngiatuong]

Mong các A/c chỉ giúp xem tại sao như vậy. Mình không tìm nổi. Cảm ơn.

 

[mhung12005]

Mong các A/c chỉ giúp xem tại sao như vậy. Mình không tìm nổi. Cảm ơn.

Mình đoán là bạn đang dùng Excel 97-2003 nên lỗi, vì hàm IFERROR không có trong Excel 2003.

Bạn đổi thành công thức này:

=IF(ISERROR(INDEX(Data,MATCH(SMALL(arr,1),arr,0))),"",INDEX(Data,MATCH(SMALL(arr,1),arr,0)))

 

[hngiatuong]

mhung12005
cảm ơn bạn. Đúng là mình dùng Excel 2003. Khi thay công thức
=IF(ISERROR(INDEX(Data,MATCH(SMALL(arr,1),arr,0))) ,"",INDEX(Data,MATCH(SMALL(arr,1),arr,0)))
thì đã hết xảy ra lỗi rồi.
cảm ơn nhé.

 

[aries8214]

Mình cũng có yêu cầu giống bác chủ top. Tuy nhiên mình thấy là dữ liệu sau khi lọc sang một bảng khác thì mình sẽ ko biết trước được số hàng chứa dữ liệu lọc ra sẽ là bao nhiêu. Chẳng hạn như file của bác chủ có 6 loại con thì khi lọc ra sẽ được 1 cột 6 hàng, nhưng nếu khi cần sửa đổi bảng dữ liệu nguồn thì số hàng sẽ khác. Vậy mình sẽ kéo công thức hú hoạ một số hàng, cho đến khi thấy hàng trắng thì ngừng. Có cách nào để tự động lọc ra một cột có số hàng tự động thay đổi theo bảng dữ liệu nguồn không nhỉ.

 

[thuan90]

Chào hngiatuong, Let-GâuGâu
Sao mình lam theo hướng dẫn mà không được ở ô F2 báo lỗi không ah, giúp mình với

 

[thuan90]

số liệu của bạn quá lớn nên việc sử dụng cthức mảng làm tốc độ tính ko nhanh được,
bạn có thể đưa vào name để tăng tốc phần nào
tại F2 đặt name

dk=MATCH(0,COUNTIF(XL!$F$1:F1,Data)*(Data<>""),0)

cthức tại

F2=INDEX(Data,DK)

ngoài ra bạn có thể sử dụng các cách khác nhanh hơn như remove duplicated hay pivot table và nhờ các thầy viết code vba

Chào Let-GâuGâu
sao mình làm theo hướng dẫn của bạn mả ở ô F2 báo lỗi, máy vẫn chạy chậm
giúp mình với