Xin giúp phân chia dử liệu trong excel

[Đá Hoa Cương Đức Hiếu]

Mình có một đoạn văn bản như sau:
"phân chia văn bản 0909090909 văn bản gì đó"
Dãy số thường là từ 9 -> 11 số, nằm bất kì nơi đâu trong đoạn văn.
Mình muốn nó phân chia ra theo cột chử 1 bên, số một bên thì làm sao ạ?
Cảm ơn các bạn.

 

[Hoang2013]

Như âậy cần tối thiểu 3 cột để chứa kết quả sau phân chia;

Cái này VBA làm vô tư; Chỉ sợ bạn không ưa nó thôi.

 

[eke_rula]

Mình có một đoạn văn bản như sau:
"phân chia văn bản 0909090909 văn bản gì đó"
Dãy số thường là từ 9 -> 11 số, nằm bất kì nơi đâu trong đoạn văn.
Mình muốn nó phân chia ra theo cột chử 1 bên, số một bên thì làm sao ạ?
Cảm ơn các bạn.

Giả sử chuỗi của bạn nằm ở A1, Bạn dùng các CT này ở B1,C1:
Tách số :

B1=LOOKUP(2,1/FIND(REPT("0",ROW(1:11))&AGGREGATE(14,6,--MID(A1,ROW(1:100),{9,10,11}),1),A1),REPT("0",ROW(1:11))&AGGREGATE(14,6,--MID(A1,ROW(1:100),{9,10,11}),1))
C1=TRIM(SUBSTITUTE(A1,B1,""))

 

[quocgiacan]

Giả sử chuỗi của bạn nằm ở A1, Bạn dùng các CT này ở B1,C1:
Tách số :

B1=LOOKUP(2,1/FIND(REPT("0",ROW(1:11))&AGGREGATE(14,6,--MID(A1,ROW(1:100),{9,10,11}),1),A1),REPT("0",ROW(1:11))&AGGREGATE(14,6,--MID(A1,ROW(1:100),{9,10,11}),1))
C1=TRIM(SUBSTITUTE(A1,B1,""))

Khà khà khà!

Anh thấy trước nay em chơi theo kiểu này, nay trình diễn kiểu mới nữa rồi!

B1=TRIM(LOOKUP(10^12,MID(SUBSTITUTE(A1," ",REPT(" ",100)),(ROW(1:100)-1)*100+1,100)*1,MID(SUBSTITUTE(A1," ",REPT(" ",100)),(ROW(1:100)-1)*100+1,100)))

Chúc anh em ngày thiệt vui.

 

[eke_rula]

Khà khà khà!

Anh thấy trước nay em chơi theo kiểu này, nay trình diễn kiểu mới nữa rồi!

B1=TRIM(LOOKUP(10^12,MID(SUBSTITUTE(A1," ",REPT(" ",100)),(ROW(1:100)-1)*100+1,100)*1,MID(SUBSTITUTE(A1," ",REPT(" ",100)),(ROW(1:100)-1)*100+1,100)))

Chúc anh em ngày thiệt vui.

Ct này của anh hên xui, lỡ không có cách khoảng hoặc >=2 chuỗi số, ví dụ có thêm chuỗi số "12" và nó đứng sau số cần tìm thì...hehe, nhưng em nghĩ CT này đáp ứng đủ yêu cầu rồi!!!

 

[bebo021999]

Một cách khác dựa theo SEARCH chuỗi từ 0-9:

=IF(MID(A1,MIN(IFERROR(SEARCH(ROW(1:10)-1,A1),"")),1)="0",0,"")&
IFERROR(--MID(A1,MIN(IFERROR(SEARCH(ROW(1:10)-1,A1),"")),{9,10,11}),"")

Ctrl-shift-enter