Tính toán với nhiều đơn vị tính (đvt) khác nhau ? (3 người xem)

[today100506]

Dữ liệu đã có:

- Slg Nhập (đvt bất kỳ)
- Slg Tồn cuối (đvt bất kỳ)

Yêu cầu: Tính SlgXuat dựa vào SlgNhap & SlgTonCuoi

Em có gửi kèm file mẫu. Mong mọi người giúp đỡ. XIN CẢM ƠN !

 

[vanle33]

Dữ liệu đã có:

- Slg Nhập (đvt bất kỳ)
- Slg Tồn cuối (đvt bất kỳ)

Yêu cầu: Tính SlgXuat dựa vào SlgNhap & SlgTonCuoi

Em có gửi kèm file mẫu. Mong mọi người giúp đỡ. XIN CẢM ƠN !

Theo mình dùng hàm SUMPRODUCT, bạn cho kết quả đúng ở cột F ví dụ F2 đi?

 

[today100506]

Đây là file mẫu (có kèm dữ liệu thực tế). hơi khó nhìn. mong các anh chị giúp.

Theo mình dùng hàm SUMPRODUCT, bạn cho kết quả đúng ở cột F ví dụ F2 đi?

Cảm ơn bạn vanle33, cái khó là đvt khác nhau. mình cần có một công thức để quy đổi ra 1 slg chung rùi tính. mong bạn giúp. Mình bị rối ở chỗ quy đổi đvt cho linh hoạt ấy. (1 ct cho mọi sản phẩm).

 

[ChanhTQ@]

Bạn thử lập bảng tra & dùng hàm VLOOKUP() thôi

Cảm ơn bạn vanle33, cái khó là đvt khác nhau. mình cần có một công thức để quy đổi ra 1 slg chung rùi tính. mong bạn giúp. Mình bị rối ở chỗ quy đổi đvt cho linh hoạt ấy. (1 ct cho mọi sản phẩm).

Bạn lập bảng sau:

| J | K | L | M | N 2 | ĐVT | Thung | Hop | Bich | Goi 3 | Thung |1|2|10|100
4 | Hop |0.5|1|5|50
5 | Bich |0.1|0.2|1|10
6 | Goi |0.01|0.02|0.1|1

Bảng này được gán cái tên, như 'DVT'

Tại [F2] bạn áp công thức:

=B2*VLOOKUP(C2,DVT,IF(E2="Thung",2,IF(E2="Hop",3,IF(E2="Bich",4,5))),FALSE)-D2
​

Sau đó bạn kiểm các kết quả xem sao.

 

[today100506]

Bạn lập bảng sau:

| J | K | L | M | N 2 | ĐVT | Thung | Hop | Bich | Goi 3 | Thung |1|2|10|100
4 | Hop |0.5|1|5|50
5 | Bich |0.1|0.2|1|10
6 | Goi |0.01|0.02|0.1|1

Bảng này được gán cái tên, như 'DVT'

Tại [F2] bạn áp công thức:

=B2*VLOOKUP(C2,DVT,IF(E2="Thung",2,IF(E2="Hop",3,IF(E2="Bich",4,5))),FALSE)-D2
​

Sau đó bạn kiểm các kết quả xem sao.

Cảm ơn bạn. Đây cũng là một cách. Nhưng chỉ áp dụng được cho 1 sản phẩm/ hoặc 1 loạt các sản phẩm có cùng hệ số dvt (thùng, hộp, bịch...). Mình cần cách linh hoạt hơn áp dụng cho nhiều loại sản phẩm, mặt hàng có dvt không giống nhau như file thực tế kèm theo. Mong các bạn nhiệt tình giúp đỡ.

 

[sealand]

Bài này mình đã làm nhưng khi trả lời thì bị khoá.
Theo mình thấy ở tất cả các phần mềm quản lý kho hàng thì đối với 1 hàng hoá có nhiều đơn vị tính phải quy ước 1 đơn vị cơ sở và các đơn vị khác đều quy đổi dựa trên đơn vị cơ
sở. Đối với bài này ta nên tính toán theo gói còn đơn vị ra sao ta quy đổi trả về theo yêu cầu.
Trong file ví dụ hôm nay đã gửi bạn thiếu đơn vị xuất tính là gì? Vậy mình thêm 1 cột cho đơn vị xuất.

