Chuyển thời gian từ dạng chứa chữ sang số (1 người xem)

[chinhntt3]

dear cả nhà!!!

Mọi người ơi giúp e với
E muốn chuyển thời gian từ dạng chứa chữ sang số thì làm thế nào ạ?

ví dụ:
1h20m30s => 01:20:30
52m20s => 0:50:20
50s => 0:0:50

e cảm ơn ạ!!!

 

[Phuocam]

1h20p30s => 01:20:30
52m20s => 0:50:20
50s => 0:0:50

Quy định phút là p hay là m hay cả 2?

 

[chinhntt3]

Quy định phút là p hay là m hay cả 2?

dạ e viết nhầm ạ, quy định chỉ có: h:m:s thôi ạ

 

[Phuocam]

dạ e viết nhầm ạ, quy định chỉ có: h:m:s thôi ạ

Nên sửa tiêu đề thành: Chuyển thời gian từ dạng chứa chữ sang số

 

[chinhntt3]

Nên sửa tiêu đề thành: Chuyển thời gian từ dạng chứa chữ sang số

dạ vâng

 

[Phuocam]

Giờ:

=IF(ISNUMBER(FIND("h",A1)),LEFT(A1,FIND("h",A1)-1),0)

Phút:

=IF(ISNUMBER(FIND("m",A1)),LOOKUP(60,--MID(A1,FIND("m",A1)-{1,2},{1,2})),0)

Giây:

=IF(ISNUMBER(FIND("s",A1)),LOOKUP(60,--MID(A1,FIND("s",A1)-{1,2},{1,2})),0)

Dùng hàm TIME() nối lại:

=TIME(Giờ, Phút,Giây)

 

[huuthang_bd]

dear cả nhà!!!

Mọi người ơi giúp e với
E muốn chuyển thời gian từ dạng chứa chữ sang số thì làm thế nào ạ?

ví dụ:
1h20m30s => 01:20:30
52m20s => 0:50:20
50s => 0:0:50

e cảm ơn ạ!!!

Bạn thử công thức này

=--SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(IF(ISERR(FIND("h",A1)),"0h","")&A1,"h",IF(ISERR(FIND("m",A1)),":0:",":")),"m",":"),"s","")

 

[Phan Thế Hiệp]

ví dụ:
1h20m30s => 01:20:30
52m20s => 0:50:20
50s => 0:0:50

Góp vui thêm 1 công thức mảng:

=SUM(MOD(SMALL({1,2,3}*100+IFERROR(--RIGHT(LEFT(A1,SEARCH({"h","m","s"},A1)-1),{1;2}),),{2,4,6}),100)/(24*{1,60,3600}))

Kết thúc bằng Ctrl+Shift+Enter.

Thân

 

[chinhntt3]

Giờ:

=IF(ISNUMBER(FIND("h",A1)),LEFT(A1,FIND("h",A1)-1),0)

Phút:

=IF(ISNUMBER(FIND("m",A1)),LOOKUP(60,--MID(A1,FIND("m",A1)-{1,2},{1,2})),0)

Giây:

=IF(ISNUMBER(FIND("s",A1)),LOOKUP(60,--MID(A1,FIND("s",A1)-{1,2},{1,2})),0)

Dùng hàm TIME() nối lại:

=TIME(Giờ, Phút,Giây)

dạ e cảm ơn nhé!