Tìm dữ liệu không trùng (1 người xem)

[baquy]

Các Bạn giúp mình có cách nào để từ ô A2:A7 nếu "họ tên" của ai đó mà ko trùng với "vùng dữ liệu khai báo" thì sẽ tô mầu nền "xanh" cho ô đó.
Ví dụ: như ô A2 có tên là "Nguyễn Văn AA" (Họ tên của người này ko có trong vùng khai báo dữ liệu) cho nên được tô mầu nền xanh. Mình có gửi file đính kèm. Mong các Bạn giúp đỡ. Cảm ơn các Bạn nhiều!

 

[vodoi2x]

Dùng conditional Formatting

+ Chọn vùng A5:A10

+ Format / Conditional Formatting ... chọn Formula: nhập công thức
=COUNTIF($G$17:$G$21,$A5)=0

Click Format định dạng màu hay bất cứ cái gì bạn muốn

+ Click OK là được kết quả mong muốn

 

[ndu96081631]

Bài này đúng ra thuộc dạng dễ (như bạn vodoi2x làm là được rồi)
Thất nghiệp quá, xin đố mọi người 1 câu có liên quan: Nếu phân biệt luôn chữ HOA thường thì công thức sẽ sửa thế nào?
Ẹc... Ẹc...

 

[baquy]

Dùng conditional Formatting

+ Chọn vùng A5:A10

+ Format / Conditional Formatting ... chọn Formula: nhập công thức
=COUNTIF($G$17:$G$21,$A5)=0

Click Format định dạng màu hay bất cứ cái gì bạn muốn

+ Click OK là được kết quả mong muốn

Cảm ơn Bạn Vodoi2x rất nhiều! Đúng như ý của mình rồi. Nhưng có cách nào để ô ko có dữ liệu thì ko bị tô mầu ko bạn?

 

[ndu96081631]

Cảm ơn Bạn Vodoi2x rất nhiều! Đúng như ý của mình rồi. Nhưng có cách nào để ô ko có dữ liệu thì ko bị tô mầu ko bạn?

Thì thêm điều kiện vào:

=AND($A5<>"",COUNTIF($G$17:$G$22,$A5)=0)

 

[baquy]

Thì thêm điều kiện vào:

=AND($A5<>"",COUNTIF($G$17:$G$22,$A5)=0)

Cảm ơn Thầy nhiều nhiều!

 

[phihndhsp]

Bài này đúng ra thuộc dạng dễ (như bạn vodoi2x làm là được rồi)
Thất nghiệp quá, xin đố mọi người 1 câu có liên quan: Nếu phân biệt luôn chữ HOA thường thì công thức sẽ sửa thế nào?
Ẹc... Ẹc...

có cách cùi mía này hà anh ndu

ISERROR(FIND(A5,CONCATENATE($G$17,$G$18,$G$19,$G$20,$G$21),1))

xin anh ndu chỉ thêm cách hay để học hỏi thêm, xin chân thành cảm ơn

 

[vodoi2x]

Bài này đúng ra thuộc dạng dễ (như bạn vodoi2x làm là được rồi)
Thất nghiệp quá, xin đố mọi người 1 câu có liên quan: Nếu phân biệt luôn chữ HOA thường thì công thức sẽ sửa thế nào?
Ẹc... Ẹc...

cao thủ Ndu... mà thất nghiệp ở đây, thì cả GPE tan hết, hehe

Nhàn cư dễ gây bất ....ý kiến, nhưng bác lại có ý kiến hỏi mới sung (spam chút vì cũng đang nhàn), giải pháp ở dưới bác nhé

có cách cùi mía này hà anh ndu

ISERROR(FIND(A5,CONCATENATE($G$17,$G$18,$G$19,$G$20,$G$21),1))

xin anh ndu chỉ thêm cách hay để học hỏi thêm, xin chân thành cảm ơn

Làm gì phải phức tạp hóa vấn đề thế vậy thầy, và như thế phải chọn từng ô vùng nguồn nữa

Đơn giản điều kiện thay lại thế này thôi

=MIN(1*ISERROR(FIND($A5,$G$17:$G$21)))=1

-------------------

 

[phihndhsp]

=MIN(1*ISERROR(FIND($A5,$G$17:$G$21)))=1
công thức của bạn quả là Tuyệt vời, nhưng tại sao tôi thử từng phần từng phần nó không ra như ý muốn, mà khi thử hết thì nó mới ra đúng đáp số ta

 

[vodoi2x]

=MIN(1*ISERROR(FIND($A5,$G$17:$G$21)))=1
công thức của bạn quả là Tuyệt vời, nhưng tại sao tôi thử từng phần từng phần nó không ra như ý muốn, mà khi thử hết thì nó mới ra đúng đáp số ta

Muốn thử từng phần thì phải copy điều kiện đó ra 1 ô của excel (E5 chẳng hạn công thức mảng nên kết thúc Ctrl+Shift+Enter)
Giờ có thể thử từng phần rồi, thầy ah

 

[ndu96081631]

cao thủ Ndu... mà thất nghiệp ở đây, thì cả GPE tan hết, hehe

Nhàn cư dễ gây bất ....ý kiến, nhưng bác lại có ý kiến hỏi mới sung (spam chút vì cũng đang nhàn), giải pháp ở dưới bác nhé




Làm gì phải phức tạp hóa vấn đề thế vậy thầy, và như thế phải chọn từng ô vùng nguồn nữa

Đơn giản điều kiện thay lại thế này thôi

=MIN(1*ISERROR(FIND($A5,$G$17:$G$21)))=1

-------------------

Có vẻ không chính xác nha!
Ví dụ trường hợp trong danh sách gốc có tên Nguyễn Văn Dung mà danh sách cần tô màu lại có tên Nguyễn Văn Du
Ẹc... Ẹc...

 