Đây là công thức cho ô F2

=(B2*LOOKUP(C2,{"bich","goi","hop","thung"},{10,1,50,100})-D2*LOOKUP(E2,{"bich","goi","hop","thung"},{10,1,50,100}))/LOOKUP(G2,{"bich","goi","hop","thung"},{10,1,50,100})

Trong đó:
B2: Lượng nhập, C2: dơn vị nhập
D2: Lượng tồn, E2: dơn vị tồn
F2: Lượng xuất, G2: dơn vị xuất

Bạn xem trong file ví dụ nha (Có xuất âm vì nhập 1 gói mà tồn 0,1 thùng=10 gói thí xuất âm (Nhập vào) 9 gói)

P/s: Giờ mới phát hiện bạn quy định xuất theo đơn vị tồn cuối Vậy bạn thay G2 bằng E2 rồi filldown nha)

 

[today100506]

Xin chào các bạn !

Mình đã tìm được hướng giải quyết tính slg theo nhiều đvt khác nhau:

SP Thung Hop Bich Goi
a Thung 1 2 10 100
a Hop 0.5 1 5 50
a Bich 0.1 0.2 1 10


=OFFSET($H$2,MATCH($C2,DVT_1,0),MATCH($D2,DVT_2,0))

Nhưng mình chưa match được đvt với từng tên hàng.

Mong các bạn giúp đỡ (có kèm theo file mẫu).

Xin cảm ơn !

Em cảm ơn bác ndu96081631đã quan tâm.
Bác vui lòng giúp em công thức luôn nhé.
Em xin cảm on !

 

[nhapmon]

Xin chào các bạn !

Mình đã tìm được hướng giải quyết tính slg theo nhiều đvt khác nhau:

SP Thung Hop Bich Goi
a Thung 1 2 10 100
a Hop 0.5 1 5 50
a Bich 0.1 0.2 1 10


=OFFSET($H$2,MATCH($C2,DVT_1,0),MATCH($D2,DVT_2,0))

Nhưng mình chưa match được đvt với từng tên hàng.

Mong các bạn giúp đỡ (có kèm theo file mẫu).

Xin cảm ơn !

bạn xem có được ko.
mình làm ở sheet (du lieu vidu).
1- sữa "a" thành "sp 1"
2- yêu cầu nhâp đợn vị lớn, t6on đơn vị nhỏ.
vi du nhập vào là thùng thì tồn đơn vị hợp, bịch, gói. ko là ngược lại

F2=PRODUCT(INDIRECT(ADDRESS(MATCH(A2,$J$3:$J$4,0)+2,MATCH(C2,$J$2:$N$2,0)+10) & ":" & ADDRESS(MATCH(A2,$J$3:$J$4,0)+2,MATCH(E2,$J$2:$N$2,0)+9)))*B2-D2
bạn có thể đạt thành name cho cthức gọn lại

 

[arexthena]

File đính kèm

Bạn xem file đính kèm nhé. Mình làm theo nguyên tắc đổi hết ra đơn vị nhỏ nhất, trừ cho nhau rồi đổi ngược lại đơn vị cần tính.
Note: file đã thêm số "1" vào dưới ô "gói"
WR!

 

[sealand]

Tôi tham gia thế này, nếu các bạn vẫn đi theo hướng này sẽ đi vào lối cụt vì các bạn phải liên tưởng thực tế 1 chút
-Trong kho có rất nhiều hàng hoá khác nhau được đóng gói với quy cách khác nhau.
-Mỗi sản phẩm lại có các đơn vị tính khác nhau ví dụ:
Đinh vít: Gói-Bịch-Hộp-Thùng.
Sắt Soắn phi18: Kg-Cây-Bó-Kiện
-Khi xuất nhập loại đơn vị nào thì cộng trừ đơn vị đó để còn theo dõi hàng nguyên kiện, nguyên bó, nguyên cây hay chặt lẻ
Vậy nên ta phải có bảng hệ thống đơn vị tính với hệ số quy đổi cho tất cả các loại SP. Khi xuất nhập kho cũng phải có nguyên tắc trừ kho hợp lý. Ví dụ như trong bài của bạn không phải cứ còn 6 hop là còn 3 thung mà dở dang đến 4 thùng thì sao.
Mình tham gia thế này muốn ta tìm giải pháp cho cơ sở đã rồi tính toán phát triển. Chứ làm chán rồi cuối cùng không ráp vào yêu càu thì dở ẹc.

 

