Cách tính ngày đến hạn!

[tienduyet]

Chào anh/chị! Em đang là một Kế toán viên ở một Quỹ tín dụng cơ sở nho nhỏ - một miền quê Nam Định. Em có rắc rối xin được anh/chị thỉnh giáo.
Chuyện là thế này. Ở lịch đời thường ta thường biết Tháng 2 của năm nào chia hết cho 4 -> thì năm đó Tháng 2 có 29 ngày, còn lại là 28 ngày. Nhưng trong Excel thì em phải dùng công thức như thế nào để biết được năm đó là năm chia hết cho 4, và năm nào là năm không chia hết cho 4.
Ví dụ em có dữ liệu như sau: Ngày gửi là 31/12/2008, kỳ hạn gửi là 02 tháng -->> tính bằng "miệng" thì em biết được ngày đến hạn là 28/02/2009. Nhưng làm thế nào để em biết được Ngày đến hạn là 28 chứ không phải là 31 (vì tháng 02/2009 chỉ có 28 ngày thôi mà), Tháng đến hạn là 02 và Năm đến hạn là 2009.
Mong được anh/chị chỉ giáo! Em xin cảm ơn.

 

[BNTT]

Bạn dùng hàm này nhé: =EOMONTH("31/12/2008", 2)

EOMONTH là viết tắt của chữ End Of Month (ngày cuối tháng), và con số 2 là số kỳ hạn. Công thức này tìm ngày cuối tháng của tháng cách ngày đã cho 2 tháng.

Nếu như ngày người ta vay tiền không phải là một ngày cuối tháng, thì bạn dùng hàm EDATE() với cú pháp như sau: =EDATE(Ngày vay, Kỳ hạn)

Ví dụ, nếu ngày vay là 29/11/2007, kỳ hạn 3 tháng, bạn gõ: =EDATE("29/11/2008", 3)

Chắc ăn hơn nữa, thì bạn dùng: =EOMONTH(DATE(2008,12,31), 2) và =EDATE(DATE(2008,11,29), 3) thay cho hai công thức ở trên.



Bạn xem thêm ở đây: Hàm EOMONTH(), Hàm EDATE() và Hàm DATE()

Hoặc nếu có thời gian thì đọc bài này: Các Hàm ngày tháng và thời gian

 

[tienduyet]

Ôi.................................
Em cản ơn anh nhiều lắm. Em thử rồi mấy hàm anh đưa cho "CỰC KỲ" hiệu quả.
Cảm ơn anh nhiều lắm!
(Anh ah, thế trong Access em dùng hàm gì vậy anh)

 

[sealand]

Các công thức BNTT đưa ra là của Excel 2007 thì phải, nếu Version thấp hơn thì không áp dụng được. Tôi tham gia mẹo nhỏ là lấy ngày 1 tháng sau trừ 1 chắc đúng khỏi lo năm nhuận, tháng thiếu...

 

[salam]

Các công thức BNTT đưa ra là của Excel 2007 thì phải, nếu Version thấp hơn thì không áp dụng được. Tôi tham gia mẹo nhỏ là lấy ngày 1 tháng sau trừ 1 chắc đúng khỏi lo năm nhuận, tháng thiếu...

Các hàm trên là trong analysis toolpak mà. còn nếu muốn lấy ngày cuối tháng mà không cài analysis toolpak bạn dùng ct day(date(year,month+1,0)).

 

[ndu96081631]

Cái này:

Các công thức BNTT đưa ra là của Excel 2007 thì phải, nếu Version thấp hơn thì không áp dụng được. Tôi tham gia mẹo nhỏ là lấy ngày 1 tháng sau trừ 1 chắc đúng khỏi lo năm nhuận, tháng thiếu...

Và cái này:

Các hàm trên là trong analysis toolpak mà. còn nếu muốn lấy ngày cuối tháng mà không cài analysis toolpak bạn dùng ct day(date(year,month+1,0)).

Là để tính ngày cuối tháng! Còn tác giã muốn tính ngày đến hạn sau bao nhiêu tháng cho trước cơ mà! Đâu có giống nhau

 

[BNTT]

Các công thức BNTT đưa ra là của Excel 2007 thì phải, nếu Version thấp hơn thì không áp dụng được. Tôi tham gia mẹo nhỏ là lấy ngày 1 tháng sau trừ 1 chắc đúng khỏi lo năm nhuận, tháng thiếu...

Các hàm tôi đưa ra trong bài trên có trong Excel 2003, với điều kiện bạn phải cài đặt Add-in Analysis ToolPak.

Nếu chưa biết Add-in này là cái gì, bạn tìm hiểu ở đây: Analysis ToolPak

 

[salam]

Cái này:

Và cái này:

Là để tính ngày cuối tháng! Còn tác giã muốn tính ngày đến hạn sau bao nhiêu tháng cho trước cơ mà! Đâu có giống nhau

Em theo cái dưới này mà.

Tôi tham gia mẹo nhỏ là lấy ngày 1 tháng sau trừ 1 chắc đúng khỏi lo năm nhuận

 

[tienduyet]

anh Salam ah, em dùng hàm EDate() là tính được ngày đến hạn anh ah. Tốt ý chứ anh.
thế giờ hai anh có thể giúp em công thức tính Ngày đến hạn trong Access, được không ah?tiện thể hai anh chỉ dẫn cho em cách đánh số thứ tự (tức là số chứng từ) tăng dần trong Access mà không phải dùng AutoNumber.
Cảm ơn hai anh, cảm ơn anh/chị giúp đỡ em

 

