Tổng hợp hóa chất sử dụng theo tháng (1 người xem)

biboylenka · Thứ tư lúc 14:08

Nhờ các anh chị diễn đàn giúp em công thức để tổng hợp hóa chất, trong file em có:
Bảng 1: là bảng định mức, ví dụ để sản xuất SP1 cần dùng 2 đơn vị HC1, 0 đơn vị HC2, 1 đơn vị HC3
Bảng 2: là bảng kế hoạch, ví dụ tháng 1 sản xuất 9 đơn vị SP1, 10 đơn vị SP3, 5 đơn vị SP2
Bảng 3: là tổng hợp số lượng các loại HC cần sử dụng theo tháng dựa vào bảng 2 kế hoạch và bảng 1 định mức, ví dụng loại HC1 trong tháng 1 cần sử dụng 33 đơn vị
Nhờ anh chị giúp em sử dụng công thức nào để tổng hợp vào bảng 3.

thanthanhan · Thứ tư lúc 14:55

Tại ô B14 bạn gõ công thức sau:
=SUMPRODUCT(TRANSPOSE(INDEX($B$8:$D$10,,MATCH(B$13,$B$7:$D$7,0))),INDEX($B$2:$D$4,MATCH($A14,$A$2:$A$4,0),))

biboylenka · Thứ tư lúc 15:39

thanthanhan đã viết:
Tại ô B14 bạn gõ công thức sau:
=SUMPRODUCT(TRANSPOSE(INDEX($B$8:$D$10,,MATCH(B$13,$B$7:$D$7,0))),INDEX($B$2:$D$4,MATCH($A14,$A$2:$A$4,0),))

Em cảm ơn anh đã hỗ trợ, nhưng anh ơi em thử dùng công thức này thì báo lỗi #VALUE!.

Em thử bấm ctrl + shift + enter thì ra kết quả không chính xác.

Nhờ anh xem lại giúp em, em dùng excel 2016.

thanthanhan · Thứ tư lúc 15:58

Bạn tải file thử xem nhé.

dungpham01 · Thứ tư lúc 16:20

Mã:

=SUMPRODUCT(IFERROR(HLOOKUP($A$8:$A$10;$A$1:$D$4;MATCH($A14;$A$1:$A$4;0));0);INDEX($A$8:$D$10;;MATCH(B$13;$A$7:$D$7;0)))

bạn kiểm tra xem đúng chưa, file này nhìn đơn giản vậy mà rối não phết đấy, chắc tại quen vlookup rồi giờ chơi hlookup thấy không quen. cần có iferror để tránh lỗi N/A

Phan Thế Hiệp · Thứ tư lúc 22:20

dungpham01 đã viết:
Mã:

=SUMPRODUCT(IFERROR(HLOOKUP($A$8:$A$10;$A$1:$D$4;MATCH($A14;$A$1:$A$4;0));0);INDEX($A$8:$D$10;;MATCH(B$13;$A$7:$D$7;0)))

bạn kiểm tra xem đúng chưa, file này nhìn đơn giản vậy mà rối não phết đấy, chắc tại quen vlookup rồi giờ chơi hlookup thấy không quen. cần có iferror để tránh lỗi N/A

1/ Bỏ iferror(,0) cũng ra kết quả
2/ Trong bài này thay index() bằng: HLOOKUP(B$13,$B$7:$D$10,{2;3;4},) cũng được, nhưng index(,) bao quát hơn. Viết tương tự:
=SUM(HLOOKUP($A$8:$A$10,$B$1:$D$4,MATCH($A14,$A$1:$A$4,),)*HLOOKUP(B$13,$B$7:$D$10,{2;3;4},))

/-*+/

biboylenka · Thứ năm lúc 10:38

thanthanhan đã viết:
Bạn tải file thử xem nhé.

Em cảm ơn anh, công thức ra kết quả chính xác và chạy được trên máy em.

