Hỏi: Công thức tính đơn giá (2 người xem)

[ly_1]

Chào các bạn.Mình không biết tính đơn giá vì "L" và "S" không biết dùng hàm nào:RIGHT,LEFT HAY MID nhưng dùng hàm VALUE(MID thì không được vì Value chỉ dùng cho số không dùng được cho chữ.Các bạn cho mình câu trả lời.

 

[MinhCong]

Chào các bạn.Mình không biết tính đơn giá vì "L" và "S" không biết dùng hàm nào:RIGHT,LEFT HAY MID nhưng dùng hàm VALUE(MID thì không được vì Value chỉ dùng cho số không dùng được cho chữ.Các bạn cho mình câu trả lời.

Bạn dùng công thức này xem sao?

=HLOOKUP(LEFT(B4,1),$B$16:$E$18,MATCH(LEFT(RIGHT(B4,3),1),$A$16:$A$18,0),0)

 

[ThuNghi]

Chào các bạn.Mình không biết tính đơn giá vì "L" và "S" không biết dùng hàm nào:RIGHT,LEFT HAY MID nhưng dùng hàm VALUE(MID thì không được vì Value chỉ dùng cho số không dùng được cho chữ.Các bạn cho mình câu trả lời.

Công thức

HLOOKUP(LEFT(B4,1),$B$17:$E$18,IF(RIGHT(B4,3,LEN(B4)-5)="L",2,3),0)

Bạn nên tách ra từng đoạn xem xét thử nhé

IF(RIGHT(B4,3,LEN(B4)-5)="L",2,3)

Có thể thay thế ham Mid

IF(MID($B4,4,1)="L",2,3)

hay là

=LEFT(RIGHT($B4,3),1)

Và phần dùng HLOOKUP(LEFT(B4,1),$B$17:$E$18... này bị sai do $B$17:$E$18 thiếu phần tham chiếu của LEFT(B4,1) phài là

HLOOKUP(LEFT(B4,1),$B$16:$E$18...

Và ct tại D4 là

=HLOOKUP(LEFT($B4,1),$B$16:$E$18,IF(MID($B4,4,1)="L",2,3),0)

Hay

=HLOOKUP(LEFT($B4,1),$B$16:$E$18,IF(LEFT(RIGHT($B4,3),1)="L",2,3),0)

Vận dụng làm tương tự nhé.
Chúc thành công.

 

[concogia]

Công thức
Bạn nên tách ra từng đoạn xem xét thử nhé
Có thể thay thế ham Mid
Và phần dùng HLOOKUP(LEFT(B4,1),$B$17:$E$18... này bị sai do $B$17:$E$18 thiếu phần tham chiếu của LEFT(B4,1) phài là
Và ct tại D4 là
Vận dụng làm tương tự nhé.
Chúc thành công.
À mà bài này chắc ra đề để thi cho vui, nếu chữ L trong D10L-A mà kg nằm ở vi trí 4 mà như D13150L-A thì cũng mệt.

Chỗ này không ổn
=HLOOKUP(LEFT($B4,1),$B$16:$E$18,IF(MID($B4,4,1)=" L",2,3),0)
Với dữ liệu trong bài có lẽ phải như "zì"
=HLOOKUP(LEFT($B4,1),$B$16:$E$18,IF(MID($B4,LEN(B4)-2,1)="L",2,3),0)

 

[boyxin]

Chào các bạn.Mình không biết tính đơn giá vì "L" và "S" không biết dùng hàm nào:RIGHT,LEFT HAY MID nhưng dùng hàm VALUE(MID thì không được vì Value chỉ dùng cho số không dùng được cho chữ.Các bạn cho mình câu trả lời.

Thêm 3 cách có thể tham khảo

Cách 1: Dùng HLOOKUP kết hợp với MATCH, MID, LEFT, LEN

D4 =HLOOKUP(LEFT($B4),$B$16:$E$18,MATCH(MID($B4,LEN(B4)-2,1),$A$16:$A$18,0),0)

Cách 2: Dùng VLOOKUP kết hợp với MATCH, MID, LEFT, LEN

D4 =VLOOKUP(MID($B4,LEN($B4)-2,1),$A$17:$E$18,MATCH(LEFT($B4),$A$16:$E$16,0))

Cách 3: Dùng OFFSET kết hợp với MATCH, MID, LEFT, LEN

D4 =OFFSET($A$16,MATCH(MID($B4,LEN($B4)-2,1),$A$17:$A$18,0),MATCH(LEFT($B4),$B$16:$E$16,0))

 

[dat_butmuc]

Với dữ liệu trong bài có lẽ phải như "zì"
=HLOOKUP(LEFT($B4,1),$B$16:$E$18,IF(MID($B4,LEN(B4)-2,1)="L",2,3),0)

Như "zì" được không?
=HLOOKUP(LEFT(B4),$B$16:$E$18,(MID(B4,LEN(B4)-2,1)="S")+2,0)