[viehoai]

Công thức tính ngày đến hạn theo chu kỳ thời gian là Năm, Tháng hoặc ngày

Loay hoay mãi không tính được ngày tới hạn sắp đến của chu kỳ thời gian
Em tạm tính theo cách dưới đây, nhưng theo suy nghĩ của em không chính xác một số trường hợp. Các anh chị có cách nào khác mong được giúp đỡ.
Xin cảm ơn.

 

[Phuocam]

Loay hoay mãi không tính được ngày tới hạn sắp đến của chu kỳ thời gian
Em tạm tính theo cách dưới đây, nhưng theo suy nghĩ của em không chính xác một số trường hợp. Các anh chị có cách nào khác mong được giúp đỡ.
Xin cảm ơn.

Chưa hiểu ý bạn, làm đại ...

G3 =IF(F3="ngay",D3+E3,EDATE(D3,E3*IF(F3="nam",12,1)))

 

[viehoai]

Chưa hiểu ý bạn, làm đại ...

G3 =IF(F3="ngay",D3+E3,EDATE(D3,E3*IF(F3="nam",12,1)))

Cách bạn tính ngày đến hạn chu kỳ đầu tiên, thời gian đó qua rồi, tính làm gì nữa, mình cần tính ngày sẽ đến hạn sắp đến. Bạn xem file mình minh họa bên dưới nhé

 

[Phuocam]

Cách bạn tính ngày đến hạn chu kỳ đầu tiên, thời gian đó qua rồi, tính làm gì nữa, mình cần tính ngày sẽ đến hạn sắp đến. Bạn xem file mình minh họa bên dưới nhé

Ví dụ chu kỳ cột I

=IF(F3="ngay",D3+E3*I3,EDATE(D3,E3*IF(F3="nam",12,1)*I3))

 

[viehoai]

Ví dụ chu kỳ cột I

=IF(F3="ngay",D3+E3*I3,EDATE(D3,E3*IF(F3="nam",12,1)*I3))

Nếu Bạn lấy cột I của mình để tính, thì chắc chắn kết quả giống mình. Vấn đề ở chỗ mính tính số chu kỳ (cột H, I) không chuẫn, dẫn đến một số kết quả sẽ sai. Sai ở chỗ mình dùng công thức H3=DATEDIF(D3;TODAY();"d")/E3/IF(F3="nam";365;IF(F3="thang";30;1)) sử dụng con số 365, 30 để tính số chu kỳ chắc chắn sẽ không chuẩn

 

[Phuocam]

Chừ thì em đã hiểu:

=IF(F3="ngay",D3+CEILING(TODAY()-D3,E3),EDATE(D3,CEILING(DATEDIF(D3,TODAY(),"m"),IF(F3="nam",E3*12,E3))))

 

[Phuocam]

Công thức bài 15 bị lỗi, xin sửa lại là:

=IF(F3="ngay",D3+CEILING(TODAY()-D3,E3),EDATE(D3,CEILING(DATEDIF(D3,TODAY(),"m")+(DAY(TODAY())>DAY(D3)),IF(F3="nam",E3*12,E3))))

Phần màu đỏ mới thêm vào.

 

[viehoai]

Chừ thì em đã hiểu:

=IF(F3="ngay",D3+CEILING(TODAY()-D3,E3),EDATE(D3,CEILING(DATEDIF(D3,TODAY(),"m"),IF(F3="nam",E3*12,E3))))

Công thức của bạn vẫn chưa chuẩn
VD ngày đầu: 10/8/2003, chu kỳ 6 tháng. Công thức bạn tính ra ngày 10/8/2016 (ngày này đã qua rồi) chỉ tính ngày tới hạn hiện tại hoặc tương lai gần

 

[Phuocam]

Công thức của bạn vẫn chưa chuẩn
VD ngày đầu: 10/8/2003, chu kỳ 6 tháng. Công thức bạn tính ra ngày 10/8/2016 (ngày này đã qua rồi) chỉ tính ngày tới hạn hiện tại hoặc tương lai gần

Đã cập nhật bài 16 .

 

[viehoai]

Đã cập nhật bài 16 .

Công thức của Bạn giống như công thức của mình trong trường hợp ngày đầu 28/8/2013, chu kỳ 6 tháng kết quả công thức tính 28/2/2017. Trong khi đó kết quả cần là 28/8/2016
Xin lỗi mình nhầm rồi, nhầm hôm nay ngày 28/8/2016
Kính nhờ Mod xóa bài này, xin cảm ơn

 

[lenongree]

Cách bạn tính ngày đến hạn chu kỳ đầu tiên, thời gian đó qua rồi, tính làm gì nữa, mình cần tính ngày sẽ đến hạn sắp đến. Bạn xem file mình minh họa bên dưới nhé

Cho bạn thêm 1 cách:

=IF(F3="ngay",LOOKUP(TODAY()+E3,D3+E3*ROW($1:$100)),LOOKUP(EDATE(TODAY(),E3*IF(F3="nam",12,1)),EDATE(D3,E3*IF(F3="nam",12,1)*ROW($1:$100))))

Rồi fill xuống!!!