Tìm kết quả cho x trong khoảng a-b

[Bả.o Hương]

Giúp e tìm ra hàm phù hợp với ạ

 

[SA_DQ]

Hàm =IF() đi bạn, OK liền hà!

 

[CHAOQUAY]

Giúp e tìm ra hàm phù hợp với ạ

=IFERROR("Mức "&MATCH(A1,{90;150;250}),"")

A1 là ô dữ liệu của bạn

 

[Lê Duy Thương]

Giúp e tìm ra hàm phù hợp với ạ

Hàm phù hợp với em đây . Thay đổi số ở A1. khẹc khẹc

=LOOKUP($A$1,{0,90,150,250},{0,1,2,3})

 

[leonguyenz]

Giúp e tìm ra hàm phù hợp với ạ

Hàm IF rất thông dụng và dễ hiểu, nếu chỉ 3, 4 điều kiện thì có thể sử dụng IF, công thức:

=IF(A1<90,0,IF(A1<150,1,IF(A1<250,2,3)))

 

[Phuocam]

Góp vui:

=MATCH(A1,{0;90;150;250})-1

 

[HieuCD]

Cách khác
=SUM(N(A1>={90;150;250}))

 

[Nhattanktnn]

Vậy cũng thêm tí xíu:

=COUNT(IF(A1>={90,150,250},1))

 

[ndu96081631]

Vậy cũng thêm tí xíu:

=COUNT(IF(A1>={90,150,250},1))

Hàm COUNT có 1 tính chất là không đếm giá trị lỗi, mình lợi dụng tính chất này để "chơi chiêu" như sau:

=COUNT(1/(A1>={90,150,250}))

 

[VetMini]

Ngồi buồn, chọc cho thiên hạ chửi chơi:

Bài #3: =IFERROR("Mức "&MATCH(A1,{90;150;250}),"")
Trung bình 2 searches (căn hai số phần tử mảng). Tuy nhiên vì có IfError cno nên thêm 1 con toán.

Bài #4: =LOOKUP($A$1,{0,90,150,250},{0,1,2,3})
Trung bình 2 searches. Cộng thêm 1 truy xuất mảng thứ 2.

Bài #5: =IF(A1<90,0,IF(A1<150,1,IF(A1<250,2,3)))
Trung bình 2 so sánh (phân nửa số IF's). Và 2 Lô gic. Tuy hàm trông hơi khó đọc nhưng thực tế rất hiệu quả.

Bài #6: =MATCH(A1,{0;90;150;250})-1
Trung bình 2 searches. Cộng thêm một con toán trừ

Bài #7: =SUM(N(A1>={90;150;250}))
3 so sánh. 3 con toán đổi kiểu. Và một con toán tổng (thực sự tôi không biết Excel tổng một mảng bằng giải thuật nào)

Bài #8: =COUNT(IF(A1>={90,150,250},1))
3 so sánh. 3 con toán lô gic. Và một con toán tổng.

Bài #9: =COUNT(1/(A1>={90,150,250}))
3 so sánh. 3 con toán chia. Và một con toán tổng.

Hiệu quả của từng phương pháp tuỳ thuộc vào số phần tử mảng.
Lưu ý là các hàm có chứa mảng ở trên, lúc gõ vào thì Excel còn phải thêm con toán lập mảng.