nối chuỗi trong Excel

[dghoa]

Chào các bạn!

Trong sheet của Excel, ở cell A1 có giá trị là ABC.
cell A2 có giá trị là CBA

Ở cell A3, mình muốn làm 1 Công Thức như sau :

A3 = 1 chuỗi *** + giá trị của Cell A1 + 1 chuỗi YYY + giá trị của cell A2

Để cho ra được kết quả là một chuỗi mới, mình phải sử dụng lệnh như thế nào?

Xin các bạn chỉ giúp, cám ơn thật nhiều!

 

[duongdv]

Có phải ý bạn muốn vậy
- Cách 1
= "***"&A1&"YYY"&A2
- Cách 2
=CONCATENATE("***",A1,"yyy",A2)

 

[dghoa]

trường hợp của mình thì phải làm sao,ví dụ như ô D6 phải hiển thị là "đường pháp"chẳng hạn,mình thử rồi mà bị báo lỗi.bạn xem giùm mình nhé!

 

[BNTT]

trường hợp của mình thì phải làm sao,ví dụ như ô D6 phải hiển thị là "đường pháp"chẳng hạn,mình thử rồi mà bị báo lỗi.bạn xem giùm mình nhé!

Công thức của bạn bị lỗi ở chỗ này:

=CONCATENATE(VLOOKUP(LEFT(C6,2),$B$25:$C$29,2,0), HLOOKUP(RIGHT(C6,1),$H$24:$M$25,2,0))​

Hàm RIGHT sẽ trả về giá trị text (ký tự "1", chứ không phải là con số 1, bạn phân biệt được chứ), trong khi những cái 1, 2, 3, 4, 5 ở bảng loại hàng lại là những con số thật, do đó HLOOKUP sẽ không thể dò ra, và báo lỗi #NA!

Bạn cần phải chuyển kết quả của hàm RIGHT trở thành dạng số, bằng cách nhân kết quả của nó với 1, hoặc là dùng hàm VALUE, tuy nhiên tôi thì thích nhân với 1 hơn, vì nó ngắn hơn:

=CONCATENATE(VLOOKUP(LEFT(C6,2),$B$25:$C$29,2,0), HLOOKUP(RIGHT(C6,1)*1,$H$24:$M$25,2,0))​

Nhưng đó chỉ mới là sửa cho đúng, chứ kết quả thì hơi kỳ: Ví dụ: "ĐƯỜNGPHÁP"(chả hiểu nó là cái gì), phải thêm một khoảng trắng ở giữa nữa. Bạn tham khảo 3 công thức sau đây, thích cái nào thì xài cái đó:

=CONCATENATE(VLOOKUP(LEFT(C6,2),$B$25:$C$29,2,0), " ", HLOOKUP(RIGHT(C6)*1,$H$24:$M$25,2,0))

=VLOOKUP(LEFT(C6,2),$B$25:$C$29,2,0) & " " & HLOOKUP(RIGHT(C6)*1,$H$24:$M$25,2,0))

=VLOOKUP(LEFT(C6,2),$B$25:$C$29,2,0) & " " & OFFSET($H$25,,RIGHT(C6)*1)​

 

[duongdv]

trường hợp của mình thì phải làm sao,ví dụ như ô D6 phải hiển thị là "đường pháp"chẳng hạn,mình thử rồi mà bị báo lỗi.bạn xem giùm mình nhé!

Do bảng dữ liệu của bạn định dạng không đúng, nên công thức của bạn mói báo lỗi như vậy?
Nếu bạn muốn thực hành bài toán này bạn nên làm lại bảng dữ liệu từ đầu. Để có được định dạng đúng

 

[dghoa]

cam ơn mọi người nha! mà không biết exel của mình có bị làm sao không mà như bạn duongdv nói thì toàn bị định dạng sai,mình muốn exel định dạng như mặc định ban đầu của nó thì làm như thế nào?

 

[duongdv]

cam ơn mọi người nha! mà không biết exel của mình có bị làm sao không mà như bạn duongdv nói thì toàn bị định dạng sai,mình muốn exel định dạng như mặc định ban đầu của nó thì làm như thế nào?

Việc cài đặt lại bộ office cùng phiên bản mà bạn đang sử dụng sẽ không ảnh hưởng gì đến dữ liệu bởi vậy nếu bảng tính nào của bạn cũng bị sai về định dạng như vậy thì bạn nên bỏ chút thời gian để cài đặt lại bộ Office là xong.
Chúc thành công.

 

[daretofail]

Nhờ mọi người giúp đỡ em ô kết quả đang bôi vàng như trong file. Cảm ơn mọi người nhiều.

 

[Let'GâuGâu]

Nhờ mọi người giúp đỡ em ô kết quả đang bôi vàng như trong file. Cảm ơn mọi người nhiều.

nếu chỉ có bao nhiêu đó ô thì thử

I2="Tháng "&IF(B2<>"",B2,"")&IF(C2<>"",IF(COUNT(B2),"+"&C2,C2),"")&IF(D2<>"",IF(COUNT(B2:C2),"+"&D2,D2),"")&IF(E2<>"",IF(COUNT(B2:D2),"+"&E2,E2),"")&IF(F2<>"",IF(COUNT(B2:E2),"+"&F2,F2),"")&IF(G2<>"",IF(COUNT(B2:F2),"+"&G2,G2),"")&"/"&H2

 

[HieuCD]

Nhờ mọi người giúp đỡ em ô kết quả đang bôi vàng như trong file. Cảm ơn mọi người nhiều.

ô I2
="Tháng "&REPLACE(IF(B2="","","+"&IF(B2>9,B2,"0"&B2))&IF(C2="","","+"&IF(C2>9,C2,"0"&C2))&IF(D2="","","+"&IF(D2>9,D2,"0"&D2))&IF(E2="","","+"&IF(E2>9,E2,"0"&E2))&IF(F2="","","+"&IF(F2>9,F2,"0"&F2))&IF(G2="","","+"&IF(G2>9,G2,"0"&G2)),1,1,"")&"/"&H2