Rút gọn macro (1 người xem)

[nhk007dn]

Mình Record được đoạn code định dạng 1 vùng, tuy nhiên nó dài quá nên mình muốn nhờ các bạn giúp rút gọn đoạn code này.
Mình cảm ơn!

Sub Macro4()
'
' Macro4 Macro
'


'
    Range("F1:G3").Select
    Selection.Font.Bold = True
    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .ThemeColor = xlThemeColorDark1
        .TintAndShade = -0.149998474074526
        .PatternTintAndShade = 0
    End With
    With Selection.Font
        .Color = -65536
        .TintAndShade = 0
    End With
    Selection.Borders(xlDiagonalDown).LineStyle = xlNone
    Selection.Borders(xlDiagonalUp).LineStyle = xlNone
    With Selection.Borders(xlEdgeLeft)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeTop)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeBottom)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeRight)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlInsideVertical)
        .LineStyle = xlDot
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlInsideHorizontal)
        .LineStyle = xlDot
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection
        .HorizontalAlignment = xlGeneral
        .VerticalAlignment = xlCenter
        .WrapText = False
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
    With Selection
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlCenter
        .WrapText = False
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
End Sub

 

[SA_DQ]

Bạn thử với cái này sau đó đối chiếu:

Sub Macro4()
 Dim J As Long
 
 With Range("F1:G3")
    With .Font
        .Bold = True
        .Color = -65536
    End With
    .Borders(xlDiagonalDown).LineStyle = xlNone
    .Borders(xlDiagonalUp).LineStyle = xlNone
    For J = 7 To 12
        With .Borders(J)  '7-12'
            .LineStyle = xlContinuous
            .Weight = xlThin
        End With
    Next J
    .VerticalAlignment = xlCenter
 End With
End Sub

 

[phihndhsp]

Mình Record được đoạn code định dạng 1 vùng, tuy nhiên nó dài quá nên mình muốn nhờ các bạn giúp rút gọn đoạn code này.
Mình cảm ơn!

mục đích của bạn là làm cái gì rồi tôi sẽ rút gọn code cho bạn, định dạng khung viền, định dạng font, định dạng cell... như thế nào?

 

[nhk007dn]

Bạn thử với cái này sau đó đối chiếu:

Sub Macro4()
 Dim J As Long
 
 With Range("F1:G3")
    With .Font
        .Bold = True
        .Color = -65536
    End With
    .Borders(xlDiagonalDown).LineStyle = xlNone
    .Borders(xlDiagonalUp).LineStyle = xlNone
    For J = 7 To 12
        With .Borders(J)  '7-12'
            .LineStyle = xlContinuous
            .Weight = xlThin
        End With
    Next J
    .VerticalAlignment = xlCenter
 End With
End Sub

Mình cảm ơn!
Cho hỏi '7-12' nghĩa là gì vậy bạn?
trong code nó có nghĩa gì?

 

[nhk007dn]

mục đích của bạn là làm cái gì rồi tôi sẽ rút gọn code cho bạn, định dạng khung viền, định dạng font, định dạng cell... như thế nào?

Mình muốn định dạng
khung bao quanh
đường kẻ ở giữa
màu nền
màu font
in đậm
canh giữa theo 2 phương

cho vùng từ F1 đến cuối bảng số liệu (tính cho cả dòng và cột)
Mình cảm ơn!

 

[ChanhTQ@]

[thongbao]Cho hỏi '7-12' nghĩa là gì vậy bạn?
trong code nó có nghĩa gì?[/thongbao]

Những thứ này bạn có thể hỏi ngay trong cửa sổ 'Immediate' í;
Khỏi hỏi trên diễn đàn chi cho mắc công chờ lâu hơn!

 

[phihndhsp]

Mình muốn định dạng
khung bao quanh
đường kẻ ở giữa
màu nền
màu font
in đậm
canh giữa theo 2 phương

cho vùng từ F1 đến cuối bảng số liệu (tính cho cả dòng và cột)
Mình cảm ơn!

Sub GPE()
        With Range("H16:J20")
                .Borders.LineStyle = 1
                .HorizontalAlignment = xlCenter
                .VerticalAlignment = xlCenter
                .Interior.ColorIndex = 20
                .Font.ColorIndex = 12
                .Font.Bold = True
        End With
End Sub

theo yêu cầu của bạn ngắn gọn vậy thôi

 

[VetMini]

Theo yêu cầu của chủ thớt thì để ra một hàm chuyên môn:

sub MauMe(rg as range)
with rg
....
end with
end sub

Sau đó muón áp dụng vào range nào thì gọi hàm.

MauMe Range("H16:J20")

 

[leonguyenz]

Các diễn giải có ghi trong code, bạn tham khảo.

Sub Macro4()    
With Range("F1:G3")        
.Font.Bold = True 'In đậm chữ        
.Font.Color = -65536 'Tô màu chữ       
.Interior.ColorIndex = 15 'Tô màu nền       
.Borders.LineStyle = 1 'Kẻ khung nét liền toàn bộ vùng        
.Borders(xlInsideVertical).LineStyle = 3 'Kẻ khung nằm đứng, nét đứt trong vùng       
.Borders(xlInsideHorizontal).LineStyle = 3 'Kẻ khung nằm ngang, nét đứt trong vùng        
.VerticalAlignment = xlCenter 'Canh lề chữ ở giữa, so với trên - dưới       
.HorizontalAlignment = xlCenter 'Canh lề chữ ở giữa, so với phải - trái    
End With
End Sub

 

[nhk007dn]

@all: càng nhiều ý kiến của các bạn mình càng hiểu ra nhiều. Mình cảm ơn!