Tách sau dấu gạch cuối cùng (1 người xem)

[Thư Tín]

Em muốn tách chuỗi ký tự sau dấu - cuối cùng ra kết quả như trong file đính kèm, nhờ mọi người giúp em công thức. Em cảm ơn nhiều ạ.

 

[Ba Tê]

Em muốn tách chuỗi ký tự sau dấu - cuối cùng ra kết quả như trong file đính kèm, nhờ mọi người giúp em công thức. Em cảm ơn nhiều ạ.

Công thức ô F4:

=TRIM(RIGHT(SUBSTITUTE(E4;"-";REPT(" ";10));10))

 

[Thư Tín]

Công thức ô F4:

=TRIM(RIGHT(SUBSTITUTE(E4;"-";REPT(" ";10));10))

Thân gởi bác Ba Tê
Giờ cháu muốn tách:
PR-H-BM1-1 tách thành PR-H-BM1
PR-H-BM11-1 tách thành PR-H-BM11
PR-H-CL12-22 tách thành PR-H-CL12
thì công thức trên phải sửa lại như thế nào ạ

 

[bebo021999]

Giờ này bác ấy "quắc" rồi bạn ơi

=SUBSTITUTE(TRIM(LEFT(SUBSTITUTE(A1,"-",REPT(" ",100)),LEN(SUBSTITUTE(A1,"-",REPT(" ",100)))-100))," ","-")

 

[Ba Tê]

Thân gởi bác Ba Tê
Giờ cháu muốn tách:
PR-H-BM1-1 tách thành PR-H-BM1
PR-H-BM11-1 tách thành PR-H-BM11
PR-H-CL12-22 tách thành PR-H-CL12
thì công thức trên phải sửa lại như thế nào ạ

Công thức trên gán cho nó bằng X
Kết quả = Left(Chuỗi, Len(Chuỗi)- Len(X)- 1)

 

[Phuocam]

. .

 

[Pro speed]

Em muốn tách chuỗi ký tự sau dấu - cuối cùng ra kết quả như trong file đính kèm, nhờ mọi người giúp em công thức. Em cảm ơn nhiều ạ.

Gửi bạn :

=TRIM(RIGHT(SUBSTITUTE(E4,"-",REPT(" ",LEN(E4))),LEN(E4)))

 

[Nhattanktnn]

Thân gởi bác Ba Tê
Giờ cháu muốn tách:
PR-H-BM1-1 tách thành PR-H-BM1
PR-H-BM11-1 tách thành PR-H-BM11
PR-H-CL12-22 tách thành PR-H-CL12
thì công thức trên phải sửa lại như thế nào ạ

Dữ liệu đúng kiểu như vậy thì công thức này cũng tạm:

=TRIM(MID(SUBSTITUTE(A1,"-",REPT(" ",100),3),1,100))

 

[Ba Tê]

Dữ liệu đúng kiểu như vậy thì công thức này cũng tạm:

=TRIM(MID(SUBSTITUTE(A1,"-",REPT(" ",100),3),1,100))

Không chủ quan là 3
Dữ liệu file bài #1 thế này:

195363-03-DWG-6002-CL6​

195363-03-DWG-6002-CL7​

195363-03-DWG-6002-CL14​

195363-03-DWG-6002-CL15​

195363-03-DWG-6002-AW-BM8​

195363-03-DWG-6002-AW-BM9​

195363-03-DWG-6002-AW-BM10​

195363-03-DWG-6002-AW-BM11​

195363-03-DWG-6002-AW-GR9

195363-03-DWG-6002-AW-GR10​

195363-03-DWG-6002-AW-GR11​

 

[ExcelQN]

Thân gởi bác Ba Tê
Giờ cháu muốn tách:
PR-H-BM1-1 tách thành PR-H-BM1
PR-H-BM11-1 tách thành PR-H-BM11
PR-H-CL12-22 tách thành PR-H-CL12
thì công thức trên phải sửa lại như thế nào ạ

F4:
=LEFT(E4,(LEN(E4)-LEN(TRIM(RIGHT(SUBSTITUTE(E4,"-",REPT(" ",10)),10)))-1))

 

[huuthang_bd]

Thử không theo lối mòn

=LOOKUP(2,1/(MID(E4,ROW($1:$99),1)="-"),LEFT(E4,ROW($1:$99)-1))

 

[Nhattanktnn]

Không chủ quan là 3
Dữ liệu file bài #1 thế này:

195363-03-DWG-6002-CL6​

195363-03-DWG-6002-CL7​

195363-03-DWG-6002-CL14​

195363-03-DWG-6002-CL15​

195363-03-DWG-6002-AW-BM8​

195363-03-DWG-6002-AW-BM9​

195363-03-DWG-6002-AW-BM10​

195363-03-DWG-6002-AW-BM11​

195363-03-DWG-6002-AW-GR9

195363-03-DWG-6002-AW-GR10​

195363-03-DWG-6002-AW-GR11​

Thì em làm theo cái cấu trúc đó thôi, còn nếu không thì sửa thành:

=TRIM(LEFT(SUBSTITUTE(A1,"-",REPT(" ",100),LEN(A1)-LEN(SUBSTITUTE(A1,"-",""))),100))