Giúp công thức tìm vị trí của 1 mã theo số hĐ (2 người xem)

[minhtuan55]

Chào cả nhà. giúp em công thức tìm vị trí mã như hình. Xin chân thành cảm ơn

 

[vanthinh3101]

Chào cả nhà. giúp em công thức tìm vị trí mã như hình. Xin chân thành cảm ơn
View attachment 210515

Bạn cho xin cái file excel để làm công thức cho nhanh được không?

 

[minhtuan55]

Bạn cho xin cái file excel để làm công thức cho nhanh được không?

Gửi bạn . Cảm ơn bạn

 

[vanthinh3101]

Gửi bạn . Cảm ơn bạn

Tôi dùng 1 cột phụ, bạn xem nhé!

Cập nhật:
Nếu không dùng cột phụ, bạn sử dụng công thức:

=COUNTIF(B2:INDIRECT("B"&AGGREGATE(14,6,ROW($B$2:$B$19)/($A$2:$A$19=E2)/($B$2:$B$19=F2),1)),F2)

Kết thúc bằng Enter

 

[Loc Uyen]

Gửi bạn . Cảm ơn bạn

Bạn xem công thức này thử nhé!
F2 =

=COUNTIF(OFFSET(B1,,,MATCH(D2,A1:A19,1),),E2)

 

[vanthinh3101]

Bạn xem công thức này thử nhé!
F2 =

=COUNTIF(OFFSET(B1,,,MATCH(D2,A1:A19,1),),E2)

Rất gọn gàng và chính xác
À, tôi vừa phát hiện có thể có lỗi sai nếu ở cột A, trước dòng 10, ví dụ: A3 là 45 thì kết quả sẽ bị sai.

 

[minhtuan55]

Bạn xem công thức này thử nhé!
F2 =

=COUNTIF(OFFSET(B1,,,MATCH(D2,A1:A19,1),),E2)

cảm ơn bạn. công thức rất hay. Nhưng mình muốn nếu Số hd không có trong bảng thì vị trí là 0

Bài đã được tự động gộp: 5/1/19

Tôi dùng 1 cột phụ, bạn xem nhé!

Cập nhật:
Nếu không dùng cột phụ, bạn sử dụng công thức:

=COUNTIF(B2:INDIRECT("B"&AGGREGATE(14,6,ROW($B$2:$B$19)/($A$2:$A$19=E2)/($B$2:$B$19=F2),1)),F2)

Kết thúc bằng Enter

Thank bạn. Nếu số HĐ ĐÓ KHÔNG CÓ THÌ BẠN phải làm sao cho nó = 0

 

[vanthinh3101]

cảm ơn bạn. công thức rất hay. Nhưng mình muốn nếu Số hd không có trong bảng thì vị trí là 0
View attachment 210520

Bài đã được tự động gộp: 5/1/19

Thank bạn. Nếu số HĐ ĐÓ KHÔNG CÓ THÌ BẠN phải làm sao cho nó = 0

Không có thì bạn chỉ cần sửa công thức thành =IFERROR(công thức cũ,0) là được

 

[minhtuan55]

Không có thì bạn chỉ cần sửa công thức thành =IFERROR(công thức cũ,0) là được

Mình đã sửa. Nhưng mà giá trị không lỗi sao mà Error được bạn. mình xin ví dụ

 

[dazkangel]

Thay đổi đôi chút về công thức countif:

=IFERROR(COUNTIF(OFFSET(B2,,,INDEX(MATCH(D2&E2,A2:A19&B2:B19,0),)),E2),"")

 

[minhtuan55]

Thay đổi đôi chút về công thức countif:

=IFERROR(COUNTIF(OFFSET(B2,,,INDEX(MATCH(D2&E2,A2:A19&B2:B19,0),)),E2),"")

Công thức tuyệt vời. Chúc bạn sang năm mới sớm Rực Rỡ

 

[Loc Uyen]

Rất gọn gàng và chính xác
À, tôi vừa phát hiện có thể có lỗi sai nếu ở cột A, trước dòng 10, ví dụ: A3 là 45 thì kết quả sẽ bị sai.

Em nghĩ số hóa đơn sẽ không trùng, nên để công thức vậy ạ,

Bài đã được tự động gộp: 5/1/19

Thay đổi đôi chút về công thức countif:

Hay quá ạ, lần đầu em mới biết Match có thể phối hợp 2 cột như vậy. Hihi. Học thêm được cái mới. Chúc anh cuối tuần vui ạ

 

[batman1]

Không chơi các hàm volatile, không chơi nối chuỗi

=IFERROR(COUNTIF(B$2:INDEX(B$2:B$100,MATCH(1,INDEX((A$2:A$100=D2)*(B$2:B$100=E2),0),0)),E2),0)

 

[Phan Thế Hiệp]

Thay đổi đôi chút về công thức countif:

=IFERROR(COUNTIF(OFFSET(B2,,,INDEX(MATCH(D2&E2,A2:A19&B2:B19,0),)),E2),"")

Nếu số hóa đơn của từng mã riêng biệt, đã xếp thứ tự tăng dần như dữ liệu chủ thớt đã cho, thì có thể dùng AGGREGATE():

=MATCH(E2,INDEX(AGGREGATE(15,6,A2:A19/(B2:B19=F2),ROW(1:20)),),)

Hoặc không sắp xếp, thì đành "lấy cắp" ý tưởng của em, làm như vầy:

=IFERROR(COUNT(1/(OFFSET(B2,,,MATCH(E2,IF(B2:B19=F2,A2:A19),))=F2)),"")

Kết thúc bằng Ctrl+Shift+Enter.
Hoặc khai phá thêm 1 hướng mới:

=IFERROR(LOOKUP(2,1/(E2=A2:A19),COUNTIF(OFFSET(B2,,,ROW(1:100)),F2)),"")

Chỉ Enter.

Chúc em cuối tuần vui.
Thân