Một vài công thức ứng dụng cho Kế toán (1 người xem)

[hoangdanh282vn]

1. Tách họ và tên :
a. Tách tên :

[B][COLOR=blue]=TRIM(RIGHT(SUBSTITUTE(TRIM(A2)," ","      "),7))[/COLOR][/B]

b. Tách Họ :

=LEFT(TRIM(A2),FIND(" ",TRIM(A2))-1)

c. Tách Tên lót:

{=MID(TRIM(A2),FIND(" ",TRIM(A2))+1,MAX((MID(TRIM(A2),ROW($1:$50),1)=" ")*ROW($1:$50))-FIND(" ",TRIM(A2)))}

2. Chuyển đổi ngày tháng về dạng chuẩn :
Ngày tháng có thể ở dạng text và có khoảng trắng.

=DATE(IF(ISERR(FIND("/20",SUBSTITUTE(A1," ",""))),20&RIGHT(SUBSTITUTE(A1," ",""),2),RIGHT(SUBSTITUTE(A1," ",""),4)),MID(SUBSTITUTE(A1," ",""),FIND("/",SUBSTITUTE(A1," ",""))+1,FIND("/",SUBSTITUTE(A1," ",""),FIND("/",SUBSTITUTE(A1," ",""))+1)-FIND("/",SUBSTITUTE(A1," ",""))-1),LEFT(SUBSTITUTE(A1," ",""),FIND("/",SUBSTITUTE(A1," ",""))-1))

3. Chuyển đổi số Hóa đơn :
Số HĐ chuẩn có 5 chữ số, nếu ít hơn thì thêm vào, nếu nhiều hơn thì giữ nguyên.

=IF(A1="","",IF(LEN(TRIM(A1))<5,REPT("0",(5-LEN(TRIM(A1))))&TRIM(A1),A1))

4. Kiểm tra mã số thuế :

=IF(A1="","",IF(LEN(A1)<10,"MST Không Đủ Ký Tự",MOD((SUMPRODUCT(MID(A1,ROW($1:$9),1)*{31;29;23;19;17;13;7;5;3})),11)=10-MID(A1,10,1)))

5. Chuyển đổi Mã số thuế về dạng chuẩn dùng cho phần mềm HTKK :

=IF(AND(NOT(ISERR(FIND("-",A1))),LEN(A1)>12),LEFT(SUBSTITUTE(A1,"-",""),13),IF(NOT(ISERR(FIND("-",A1))),LEFT(A1,10),IF(OR(LEN(A1)=9,LEN(A1)=12),"0"&A1,IF(AND(ISERR(FIND("-",A1)),LEN(A1)=13),A1,IF(LEN(A1)=10,A1,LEFT("0"&A1,13))))))

6. Tính thuế TNCN : dùng cho đến năm 2008

=CHOOSE(IF(A1>4*10^7,5,IF(A1>25*10^6,4,IF(A1>15*10^6,3,IF(A1>5*10^6,2,1)))),0,A1/10-5*10^5,A1/5-2*10^6,A1*0.3-45*10^5,A1*0.4-85*10^5)

 

[BNTT]

Cái này:

3. Chuyển đổi số Hóa đơn :
Số HĐ chuẩn có 5 chữ số, nếu ít hơn thì thêm vào, nếu nhiều hơn thì giữ nguyên.
=IF(A1="","",IF(LEN(TRIM(A1))<5,REPT("0",(5-LEN(TRIM(A1))))&TRIM(A1),A1))

Chọn cột chứa số hóa đơn, định dạng cho nó là 00000 thì lẹ hơn và đỡ nặng file hơn.

 

[PHONGGANHHAO]

Anh đang dùng phầm mềm kế toán UNESCO ACCOUNGTING . MUỐN IN ĐƯỢC : GIỜ + PHÚT TRONG BẢNG CRYTAL REPORT NHƯNG KG BIẾT CÁCH . NHỜ QUÝ ANH CHỊ GIÚP ĐỠ . THANK

 

[tigertiger]

Cái này:

Chọn cột chứa số hóa đơn, định dạng cho nó là 00000 thì lẹ hơn và đỡ nặng file hơn.

ĐỊnh dạng thì nhẹ hơn, nhưng nếu lấy DL đó đi chỗ khác --> nó trả về giá trị thực --> lại phải format

trong khi đó dùng công thức thì chỉ cần 1 lần / yên tâm ng khác sử dụng hoặc ta tham chiếu thì KQ như mong muốn

.

 

[cadafi]

3. Chuyển đổi số Hóa đơn :
Số HĐ chuẩn có 5 chữ số, nếu ít hơn thì thêm vào, nếu nhiều hơn thì giữ nguyên.

=IF(A1="","",IF(LEN(TRIM(A1))<5,REPT("0",(5-LEN(TRIM(A1))))&TRIM(A1),A1))

Công thức trên có thể được thay thế bằng:

=Right("00000"&Trim(A1),5)

 

[BNTT]

ĐỊnh dạng thì nhẹ hơn, nhưng nếu lấy DL đó đi chỗ khác --> nó trả về giá trị thực --> lại phải format

trong khi đó dùng công thức thì chỉ cần 1 mình / yên tâm ng khác sử dụng hoặc ta tham chiếu thì KQ như mong muốn.