[today100506]

Tôi tham gia thế này, nếu các bạn vẫn đi theo hướng này sẽ đi vào lối cụt vì các bạn phải liên tưởng thực tế 1 chút
-Trong kho có rất nhiều hàng hoá khác nhau được đóng gói với quy cách khác nhau.
-Mỗi sản phẩm lại có các đơn vị tính khác nhau ví dụ:
Đinh vít: Gói-Bịch-Hộp-Thùng.
Sắt Soắn phi18: Kg-Cây-Bó-Kiện
-Khi xuất nhập loại đơn vị nào thì cộng trừ đơn vị đó để còn theo dõi hàng nguyên kiện, nguyên bó, nguyên cây hay chặt lẻ
Vậy nên ta phải có bảng hệ thống đơn vị tính với hệ số quy đổi cho tất cả các loại SP. Khi xuất nhập kho cũng phải có nguyên tắc trừ kho hợp lý. Ví dụ như trong bài của bạn không phải cứ còn 6 hop là còn 3 thung mà dở dang đến 4 thùng thì sao.
Mình tham gia thế này muốn ta tìm giải pháp cho cơ sở đã rồi tính toán phát triển. Chứ làm chán rồi cuối cùng không ráp vào yêu càu thì dở ẹc.

BẠN sealand NÓI ĐÚNG Ý MÌNH MUỐN HỎI RỒI ĐÓ.

MÌNH ĐÃ CÓ HƯỚNG GIẢI QUYẾT.
MÌNH ĐÃ MATCH ĐƯỢC ĐVT CỦA DÒNG/CỘT, NHƯNG CHƯA KẾT HỢP ĐƯỢC VỚI TÊN HÀNG.
CÁC BẠN XEM FILE MẪU MỚI, RỒI CHỈ MÌNH CÔNG THỨC NHÉ.

 

[arexthena]

Linh động một chút đi, dùng file bên trên của tôi, nhập các chỉ số cho sản phẩm mới trong bảng quy đổi,thay số "1" trong hàm offset của column= match tên hàng trong bảng đơn vị tính với tên hàng trong bảng cần tính là được. Yêu cầu là các tên hàng nhập ở 2 bảng phải khớp với nhau.

 

[today100506]

Bạn arexthena ơi, bạn ghi ghi công thức cho mình luôn nha. mình chưa hiểu lắm.

 

[arexthena]

Trong của bạn, đầu tiên sửa tên sản phẩm ở 2 bảng cho khớp nhau, sau đó chép công thức này vô ô e2:
=OFFSET($H$2,MATCH($C2,DVT_1,0)+MATCH(A2,$G$3:$G$11,0)-1,MATCH($D2,DVT_2,0))
...và tự thêm số kiểm tra kết quả!
QUOTE=today100506;511547]Bạn arexthena ơi, bạn ghi ghi công thức cho mình luôn nha. mình chưa hiểu lắm.[/QUOTE]

 

[arexthena]

P/S: dùng file excel mẫu mới của bạn nhé!

 

[vodoi2x]

BẠN sealand NÓI ĐÚNG Ý MÌNH MUỐN HỎI RỒI ĐÓ.

MÌNH ĐÃ CÓ HƯỚNG GIẢI QUYẾT.
MÌNH ĐÃ MATCH ĐƯỢC ĐVT CỦA DÒNG/CỘT, NHƯNG CHƯA KẾT HỢP ĐƯỢC VỚI TÊN HÀNG.
CÁC BẠN XEM FILE MẪU MỚI, RỒI CHỈ MÌNH CÔNG THỨC NHÉ.

Hướng giải quyết gì chứ? thấy cũng match thường thường ah,

Thử phương án này:

- sửa name DVT_1 thành
=test!$H$3:$H$11

-thêm 1 name đặt là: SP
=test!$G$3:$G$11

-thì có thể sử dụng 1 trong 2 công thức sau
=OFFSET($H$2,MATCH(1,INDEX((DVT_1=C2)*(A2=SP),0),0),MATCH($D2,DVT_2,0))

hoặc

=HLOOKUP(D2,$I$2:$L$11,1+MATCH(1,INDEX((DVT_1=C2)*(A2=SP),0),0),0)
(nếu thích thì đặt name cho vùng $I$2:$L$11, thì gọn hơn chút)

 

