Đánh số cho các cặp số chứng từ và số chứng từ đối ứng (1 người xem)

[Excel my love_1]

MÌnh cần đánh số các cặp phiếu như trong hình minh họa
Ví dụ cặp số chứng từ và phiếu đối ứng như sau: XT0125-1480 và N0125-0390 với N0125-0390 và XT0125-1480 là 1 cặp phiếu số 1
Logic là:
nếu A và B với B và A sẽ là cặp số 1
nếu C và D với D và C sẽ là cặp số 2
nếu E và F với F và E sẽ là cặp số 3
….......
(Xem hình minh họa, mình đã bôi màu các cặp phiếu để các bạn tiện theo dõi)

 

[Duy Tùng 9x]

Bạn thử này xem sao

=LET(a,BYROW(A2:B29,LAMBDA(s,CONCAT(SORT(s,,,1)))),XMATCH(a,UNIQUE(a)))

 

[Duy Tùng 9x]

Office thấp kéo thì bạn thử này xem. Đúng với dữ liệu đó, còn nhiều thì chưa rõ nữa

E2=IF(SUM(($A$1:B1=A2)+($A$1:B1=B2)),LOOKUP(1,0/(MMULT(($A$1:B1=A2)+($A$1:B1=B2),{1;1})),$E$1:E1),MAX($E$1:E1)+1)

 

[HieuCD]

MÌnh cần đánh số các cặp phiếu như trong hình minh họa
Ví dụ cặp số chứng từ và phiếu đối ứng như sau: XT0125-1480 và N0125-0390 với N0125-0390 và XT0125-1480 là 1 cặp phiếu số 1
Logic là:
nếu A và B với B và A sẽ là cặp số 1
nếu C và D với D và C sẽ là cặp số 2
nếu E và F với F và E sẽ là cặp số 3
….......
(Xem hình minh họa, mình đã bôi màu các cặp phiếu để các bạn tiện theo dõi)

C2 =IFERROR(LOOKUP(2,1/(($A$1:A1=A2)+($A$1:A1=B2))/(($B$1:B1=B2)+($B$1:B1=A2)),$C$1:C1),MAX($C$1:C1)+1)
Copy xuống . . .

 

[Phan Thế Hiệp]

C2 =IFERROR(LOOKUP(2,1/(($A$1:A1=A2)+($A$1:A1=B2))/(($B$1:B1=B2)+($B$1:B1=A2)),$C$1:C1),MAX($C$1:C1)+1)
Copy xuống . . .

Lâu lắm mới thấy anh tung "chiêu" mảng.
Còn đang nghĩ trong đầu dùng countifs(), nhìn kỹ thì anh đã quất sẵn rồi.

"Gừng càng già càng cay"

Chúc anh và gia đình vui khỏe.

 

[HieuCD]

Lâu lắm mới thấy anh tung "chiêu" mảng.
Còn đang nghĩ trong đầu dùng countifs(), nhìn kỹ thì anh đã quất sẵn rồi.

"Gừng càng già càng cay"

Chúc anh và gia đình vui khỏe.

Khà Khà Khà! Gừng già khô rồi, Thấy dạng đơn giản nhưng hơi lạ nên làm thử góp vui, dạng khó nhường người khác.
Chúc bạn và gia đình an vui.

 

[thanthanhan]

Lâu lắm mới thấy anh tung "chiêu" mảng.
Còn đang nghĩ trong đầu dùng countifs(), nhìn kỹ thì anh đã quất sẵn rồi.

"Gừng càng già càng cay"

Chúc anh và gia đình vui khỏe.

Tôi cũng xin góp vui 1 công thức, cách làm không được hay như mọi người ở trên
=IFERROR(IF(A2=A1,D1,IF(VLOOKUP(VLOOKUP(A2,$A$2:B2,2,0),$A$1:B1,2,0)=A2, VLOOKUP(B2,$A$1 : D1,4,0))), MAX($D$1 : D1)+1)

Thấy cũng giống với kết quả

 

[Phan Thế Hiệp]

Tôi cũng xin góp vui 1 công thức, cách làm không được hay như mọi người ở trên
=IFERROR(IF(A2=A1,D1,IF(VLOOKUP(VLOOKUP(A2,$A$2:B2,2,0),$A$1:B1,2,0)=A2,VLOOKUP(B2,$A$11,4,0))),MAX($D$11)+1)

Thấy cũng giống với kết quả
View attachment 308951

Thấy bạn cũng hay xài 365, vậy dùng vầy đi (chôm điều kiện của anh @HieuCD )

=@FILTER(C$1:C1,(($A$1:A1=A2)+($A$1:A1=B2))*(($B$1:B1=B2)+($B$1:B1=A2)),MAX(C$1:C1)+1)

Thân

 

[thanthanhan]

Thấy bạn cũng hay xài 365, vậy dùng vầy đi (chôm điều kiện của anh @HieuCD )

=@FILTER(C$1:C1,(($A$1:A1=A2)+($A$1:A1=B2))*(($B$1:B1=B2)+($B$1:B1=A2)),MAX(C$1:C1)+1)

Thân

Tôi ít xài 365 lắm, vẫn còn quen kiểu sử dụng của phiên bản cũ.
Cám ơn bạn đã hướng dẫn thêm cho tôi
Chúc mọi người vui vẻ.

 

[Phan Thế Hiệp]

Tôi ít xài 365 lắm, vẫn còn quen kiểu sử dụng của phiên bản cũ.
Cám ơn bạn đã hướng dẫn thêm cho tôi
Chúc mọi người vui vẻ.

Vậy, cố gắng vọc mảng cho vui, bạn sẽ học được nhiều cái lý thú.

Thân