Cần tư vấn công thức xếp hạng có điều kiện (1 người xem)

[Đặng Việt Hưng]

Mình có 1 file excel như ở dưới.
Giả sử các giá trị của cột G>=34 thì xếp hạng từ cao đến thấp còn các giá trị của cột G<34 thì nợ.
Cao nhân nào giúp mình công thức với.
Xin chân thành cảm ơn

 

[phulien1902]

Mình có 1 file excel như ở dưới.
Giả sử các giá trị của cột G>=34 thì xếp hạng từ cao đến thấp còn các giá trị của cột G<34 thì nợ.
Cao nhân nào giúp mình công thức với.
Xin chân thành cảm ơn

Bạn thử:

=IF(G7>34,RANK(G7,$G$7:$G$30),"nợ")

 

[bebo021999]

Bạn thử:

=IF(G7>34,RANK(G7,$G$7:$G$30),"nợ")

chủ topic lưu ý công thức này áp dụng cho toàn đoàn, xếp hạng trên cả những người không đạt chuẩn nhé.
Còn chỉ xếp hạng trên những người >=34 thì khác à nha

 

[Đặng Việt Hưng]

Bạn thử:

=IF(G7>34,RANK(G7,$G$7:$G$30),"nợ")

Thanks bác nhé. Nó hiện đúng cái em cần

 

[Đặng Việt Hưng]

chủ topic lưu ý công thức này áp dụng cho toàn đoàn, xếp hạng trên cả những người không đạt chuẩn nhé.
Còn chỉ xếp hạng trên những người >=34 thì khác à nha

Bác có thể giúp em áp dụng công thức cho cả cái bảng kia để có thể xếp hạng luôn. Nếu được thì em đội ơn bác lắm lắm

 

[bebo021999]

Bác có thể giúp em áp dụng công thức cho cả cái bảng kia để có thể xếp hạng luôn. Nếu được thì em đội ơn bác lắm lắm

Có 2 cách
Cách 1: Xếp hạng bằng nhau nếu trùng điểm:
=IF(G7<=34,"Nợ",COUNTIFS($G$7:$G$30,">="&G7,$G$7:$G$30,">=34"))
Cách 2: Nếu trùng điểm, ai ở đầu danh sách thì xếp cao hơn:
=IF(G7<=34,"Nợ",SUMPRODUCT(--($G$7:$G$30+(MAX(ROW($G$7:$G$30))-ROW($G$7:$G$30))*10^-6>=G7+(MAX(ROW($G$7:$G$30))-ROW())*10^-6)))

 

[Mộng Thường 2001]

Có 2 cách
Cách 1: Xếp hạng bằng nhau nếu trùng điểm:
=IF(G7<=34,"Nợ",COUNTIFS($G$7:$G$30,">="&G7,$G$7:$G$30,">=34"))
Cách 2: Nếu trùng điểm, ai ở đầu danh sách thì xếp cao hơn:
=IF(G7<=34,"Nợ",SUMPRODUCT(--($G$7:$G$30+(MAX(ROW($G$7:$G$30))-ROW($G$7:$G$30))*10^-6>=G7+(MAX(ROW($G$7:$G$30))-ROW())*10^-6)))

Anh ơi em làm theo cách 1 không có ai được hạng 1 vậy anh?
có cách nào xếp từ cao đến thấp cũng tính điểm từ 34 trở lên, mà nếu đồng điểm thì đồng hạng không anh?
như xếp tay thì có 2 hạng 1, 1 hạng 2, 2 hạng 3, 3 hạng 4, 1 hạng 5-6-7, 2 hạng 8-9-10-11?

 

[Phuocam]

Thử:

=IF(G7<=34,"Nợ",SUMPRODUCT(($G$7:$G$30>=G7)/(COUNTIFS($G$7:$G$30,$G$7:$G$30))))

 

[Mộng Thường 2001]

Thử:

=IF(G7<=34,"Nợ",SUMPRODUCT(($G$7:$G$30>=G7)/(COUNTIFS($G$7:$G$30,$G$7:$G$30))))

chắc bỏ bằng mới đúng từ 34 trở lên:
=IF(G7<34,"Nợ",SUMPRODUCT(($G$7:$G$30>=G7)/(COUNTIFS($G$7:$G$30,$G$7:$G$30))))
cảm ơn anh hihi ^o^.

 

[Đặng Việt Hưng]

Thử:

=IF(G7<=34,"Nợ",SUMPRODUCT(($G$7:$G$30>=G7)/(COUNTIFS($G$7:$G$30,$G$7:$G$30))))

Bạn có thể giúp mình?
Ví dụ mình muốn làm phép cộng (H2+j2+K2+M2), nhưng nếu trong các ô trên có (Nợ hoặc bỏ) thì không ra kết quả mà sẽ ra (nợ hoặc bỏ) có được không bạn

 

[Phuocam]

=IF(COUNTIF(H7:N7,"Nợ")>0,"Nợ",IF(COUNTIF(H7:N7,"Bỏ")>0,"Bỏ",H7+J7+L7+N7))

 

[Đặng Việt Hưng]

=IF(COUNTIF(H7:N7,"Nợ")>0,"Nợ",IF(COUNTIF(H7:N7,"Bỏ")>0,"Bỏ",H7+J7+L7+N7))

Cảm ơn bạn nhiều nhé

 

[Mộng Thường 2001]

Bạn có thể giúp mình?
Ví dụ mình muốn làm phép cộng (H2+j2+K2+M2), nhưng nếu trong các ô trên có (Nợ hoặc bỏ) thì không ra kết quả mà sẽ ra (nợ hoặc bỏ) có được không bạn

em tìm lại bài trứơc thấy có cái nầy cũng hay hay:
=IFERROR(LOOKUP("zzzz",IF($H$6:$N$6=$P$6,H7:N7)),H7+J7+L7+N7)
yêucầu nhấn ctrl + shift + enter
còn nếu nhìu cột nửa, khỏi mất công gỏ H7+J7+L7+N7+P7+..nhìu nhìu..:
=IFERROR(LOOKUP("zzzz",IF($H$6:$P$6=$P$6,H7: P7)),SUMIF($H$6:$P$6,$P$6,H7: P7))
yêucầu nhấn ctrl + shift + enter . hok bít anh sài đc ko?