Bài đã được tự động gộp: Thứ năm lúc 10:40

dungpham01 đã viết:
Mã:

=SUMPRODUCT(IFERROR(HLOOKUP($A$8:$A$10;$A$1:$D$4;MATCH($A14;$A$1:$A$4;0));0);INDEX($A$8:$D$10;;MATCH(B$13;$A$7:$D$7;0)))

bạn kiểm tra xem đúng chưa, file này nhìn đơn giản vậy mà rối não phết đấy, chắc tại quen vlookup rồi giờ chơi hlookup thấy không quen. cần có iferror để tránh lỗi N/A

Cảm ơn bạn đã hỗ trợ, công thức cho ra kết quả chính xác!

Phan Thế Hiệp đã viết:
1/ Bỏ iferror(,0) cũng ra kết quả
2/ Trong bài này thay index() bằng: HLOOKUP(B$13,$B$7:$D$10,{2;3;4},) cũng được, nhưng index(,) bao quát hơn. Viết tương tự:
=SUM(HLOOKUP($A$8:$A$10,$B$1:$D$4,MATCH($A14,$A$1:$A$4,),)*HLOOKUP(B$13,$B$7:$D$10,{2;3;4},))

Cảm ơn anh đã hỗ trợ, em có thêm 1 cách sử dụng.

Bài đã được tự động gộp: Thứ năm lúc 10:43

Phan Thế Hiệp đã viết:
=SUM(HLOOKUP($A$8:$A$10,$B$1:$D$4,MATCH($A14,$A$1:$A$4,),)*HLOOKUP(B$13,$B$7:$D$10,{2;3;4},))

Nhưng anh ơi em thử sử dụng thì ra kết quả không như mong muốn

Bài đã được tự động gộp: Thứ năm lúc 10:52

dungpham01 đã viết:
Mã:

=SUMPRODUCT(IFERROR(HLOOKUP($A$8:$A$10;$A$1:$D$4;MATCH($A14;$A$1:$A$4;0));0);INDEX($A$8:$D$10;;MATCH(B$13;$A$7:$D$7;0)))

bạn kiểm tra xem đúng chưa, file này nhìn đơn giản vậy mà rối não phết đấy, chắc tại quen vlookup rồi giờ chơi hlookup thấy không quen. cần có iferror để tránh lỗi N/A

Nhưng công thức này không chạy trên máy mình máy mình win10 64bit, excel 2016. Mình chưa có máy khác và phiên bản excel khác để thử

Phan Thế Hiệp · Thứ năm lúc 10:55

biboylenka đã viết:
Nhưng anh ơi em thử sử dụng thì ra kết quả không như mong muốn

Xem file đính kèm

Thân

dungpham01 · Thứ năm lúc 13:27

thật xin lỗi, mấy câu trả lời bên trên đều là dùng trên office 2019 trở lên nên nó nhận mảng ra kết quả đúng, mình copy tất cả vào máy chỉ có office 2016 thì đúng như bạn nói, nó trả kết quả sai hết, kể cả file của thầy Hiệp!!! hiện chưa có cách nào khác, để mình nghĩ đã

dungpham01 · Thứ năm lúc 14:18

ok bạn, mình thử trên máy office 2016 được rồi đấy, ban thử xem. à với điều kiện từ B1 đến D1 sắp xếp SP123 thì cột A8-A10 cũng phải sắp xếp SP123 y như thế

Mã:

=MMULT(INDEX($B$1:$D$4;MATCH($A14;$A$1:$A$4;0););INDEX($A$8:$D$10;;MATCH(B$13;$A$7:$D$7;0)))

dungpham01 · Thứ năm lúc 16:52

còn nếu các SP xáo trộn như bảng 2 thì sẽ phức tạp hơn

Mã:

=MMULT(INDEX($B$2:$D$4;MATCH($A14;$A$2:$A$4;0););MMULT(--($B$1:$D$1=$A$8:$A$10);INDEX($B$8:$D$10;;MATCH(B$13;$B$7:$D$7;0))))