Đồng ý với ý kiến này.

Số HĐ chuẩn có 5 chữ số, nếu ít hơn thì thêm vào, nếu nhiều hơn thì giữ nguyên.
=IF(A1="","",IF(LEN(TRIM(A1))<5,REPT("0",(5-LEN(TRIM(A1))))&TRIM(A1),A1))

Nếu dùng công thức thì có lẽ dùng cái này sẽ ngắn hơn:

=IF(A1="","",TEXT(A1, "0000000"))

Ở đây tôi đề nghị là dùng 7 chữ số (là đúng nguyên xi con serial number in trên tờ hóa đơn), thay vì 5, bởi vì có nhiều chi cục thuế không chấp nhận dùng 40761 thay cho 0045761, mặc dù chẳng có gì khác nhau.

 

[hoangdanh282vn]

Công thức trên có thể được thay thế bằng:

=Right("00000"&Trim(A1),5)

Công thức của anh đúng là ngắn hơn nhưng chưa đúng ý lắm.
Trong tựa em có nói là Nếu chiều dài chuỗi <5 thì thêm 0 vào cho đủ 5, còn nếu dài hơn 5 thì vẫn giữ nguyên chuỗi. Mục đích là nếu chuỗi có ít ký tự mà thêm cho đủ 7 thì nhìn mỏi mắt lắm, VD 0000015

 

[OverAC]

Vậy dùng công thức của anh Tường thì có thể hợp hơn:
=IF(A1="","",TEXT(A1, "00000"))

Nếu nhỏ hơn 5 thì là 5, dài hơn 5 thì muốn bao nhiêu có bấy nhiêu.

 

[dongdv]

=TRIM(RIGHT(SUBSTITUTE(TRIM(A2)," "," "),7))
Mình không hiểu ct này lại tìm ra tên được! bạn xem lại xem!

 

[TKT]

=TRIM(RIGHT(SUBSTITUTE(TRIM(A2)," "," "),7))
Mình không hiểu ct này lại tìm ra tên được! bạn xem lại xem!

dongdv nên tải file về xem, nếu dongdv chỉ copy công thức ở bài gửi rồi dán vào excel thì chú ý dâu ; hoặc dấu ,

 

[OverAC]

Đúng là công thức ở trên hiển thị trên màn hình bị sai do lỗi của diễn đàn đúng ra nó phải là:

=TRIM(RIGHT(SUBSTITUTE(TRIM(A2)," ","      "),7))

bên trong dấu ngoặc kép thứ 2 (" ") có 6 khoản trắng . Nếu trường hợp có tên dài hơn 7 ký tự (ví dụ tên christopher chẳng hạn thì bạn có thể tăng số lượng khoản trắng lên thành 9 và số 7 trong công thức sửa thành số 10

 

[ThuNghi]

=TRIM(RIGHT(SUBSTITUTE(TRIM(A2)," "," "),7))
Mình không hiểu ct này lại tìm ra tên được! bạn xem lại xem!

Công thức lây tên phải là
=TRIM(RIGHT(SUBSTITUTE(TRIM(A2)," ",REPT(" ",6)),8))

 

[staythesame]

ĐỊnh dạng thì nhẹ hơn, nhưng nếu lấy DL đó đi chỗ khác --> nó trả về giá trị thực --> lại phải format

trong khi đó dùng công thức thì chỉ cần 1 lần / yên tâm ng khác sử dụng hoặc ta tham chiếu thì KQ như mong muốn

.

Đồng ý là dùng sẽ hơn. Nhưng có cái bất tiện là phải thêm 1 cột số hóa đơn sau đó mới dùng lệnh chuyển đổi. Trong 1 bảng nếu thêm nhiều cột kiểu này chắc khó theo dõi lắm! Còn cách nào khá hơn ko?

 

[lammtv]

=TRIM(RIGHT(SUBSTITUTE(TRIM(B4)," "," "),7)) cho em hỏi số 7 trong hàm này nghĩa là gì vậy?

 

[ptm0412]

cho em hỏi số 7 trong hàm này nghĩa là gì vậy?

7 là số ký tự của từ dài nhất trong tiếng Việt. 6 ký tự trống nối với 1 cái tên bất kỳ, lấy 7 ký tự cuối bằng Right, loại bỏ khoảng trắng thừa bằng Trim, sẽ ra tên.

 

[maikhoi]

1. Tách họ và tên :
a. Tách tên :

[B][COLOR=blue]=TRIM(RIGHT(SUBSTITUTE(TRIM(A2)," ","      "),7))[/COLOR][/B]

b. Tách Họ :

c. Tách Tên lót:


2. Chuyển đổi ngày tháng về dạng chuẩn :
Ngày tháng có thể ở dạng text và có khoảng trắng.


3. Chuyển đổi số Hóa đơn :
Số HĐ chuẩn có 5 chữ số, nếu ít hơn thì thêm vào, nếu nhiều hơn thì giữ nguyên.


4. Kiểm tra mã số thuế :


5. Chuyển đổi Mã số thuế về dạng chuẩn dùng cho phần mềm HTKK :


6. Tính thuế TNCN : dùng cho đến năm 2008

MST ờ tỉnh kiểm tra không được vậy anh ơi, có công thức kiểm tra MST các tỉnh không anh