[vodoi2x]

Có vẻ không chính xác nha!
Ví dụ trường hợp trong danh sách gốc có tên Nguyễn Văn Dung mà danh sách cần tô màu lại có tên Nguyễn Văn Du
Ẹc... Ẹc...

Thanks, Chuẩn, 1 phát hiện lý thú
Đúng là Find có thể đúng khi chứa có 1 phần,

Vậy bác thử giải pháp mới,
Điều kiện thay thành
=MIN(1*ISERROR(FIND("#"&$A5&"#","#"&$G$17:$G$21&"#")))=1

Nếu muốn thêm ô Trống không bị tô, thì thêm AND, như sau

=AND($A5<>"",MIN(1*ISERROR(FIND("#"&$A5&"#","#"&$G $17:$G$21&"#"))))

---------------

 

[ndu96081631]

Thanks, Chuẩn, 1 phát hiện lý thú
Đúng là Find có thể đúng khi chứa có 1 phần,

Vậy bác thử giải pháp mới,
Điều kiện thay thành (xét cả cho ô trống)
=AND($A8<>"",MIN(1*ISERROR(FIND("#"&$A5&"#","#"&$G$17:$G$21&"#"))))

---------------

Vì bạn dựa vào tiêu chí: TÊN THÌ KHÔNG THỂ CÓ DẤU # nên mới làm như vậy!
Đặt trường hợp tổng quát 1 chút thì sao? (tức danh sách bất kỳ, ký tự gì cũng được)
(Thật ra giải pháp rất đơn giản đấy! Và nói chung thì dùng FIND không phải là giải pháp)

 

[vodoi2x]

Nếu muốn thêm ô Trống không bị tô, thì thêm AND, như sau

=AND($A5<>"",MIN(1*ISERROR(FIND("#"&$A5&"#","#"&$G$17:$G$21&"#"))))


Đã post trùng, nhờ MODs xóa dùm, xin cảm ơn

 

[vodoi2x]

Vì bạn dựa vào tiêu chí: TÊN THÌ KHÔNG THỂ CÓ DẤU # nên mới làm như vậy!
Đặt trường hợp tổng quát 1 chút thì sao? (tức danh sách bất kỳ, ký tự gì cũng được)
(Thật ra giải pháp rất đơn giản đấy! Và nói chung thì dùng FIND không phải là giải pháp)

hehe, bác ah, giải pháp phải căn cứ dữ liệu, nếu thế thì thay ký tự khác, hoặc ký tự Trống cũng được vì luôn cách ký tự trống

Vì e rằng mọi người copy về bị Char(160 ) nên dùng ký tự # để đại diện

có giải pháp khác , nhưng đang muốn dùng FIND đơn giản

 

[ndu96081631]

hehe, bác ah, giải pháp phải căn cứ dữ liệu, nếu thế thì thay ký tự khác, hoặc ký tự Trống cũng được vì luôn cách ký tự trống

Vì e rằng mọi người copy về bị Char(160 ) nên dùng ký tự # để đại diện

có giải pháp khác , nhưng đang muốn dùng FIND,

Không được!
Nói tóm lại bạn muốn giải chính xác bài này thì hãy quên hàm FIND đi, vì chắc chắn 100% nó không phải là giải pháp

 

[vodoi2x]

Không được!
Nói tóm lại bạn muốn giải chính xác bài này thì hãy quên hàm FIND đi, vì chắc chắn 100% nó không phải là giải pháp

Bác cứ làm kho, nói chung là nhiều giải pháp, nhưng kiếm tìm giải pháp dễ hiểu và ngắn, - giải pháp phức tạp để dành cho các cao thủ ah

Thích quên FIND, thì dùng giải pháp SUBSTITUTE sau (đúng cho kiểu chuỗi ký tự)

Điều kiện cho Conditional formatting:
=AND($A5<>"",MIN(1*ISERROR(1*SUBSTITUTE($G$17:$G$21,$A5,0))))

Vậy bác ndu... và các thành viên khác có cách hay, cứ đưa lên để mọi người cùng tham khảo

 

[vodoi2x]

Giải pháp nữa, cho đẹp hơn

Chiều lòng bác ndu... vậy, kiếm tìm giải pháp cho cao thủ cũng mệt thật

Điều kiện thay thành

=AND($A5<>"",MAX(1*EXACT($A5,$J$17:$J$21))=0)

 

[ndu96081631]

Chiều lòng bác ndu... vậy, kiếm tìm giải pháp cho cao thủ cũng mệt thật

Điều kiện thay thành

=AND($A5<>"",MAX(1*EXACT($A5,$J$17:$J$21))=0)

Chính xác là hàm EXACT...
nhưng mà dùng hàm EXACT rồi còn thêm MAX làm chi ta?
Chẳng hạn có thể thế này:

=NOT(OR($A5="",EXACT(A5,$G$17:$G$21)))

Đâu thấy có vấn đề gi chứ

 

[vodoi2x]

Chính xác là hàm EXACT...
nhưng mà dùng hàm EXACT rồi còn thêm MAX làm chi ta?
Chẳng hạn có thể thế này:

=NOT(OR($A5="",EXACT(A5,$G$17:$G$21)))

Đâu thấy có vấn đề gi chứ

Đúng là gọn hơn, NHƯNG vẫn khẳng định là EXACT ...hehe

Cám ơn a, đã có những giờ thất nghiệp có ích,
NHƯNG sao các thành viên khác không cùng trao đổi nhỉ, hay cứ có a ndu là thôi ah ... vẫn có các giải pháp hay khác các bạn ah - hoặc không hay ở bài này, thì cũng có thể hay ở bài khác hoặc chí ít mọi người cùng học tập được điều gì đó.