biboylenka · Thứ sáu lúc 09:50

Cảm ơn mọi người đã giúp đỡ nhiệt tình ạ!

dungpham01 · Thứ sáu lúc 09:54

biboylenka đã viết:
Cảm ơn mọi người đã giúp đỡ nhiệt tình ạ!

bạn lưu ý: file của bác thanthanhan cũng chỉ áp dụng được khi bảng 1 theo thứ tự SP1-2-3 thì bảng 2 cũng phải theo thứ tự SP1-2-3 nhé, nếu bảng 2 mà SP1-3-2 thì phải dùng file của mình mới được.

Phan Thế Hiệp · Thứ sáu lúc 11:49

dungpham01 đã viết:
thật xin lỗi, mấy câu trả lời bên trên đều là dùng trên office 2019 trở lên nên nó nhận mảng ra kết quả đúng, mình copy tất cả vào máy chỉ có office 2016 thì đúng như bạn nói, nó trả kết quả sai hết, kể cả file của thầy Hiệp!!! hiện chưa có cách nào khác, để mình nghĩ đã

À! Đúng như bạn nói, tôi quên là excel dưới 2019, thì 1 số hàm (như Hlookup..) không hỗ trợ trực tiếp lấy mảng làm giá trị dò, đành phải chơi 'bùa': T(IF({1},...)) để ép nó hiện "nguyên hình" vậy

Mã:

=SUMPRODUCT(HLOOKUP(T(IF({1},$A$8:$A$10)),$B$1:$D$4,MATCH($A14,$A$1:$A$4,),),HLOOKUP(B$13,$B$7:$D$10,{2;3;4},))

chỉ Enter, fill xuống và qua phải.

Thân
/-*+/

HieuCD · Thứ sáu lúc 13:15

Thử dùng hàm Sumif tìm sản lượng

Mã:

=SUMPRODUCT(SUMIF($A$8:$A$10,$B$1:$D$1,B$8:B$10)*$B2:$D2)

dungpham01 · Thứ sáu lúc 15:06

Phan Thế Hiệp đã viết:
À! Đúng như bạn nói, tôi quên là excel dưới 2019, thì 1 số hàm (như Hlookup..) không hỗ trợ trực tiếp lấy mảng làm giá trị dò, đành phải chơi 'bùa': T(IF({1},...)) để ép nó hiện "nguyên hình" vậy

Mã:

=SUMPRODUCT(HLOOKUP(T(IF({1},$A$8:$A$10)),$B$1:$D$4,MATCH($A14,$A$1:$A$4,),),HLOOKUP(B$13,$B$7:$D$10,{2;3;4},))

chỉ Enter, fill xuống và qua phải.

Thân

thầy thật lắm chiêu trò! tà đạo cao cấp.

Phan Thế Hiệp · Thứ sáu lúc 21:40

dungpham01 đã viết:
thầy thật lắm chiêu trò! tà đạo cao cấp.
View attachment 310907

Cái bùa T(IF({1},...)) đã được anh em trên diễn đàn GPE đem ra xài cách đây gần chục năm rồi, ChatGPT còn chưa ra đời nữa lấy đâu mà 'đánh' với 'giá'.

/-*+/

Tổng hợp hóa chất sử dụng theo tháng (1 người xem)

Người dùng đang xem chủ đề này

Thành viên mới

File đính kèm

Thành viên hoạt động

Thành viên mới

Thành viên hoạt động

File đính kèm

Thành viên chính thức

File đính kèm

-⍟-

Thành viên mới

-⍟-

File đính kèm

Thành viên chính thức

Thành viên chính thức

File đính kèm

Thành viên chính thức

File đính kèm

Thành viên mới

Thành viên chính thức

-⍟-

File đính kèm

Chuyên gia GPE

Thành viên chính thức

-⍟-

Thời gian đếm ngược.