[today100506]

Đúng rồi. cảm ơn bạn.
để mình test xem sao...chưa close topic đâu....hiii...

 

[vodoi2x]

Đúng rồi. cảm ơn bạn.
để mình test xem sao...chưa close topic đâu....hiii...

Nhiều cách lém, đây là 1 phương án nữa


Hoặc không cần name gì cả (xóa hết các name đi)
Sử dụng công thức sau cho E2

=LOOKUP(2,1/($G$3:$G$11=A2)/($H$3:$H$11=C2),INDEX($I$3:$L$11,0,MATCH(D2,$I$2:$L$2,0)))

dĩ nhiên ta có thể đặt name cho phù hợp công thức này

 

[today100506]

Cảm ơn các bạn. Mình đang fill dữ liệu, sẽ up lên cho các bạn cùng tham khảo...hiiii

Xin chào các bạn.

Xin cảm ơn bạn arexthena, vodoix2, và các bạn khác đã giúp đỡ mình.

Sau khi kiểm tra, mình thấy:

Công thức của bạn ảexthena ra kết quả chưa chính xác.

Công thức của bạn vodoix2 đã ra kết quả chính xác.

Sau đây mình sẽ up file dữ liệu thực tế lên cho các bạn xem. Các bạn nào có ý tưởng, cách trình bày, hay công thức nào hay hơn có thể post lên cho ae học hỏi thêm...xin cảm ơn.


Ah, mình còn thắc mắc: Trong khi chuyển đổi đơn vị tính (ĐVT) mình phải quy đổi ra hệ số (thùng/bịch/gói) bằng tay.
Ví dụ: Thùng 01_______Bịch 2____Gói 20 (một thùng có 2 bịch, 20 gói)
Bạn nào có cách cho nó tính bằng công thức luôn, thì giúp mình nhé, nhớ là áp dụng cho rất nhiều mặt hàng...
có kèm file mẫu (FILE 1) ở dưới đó.

 

[today100506]

Lại phát sinh vấn đề nữa rồi :

Mỗi ngày nhập nhiều mặt hàng.
Mỗi mặt hàng mỗi ngày lại có những đơn vị tính khác nhau.

[TABLE="class: outer_border, width: 500"]
[TR]
[TD]NGÀY NHẬP[/TD]
[TD]TÊN HÀNG[/TD]
[TD]ĐVT[/TD]
[TD]SLG NHẬP[/TD]
[/TR]
[TR]
[TD]1/6/13[/TD]
[TD]Gạo 504 (nhân viên)[/TD]
[TD]BAO[/TD]
[TD]1[/TD]
[/TR]
[TR]
[TD]3/6/13[/TD]
[TD]Gạo 504 (nhân viên)[/TD]
[TD]Kg[/TD]
[TD]5[/TD]
[/TR]
[TR]
[TD]10/6/13[/TD]
[TD]BAO MUỖNG[/TD]
[TD]Thùng[/TD]
[TD]1[/TD]
[/TR]
[TR]
[TD]10/6/13[/TD]
[TD]BAO MUỖNG[/TD]
[TD]Bịch[/TD]
[TD]1[/TD]
[/TR]
[TR]
[TD]15/6/13[/TD]
[TD]BAO MUỖNG[/TD]
[TD]Xấp[/TD]
[TD]1[/TD]
[/TR]
[TR]
[TD]20/6/13[/TD]
[TD]BAO MUỖNG[/TD]
[TD]Cây[/TD]
[TD]100[/TD]
[/TR]
[/TABLE]

Hiện tại mình làm được thế này:

=SUMIFS(slgNhap,tenhangNhap,$A2,ngayNhap,$H$1,ngayNhap,$H$2)*OFFSET('BANG DON VI TINH'!$D$2,MATCH(1,INDEX((DVT_1=C2)*(A2=sp),0),0 )+1,MATCH($D2,DVT_2,0))

Mình lấy tổng sumifs sau khi tính toán * hệ số ĐVT.
Như vậy chỉ sumifs được các sản phẩm theo cùng 1 đvt thôi.
Mình muốn sumifs các sản phẩm có những đvt khác nhau từ ngày...đến ngày...


FILE MẪU NÈ CÁC BẠN >>>