Hàm trả về ngày đầu của tháng (1 người xem)

[changngoc]

Em có ví dụ:
ô A1 là ô THÁNG --> nhập số 1
ô A2 là ô NĂM --> 2011

ô A3 = hàm gì để ra kết quả là 1/1/2011
tương tự: A1=5, A2=2012 --> A3 ra KQ là 5/1/2011 ( tức là ngày 1 tháng 5, năm 2011)

Các bạn giúp mình nhé.

 

[vu_tuan_manh_linh]

Dùng =Date(Year;Month;day)
đương nhiên day=1. Còn year, Month là các ô năm, tháng mà bạn muốn.

 

[ndu96081631]

Dùng =Date(Year;Month;day)
đương nhiên day=1. Còn year, Month là các ô năm, tháng mà bạn muốn.

Cách khác:

=1*(A2&"/"&A1&"/1")

Định dạng lại kết quả là dd/mm/yyyy

 

[changngoc]

Cách khác:

=1*(A2&"/"&A1&"/1")

Định dạng lại kết quả là dd/mm/yyyy

Cái này gõ ở đâu vậy anh. vì nếu gõ ở ô A3 thì dùng date gọn hơn. Hay là Alt-F11 để gõ trong VBA ? Hướng dẫn chi tiết một chúc giúp em vì cũng mới tập tành học VB á. thanks.

 

[ndu96081631]

Cái này gõ ở đâu vậy anh. vì nếu gõ ở ô A3 thì dùng date gọn hơn. Hay là Alt-F11 để gõ trong VBA ? Hướng dẫn chi tiết một chúc giúp em vì cũng mới tập tành học VB á. thanks.

Gõ đâu cũng được, tùy bạn (là công thức chứ không phải VBA code gì đâu)
Lưu ý là sau khi gõ xong phải bấm Ctrl + 1 để định dạng lại cell (vì rất có thể nó sẽ ra dạng số)
Như tôi đã nói ở trên, đây chỉ là 1 cách khác để tham khảo thôi (đương nhiên dùng hàm DATE mới "trong sáng", còn cách tôi đưa lên chỉ là kiểu "tà đạo)
Ẹc... Ẹc...

 

[thangpnit]

xin hỏi! Mình muốn lấy ra thứ hai đầu tiên của tháng tiếp theo tháng hiện tại thì dùng hàm gì hợp lý vậy? Mong các cao nhân chỉ bảo

 

[Phuocam]

Mình muốn lấy ra thứ hai đầu tiên của tháng tiếp theo tháng hiện tại

=WORKDAY.INTL(EOMONTH(TODAY(),0),1,"0111111")

 

[Hoang2013]

xin hỏi! Mình muốn lấy ra thứ hai đầu tiên của tháng tiếp theo tháng hiện tại thì dùng hàm gì hợp lý vậy? Mong các cao nhân chỉ bảo

Bạn thử cái cùi bắp này:

=DATE(YEAR(I3),1+MONTH(I3),0)+IF(WEEKDAY(DATE(YEAR(I3),1+MONTH(I3),0))=1,1,9-WEEKDAY(DATE(YEAR(I3),1+MONTH(I3),0)))


(18/05):

. . . Mình đã ra đúng yêu cầu.nhưng hàm hơi dài và khó hiểu.b có thể việt sub chút được không

Ờ hén, đúng là dài & :

=EOMONTH(I3,0)+IF(WEEKDAY(EOMONTH(I3,0))=1,1,9-WEEKDAY(EOMONTH(I3,0)))

sẽ ngắn hơn.

 

[thangpnit]

=WORKDAY.INTL(EOMONTH(TODAY(),0),1,"0111111")

Tuyệt vời.cảm ơn b với hàm ngắn gọn dễ hiểu này

Bạn thử cái cùi bắp này:

=DATE(YEAR(I3),1+MONTH(I3),0)+IF(WEEKDAY(DATE(YEAR(I3),1+MONTH(I3),0))=1,1,9-WEEKDAY(DATE(YEAR(I3),1+MONTH(I3),0)))

Cám ơn b mình đã ra đúng yêu cầu.nhưng hàm hơi dài và khó hiểu.b có thể việt sub chút được không ^^

 

[thangpnit]

Tiện đây xin hỏi thêm các nhà thông thái.mình có cột" B" ghi ngày tháng năm lộn xộn(không tịnh tiến mà ngày trước sau không theo thứ tự).Cột"A" mình muốn đánh số thứ tự các ngày sau ngày hiện tại theo quy tắc cột "B". Mình gửi kèm file cho đễ hiểu.mong các nhà thông thái đổi thành hàm đánh số tự động hộ mình

 

[Ba Tê]

Tiện đây xin hỏi thêm các nhà thông thái.mình có cột" B" ghi ngày tháng năm lộn xộn(không tịnh tiến mà ngày trước sau không theo thứ tự).Cột"A" mình muốn đánh số thứ tự các ngày sau ngày hiện tại theo quy tắc cột "B". Mình gửi kèm file cho đễ hiểu.mong các nhà thông tháy đổi thành hàm đánh số tự động hộ mình

Rất tiếc mình không phải nhà thông thái (tháy).

 

[Hoang2013]

. . . .mình có cột" B" ghi ngày tháng năm lộn xộn(không tuần tự mà ngày trước sau không theo thứ tự).Cột"A" mình muốn đánh số thứ tự các ngày sau ngày hiện tại theo quy tắc cột "B". Mình gửi kèm file cho đễ hiểu.mong các nhà thông tháy đổi thành hàm đánh số tự động hộ mình

UDF thì khó vô chừng, macro thì được, chịu không?

 

[Ba Tê]

UDF thì khó vô chừng, macro thì được, chịu không?

Công thức Excel cũng "chơi" được mà:

Spoiler: GPE

A6=IF(B6>$D$6;COUNTIFS($B$6:$B$12;">"&$D$6;$B$6:$B$12;"<"&B6)+1;"-")

 

[thangpnit]

Công thức Excel cũng "chơi" được mà:

Spoiler: GPE

A6=IF(B6>$D$6;COUNTIFS($B$6:$B$12;">"&$D$6;$B$6:$B$12;"<"&B6)+1;"-")

tuyệt vời ông mặt trời.quá chuẩn luôn.Thêm chút là nếu mình thay {"<"&B6)+1} thành {"<="&B6)} đều ra kết quả vậy thì có ok không.tại thấy các thầy hay để +1 thay cho thêm điều kiện nên hơi thắc mắc

 

