Gặp rắc rối về xếp hạng trong Excel, pro nào biết giúp mình mới (1 người xem)

[duy91pro]

mình muốn xếp hạng trên excel nhưng hàm RANK() chỉ cho kiểu xếp hạng min , mình cần kiểu ​xếp hạng trung bình thì dùng hàm gì hả các bạn????????
thanks!!!!

 

[quangdiepctmbk]

Không hiểu ý của bạn

 

[songqueqb]

đơn giản thế thôi mà
vì dụ bạn có 10 dòng ( 10 thứ hạng) từ 1 > 10
bạn dùng rank để xếp cho nó sau đó dùng (min + max -1)/2 ( min max đây là min max của thứ hạng
do trong EXcel mặc nhiên thứ đầu tiên là 1 rùi nên chỉ cần lấy MAX/2 la ra thứ hạng trung bình
Đôi lúc bạn sẽ chia được dạng 11/2=5.5 < thứ hạng trung bình mà trong rank không có thứ hạng đó
bạn nên lấy = 6 hoặc = 5 trước khi so sánh với kết quả hàm rank ! ok

 

[duy91pro]

ý mình là, mình muốn xếp hạng kiểu trung bình
mình có kèm hình để các bạn hiểu ý mình hỏi
View attachment Book2.xlsx

ko phải trung bình hạng bạn ah, mà vấn đề là nhưng quan sát nào có giá trị bằng nhau thì excel lấy hạng bé nhất (kiểu xếp hạng min),nhưng mình cấn nhưng giá trị quan sát bằng nhau thì lấy giá trị trung bình của hạng những quan sát đó. mình có gửi hình lên bạn xem, biết chỉ giúp nhé
thanks

 

[nghiaphuc]

ý mình là, mình muốn xếp hạng kiểu trung bình
mình có kèm hình để các bạn hiểu ý mình hỏi
View attachment 79956

Bạn xài tạm công thức này nhé, tuy còn dài dòng nhưng xài được:

=IF(COUNTIF($A$5:$A$13,A5)>1,(2*RANK(A5,$A$5:$A$13,1)+COUNTIF($A$5:$A$13,A5)-1)/2,RANK(A5,$A$5:$A$13,1))

 

[ndu96081631]

Bạn xài tạm công thức này nhé, tuy còn dài dòng nhưng xài được:

=IF(COUNTIF($A$5:$A$13,A5)>1,(2*RANK(A5,$A$5:$A$13,1)+COUNTIF($A$5:$A$13,A5)-1)/2,RANK(A5,$A$5:$A$13,1))

Không cần IF cũng được:

=(COUNTIF($A$5:$A$13,A5)*(2*RANK(A5,$A$5:$A$13,1)+(COUNTIF($A$5:$A$13,A5)-1))/2)/COUNTIF($A$5:$A$13,A5)

Dạng công thức cấp số cộng đây mà
Còn đây là công thức theo kiểu của Excel:

=SUMPRODUCT(RANK(A5,$A$5:$A$13,1)+ROW(INDIRECT("1:"&COUNTIF($A$5:$A$13,A5)))-1)/COUNTIF($A$5:$A$13,A5)

 

[huuthang_bd]

Công thức này gọn hơn nè

=RANK(A5,$A$5:$A$13,1)+(COUNTIF($A$5:$A$13,A5)-1)/2

 

[duy91pro]

mình đã làm được rồi. cảm ơn mọi người nhá!!!!