Tính chiết khấu!

[thu_love]

Đề bài:
gọi phần doanh số từ 200tr đến dưới 1tỷ là K1, số tiền được chiết khấu là N1
gọi phần doanh số từ 1Tỷ đến dưới 2.5tỷ là K2, số tiền được chiết khấu là N2
gọi phần doanh số từ 2.5tỷ đến dưới 5tỷ là K3, số tiền được chiết khấu là N3
gọi phần doanh số từ 5 tỷ trở lên là K4, số tiền được chiết khấu là N4

Yêu Cầu:
N1 = ( K1 - 200tr)*2%
N2 = ( K2 - 1tỷ ) *3% + 16tr
N3 = (K3 - 2.5tỷ)*4% + 61tr
N4 = (K4 - 5tỷ ) *5% +161tr

dùng công thức để tính chiết khấu chi tiết

Anh nào giúp em với nhé!

 

[chucuoi92]

Bạn thử cái này xem có đúng không?!
Mình cũng chưa test
Với A7 là doanh thu

=IF(A7>5*10^9,(A7-5*10^9)*5%+161000000,IF(A7>2.5*10^9,(A7-2.5*10^9)*4%+61000000,IF(A7>10^9,(A7-10^9)*3%+16000000,IF(A7>=2*10^8,(A7-2*10^8)*2%,""))))

 

[cadafi]

........
Yêu Cầu:
N1 = ( K1 - 200tr)*2%
N2 = ( K2 - 1tỷ ) *3% + 16tr
N3 = (K3 - 2.5tỷ)*4% + 61tr
N4 = (K4 - 5tỷ ) *5% +161tr

dùng công thức để tính chiết khấu chi tiết

Bạn xài đỡ công thức củ chuối này nhé!
Ví dụ Ô A1 là ô chứa doanh số:

=CHOOSE(((A1>=2*10^8)+(A1>10^9)+(A1>2.5*10^9)+(A1>5*10^9))+1,0,(A1-2*10^8)*2%,(A1-10^9)*3%+16*10^6,(A1-2.5*10^9)*4%+61*10^6,(A1-5*10^9)*5%+161*10^6)

 

[BNTT]

Các bài giải trên đây đều đúng. Tuy nhiên, cũng xin giới thiệu một phương pháp khác:

Kẻ một bảng như sau:

Và tại ô tính chiết khấu (C9), dùng công thức:

=(C8 - VLOOKUP(C8,A2:C6,1))*VLOOKUP(C8,A2:C6,2) + VLOOKUP(C8,A2:C6,3)​

Ưu điểm của phương pháp này là: Bạn có thể tùy ý thay đổi mức chiết khấu cũng như mức tiền thưởng, mà không cần phải sửa lại công thức.

 

[huuthang_bd]

Ngắn hơn một tẹo

=SUMPRODUCT(--(A1/(10^8)>{2,10,25,50}),A1-{2,10,25,50}*10^8,{2,1,1,1}/100)

 

[thu_love]

Cảm ơn các anh, có gì em sẽ nhờ tiếp