[MIROTIC35]

Chào mọi người. Các anh chị thông thái Cho em hỏi dữ liệu như này

Phạm Thị Thùy

BB 1

Công nhân

16/10/2012

Với yêu cầu là trước ngày 15 thì em sẽ trả về ngày 01/10/2012
Sau ngày 15 sẽ là 01/11/2012
Vậy e sẽ dùng công thức như nào để chạy ra dược dữ liệu này ạ?

 

[Hong.Van]

Chào mọi người. Các anh chị thông thái Cho em hỏi dữ liệu như này

Phạm Thị Thùy

BB 1

Công nhân

16/10/2012

Với yêu cầu là trước ngày 15 thì em sẽ trả về ngày 01/10/2012

Sau ngày 15 sẽ là 01/11/2012
Vậy e sẽ dùng công thức như nào để chạy ra dược dữ liệu này ạ?

Nếu = ngày 15 thì sao
Bạn tự điều chỉnh công thức với A1 là ô chứa ngày cần xét

=IF(DAY(A1)<=15;DATE(YEAR(A1);MONTH(A1);1);DATE(YEAR(A1);MONTH(A1)+1;1))

 

[leonguyenz]

=IF(DAY(A1)<15,EOMONTH(A1,-1)+1,EOMONTH(A1,0)+1)
Với A1 chứa ngày

Có thể rút gọn:

=EOMONTH(A1,(DAY(A1)>=15)-1)+1

 

[VetMini]

Chào mọi người. Các anh chị thông thái Cho em hỏi dữ liệu như này

Phạm Thị Thùy

BB 1

Công nhân

16/10/2012

Với yêu cầu là trước ngày 15 thì em sẽ trả về ngày 01/10/2012

Sau ngày 15 sẽ là 01/11/2012
Vậy e sẽ dùng công thức như nào để chạy ra dược dữ liệu này ạ?

Ngay ngày 15 thì sao?