Trang 1/2 1 2 cuốicuối
Hiển thị kết quả tìm kiếm từ 1 đến 10 trên tổng số: 18
  1. #1
    Tham gia ngày
    03 2007
    Nơi Cư Ngụ
    TP. HCM
    Bài gởi
    2,025
    Cảm ơn
    2,622
    Được cảm ơn 17,663 lần trong 1,760 bài viết

    Smile Định dạng theo điều kiện (Conditional Formatting - CF) trong Excel

    Định dạng theo điều kiện (Conditional Formatting - CF) trong Excel

    CF được Microsoft bổ sung vào Excel kể từ phiên bản Microsoft Excel 97. CF trong Excel là một công cụ mạnh giúp chúng ta định dạng các chuỗi văn bản trong các ô, các giá trị và các ô về màu sắc, kiểu mẫu nền, kẻ khung…

    CF khi áp dụng vào các ô (cell) nó sẽ đè lên các định dạng thông thường của ô về màu sắc, kiểu thể hiện văn bản và số… Tuy nhiên nếu chúng ta xoá bỏ CF của các ô thì định dạng đã có trước kia của các ô này sẽ được phục hồi.

    CF trong các phiên bản Excel 2003 trở về trước có một số giới hạn về số lượng điều kiện (tối đa là 3) và điều này đã được khắc phục trong phiên bản Excel 2007 với số lượng điều kiện cho phép là 64.

    Tài liệu này sẽ cố gắng trình bày về CF thật bao quát, nhằm giúp các bạn có thể áp dụng được CF trong tất cả phiên bản Excel hiện có cũng như một số kỹ thuật CF bằng VBA. Tài liệu cũng đề cập thật chi tiết về các điểm mới của CF trong phiên bản mới nhất Excel 2007.

    Tài liệu có sử dụng lại một số bài viết và ví dụ thực tế về CF trên diễn đàn GPE (handung107, levanduyet, …). Rất mong nhận được ý kiến đóng góp của tất cả các bạn, góp ý xin gửi về ttphong77@gmail.com

    Nội dung

    I. CF các vấn đề cơ bản
    1. Giới thiệu CF
    2. CF dùng danh mục điều kiện sẵn có
    3. Thứ tự ưu tiên của các CF
    4. CF sử dụng các công thức làm điều kiện

    • Địa chỉ tương đối và tuyệt đối trong CF
    • Công thức mảng trong CF
    • Sử dụng tên (Define Name) trong CF
    • Sử dụng Date trong CF

    5. Thêm, thay đổi và xoá CF
    6. Dùng Go To tìm kiếm các ô có áp dụng CF
    7. Một số vấn đề thường gặp và hướng giải quyết

    II. Các ví dụ về CF và các kỹ thuật nâng cao

    III. Sử dụng CF của Excel 2007 & 2010

    Thanh Phong
    thay đổi nội dung bởi: TranThanhPhong, 11-08-10 lúc 09:51 AM

  2. Có 147 thành viên cảm ơn TranThanhPhong về bài viết này:

    37t2ty, adadas, alantran, anhdp87, anhtuan1066, applecake_cherry, ballade4012, binhan007, BNTT, BritneyBeer, bthnhulan, Bumblebee303, cadafi, cancer0000, cansa, Cá ngừ F1, chickenmut, ChoTay, chusydoan, cic123, congacon521, congan74, congatre, culup, cuongbkkx, cuongsaohb, daudaucantho, Dauthivan, DIEUTHUYEN, dinhthang08, do.phuong, ductm2009, dudieuwa, duongmanhquan, duongvannam27, duyle86, dvu58, eokakoe, Flemango, future_gtvt, giakhanh_m, giangtuyen, giaomua, Giveaway For You, haikich_85, havietchuong, Heraclex, hhanh, hien07, hienl, hieuhaian, hoang1819, hochanh1, hong gam, hongnhungpx, huongngan, huongnguyen_1212, idezai, kazumair, keentwo, ketoan.11091, kieuhuy_bmt, kimloai, kim_cuc11, kuailebakuaileba, kuongnguyen, l12a7, laidaugaux9x, lalang, lamphong0503, lazymanbk, lehongphong86, leolas, lienhuonglv, limfx, lkproGPE, luanvien177, luan_thao, mai07, maingocquan, mayan, maylangthang, meocon249, meoluoi2010, MicrosoftExcel, minhhangg, minhhuan_158, minhquang3211, namlh2187, NamThienVu, nauvtran, net11, nga.nuce, ngocanhpvoil, ngocphuongueh, ngoinhahoahong1492, ngontay, ngosaigon, LikeIt, nguyen duc man, NHẤT CHI MAI, nguyenhang87, nguyenquocvinh1102, nhimxubong, nhoccan, nhokteen, nmhung49, phamduylong, phamlephuongloan, phong lan hoàng thảo, qing yu, quangnghia1990, quyennhi, quyenpl89, ranmatkinh, RogueSven, seotopnhanh, soiconkthn, SoKyHa, songngu1983, sumisumo, sutbong, svcntnk42a1, t12446t, TDUNG8X, thangnet, thanhmartinez, Thay, TheLongHCM, thienthan_angle, thinhdvpg, tonghongngochuong, tonquan90, trangvkab, Trương Thanh Huấn, tuananhya2, tuansando, tuanubag, tung1286, tvgtyb08, ukaof, VMH0307, vnwo2, vucuong51, xuan.nguyen82, zenda0203, zyzytran

  3. #2
    Tham gia ngày
    03 2007
    Nơi Cư Ngụ
    TP. HCM
    Bài gởi
    2,025
    Cảm ơn
    2,622
    Được cảm ơn 17,663 lần trong 1,760 bài viết

    Wink I. Các vấn đề cơ bản của CF

    I. Các vấn đề cơ bản

    1. Giới thiệu CF

    Định dạng theo điều kiện là công cụ cho phép bạn áp dụng định dạng cho một ô (cell) hay nhiều ô (range of cells) trong bảng tính và sẽ thay đổi định dạng tùy theo giá trị của ô hay giá trị của công thức.

    Ví dụ như bạn có thể tạo cho định dạng của ô đó là chữ in đậm màu xanh khi giá trị của nó lớn hơn 100. Khi giá trị của ô thoả điều kiện thì các định dạng bạn tạo ra ứng với điều kiện đó sẽ được áp dụng cho ô đó. Nếu giá trị của ô không thoả điều kiện bạn tạo ra thì định dạng của ô đó sẽ áp dụng định dạng mặc định (default formatting)



    Một ô có thể có 3 định dạng theo điều kiện. Ví dụ như bảng phân tích độ nhạy của Lợi nhuận bên dưới ta sẽ dùng CF cho các ô C21:K31 với 3 điều kiện:
    • Nếu giá trị của ô lớn hơn 0 thì nó sẽ được thể hiện là màu xanh (lời),
    • Nếu gía trị của ô là 0 thì chữ sẽ màu cam (hoà vốn),
    • Và nếu giá trị của ô nhỏ hơn 0 thì chữ màu đỏ (lỗ).


    Bạn chú ý rằng CF giống như việc thêm một hay nhiều công thức vào mỗi ô mỗi khi bạn sử dụng, vì vậy áp dụng CF cho một số lớn các ô có thể gây ra việc thực hiện chương trình bị chậm đi. Do đó bạn hãy chú ý khi áp dụng CF cho một số lớn các ô trong bảng tính.


    Hai minh hoạ đơn giản đã trình bày chỉ là phần nổi rất nhỏ về khả năng của CF, các phần tiếp theo sẽ giúp bạn từng bước tiếp cận và làm chủ CF – một tính năng tuyệt vời của Excel.

    2. CF dùng danh mục điều kiện sẵn có

    Trong phần này sẽ trình bày về tuỳ chọn CF đơn giản nhất là Cell Value is trong hộp thoại CF, và kết hợp với các toán tử trong danh sách sẵn có để ra điều kiện định dạng. Hộp định dạng theo điều kiện cho Excel XP được thể hiện ở hình dưới đây.



    Trong đó có các tuỳ chọn:
    • Cell Value Is: căn cứ vào giá trị chứa trong ô để làm đối số so sánh và từ đó áp dụng các định dạng nếu thoã mãn điều kiện (điều kiện trả về TRUE trong kết quả so sánh).
    • Formula Is: căn cứ vào kết quả tính toán của các công thức làm đối số so sánh và từ đó áp dụng các định dạng nếu thoã mãn điều kiện (kết quả so sanh là TRUE). Phần này sẽ trình bày ở mục sau.
    Giải thích các toán tử so sánh:
    • Between: giá trị trong ô nằm trong đoạn từ a đến b (bao gồm 2 cận trên và dưới a, b)
    • Not between: giá trị trong ô không nằm trong đoạn [a, b]
    • Equal to: giá trị trong ô bằng (=) với giá trị so sánh
    • Not equal to: giá trị trong ô không bằng (≠) giá trị so sánh
    • Greater than: giá trị trong ô lớn hơn (>) giá trị so sánh
    • Less than: giá trị trong ô nhỏ hơn (<) giá trị so sánh
    • Greater than or equal to: giá trị trong ô lớn hơn hoặc bằng (≥) giá trị so sánh
    • Less than or equal to: giá trị trong ô nhỏ hơn hoặc bằng (≤) giá trị so sánh

    Ví dụ 2.1
    : Dùng CF định dạng cho các ô trong vùng B4:E12 sao cho các giá trị lớn hơn 100 sẽ tô màu chữ xanh và in đậm.

    B1. Chọn vùng cần định dạng B4:E12
    B2. Vào Format | chọn Conditional Formatting… hộp thoại Conditional Formating hiện ra
    B3. Chọn các tuỳ chọn như hình sau:
    • Tại Condition 1, chọn tuỳ chọn là Cell Value Is
    • Chọn toán tử so sánh là greater than
    • Nhập vào giá trị 100 tại hộp trống bên phải


    B4. Nhấn nút Format… hộp thoại Format Cells xuất hiện như hình sau
    • Chọn Bold (In đậm) tại Font style
    • Chọn màu xanh tại Color
    • Nhấn OK hoàn tất định dạng


    B5. Nhấn OK để bắt đầu áp dụng CF cho các ô trong vùng đang chọn.


    Ví dụ 2.2
    : Dùng CF định dạng cho các ô trong vùng H4:K12 sao cho các giá trị từ 80 đến 100 sẽ tô màu chữ xanh, in đậm và nền ô màu vàng; các ô còn lại tô chữ màu tím và nền ô màu xám.

    B1. Chọn vùng H4:K12 cần định dạng CF
    B2. Vào Format | chọn Conditional Formatting… hộp thoại Conditional Formating hiện ra
    B3. Chọn các tuỳ chọn như hình sau:
    • Tại Condition 1, chọn tuỳ chọn là Cell Value Is, chọn toán tử so sánh là between và nhập vào giá trị 80 và 100 tại 2 ô trống kế bên. Nhấn nút Format:
      • Tại ngăn Font chọn Bold tại Font style, chọn tiếp màu xanh tại Color
      • Chuyển qua ngăn Patterns và chọn màu vàng tại Cell shading
      • Nhấn OK hoàn tất CF1.
    • Nhấn nút Add >> để thêm điều kiện mới
    • Tại Condition 2, chọn tuỳ chọn là Cell Value Is, chọn toán tử so sánh là not between và nhập vào giá trị 80 và 100 tại 2 ô trống kế bên. Nhấn nút Format:
      • Tại ngăn Font chọn màu tím tại Color
      • Chuyển qua ngăn Patterns và chọn màu xám tại Cell shading
      • Nhấn OK hoàn tất CF2.


    B4. Nhấn OK để bắt đầu áp dụng CF cho các ô trong vùng đang chọn và bên dưới là kết quả




    Ví dụ 2.3
    : Dùng CF định dạng cho bảng kết quả phân tích độ nhạy của Lợi nhuận tại vùng C21:K31 với 3 điều kiện:
    • Nếu giá trị của ô lớn hơn 0 thì nó sẽ được thể hiện là màu xanh (lời),
    • Nếu gía trị của ô là 0 thì chữ sẽ màu cam (hoà vốn),
    • Và nếu giá trị của ô nhỏ hơn 0 thì chữ màu đỏ (lỗ).

    Bạn hãy tự thực hiện các thao tác sao cho các CF1, CF2 và CF3 như hình sau:



    Liệu chúng ta có thể áp dụng nhiều hơn 3 điều kiện cho giá trị trong các ô khi sử dụng các phiên bản Excel 2003 trở về trước không? Câu trả lời cho vấn đề này là có thể, chúng ta sẽ tiếp tục thảo luận về CF trong những bài tiếp theo.

    Thanh Phong
    Tập tin đính kèm Tập tin đính kèm
    thay đổi nội dung bởi: TranThanhPhong, 27-01-08 lúc 02:12 PM


  4. #3
    Tham gia ngày
    03 2007
    Nơi Cư Ngụ
    TP. HCM
    Bài gởi
    2,025
    Cảm ơn
    2,622
    Được cảm ơn 17,663 lần trong 1,760 bài viết

    Wink I. Các vấn đề cơ bản (tt)

    3. Thứ tự ưu tiên của các CF

    Khi bạn có hơn một điều kiện áp dụng cho một ô (cell) hay một vùng (range) thì các CF này sẽ được áp dụng theo trình tự ưu tiên của chúng, các CF nằm trên sẽ có mức ưu tiên cao hơn các CF nằm dưới. Đối với Excel 2003 trở về trước thì trình tự ưu tiên là CF1 à CF2 à CF3, đối với Excel 2007 CF nào nằm trên trong danh sách sẽ ưu tiên hơn CF nằm dưới. Do vậy chúng ta phải thật cẩn thận khi sắp xếp thứ tự ưu tiên của các CF nhằm tránh các kết quả không mong muốn. Bảng tóm tắt bên dưới mô tả cách thực thi CF của Excel trong các phiên bản trước Excel 2007.


    Điểm khác biệt về CF trong Excel 2007

    Excel 2007 cho phép áp dụng nhiều CF vào cùng một ô (cell) hay vùng (range) nếu các CF đúng (True) trong khi Excel 2003 trở về trước thì chỉ áp dụng duy nhất một CF đúng có thứ tự ưu tiên cao hơn và bỏ qua các CF có ưu tiên thấp hơn mặc dù nó đúng. Trong Excel 2007, khi chúng ta thiết lập nhiều CF cho một vùng các ô trong bảng tính, và khi có nhiều CF đúng (TRUE) đồng thời thì khi đó có khả năng các CF này có mâu thuẫn với nhau:
    • Khi các CF không mâu thuẫn với nhau: Ví dụ như CF1 sẽ áp dụng định dạng cho các ô là chữ in đậm và CF2 sẽ áp dụng định dạng cho các ô chữ màu xanh. Khi cả CF1 và CF2 đúng thì không có mâu thuẫn xảy ra và các ô thoã điều kiện sẽ được định dạng chữ màu xanh và in đậm.
    • Khi các CF có mâu thuẫn với nhau: Ví dụ như CF1 sẽ áp dụng định dạng cho các ô là chữ màu đỏ và CF2 sẽ áp dụng định dạng cho các ô chữ màu xanh. Khi cả CF1 và CF2 đúng thì có mâu thuẫn xảy ra và các ô thoã điều kiện sẽ chỉ được áp dụng định dạng của CF1 là chữ màu đỏ (vì CF1 có mức ưu tiên cao hơn CF2).
    Nhằm đảm bảo tính tương thích ngược với các phiên bản Excel 2003 trở về trước, khi các bạn sử dụng CF trong Excel 2007 thì nên sử dụng tuỳ chọn Stop If True trong hộp thoại Manage Rules.
    • Nếu chọn Stop If True tại CF1 thì Excel chỉ kiểm tra duy nhất CF1 bỏ qua tất cả các CFs bên dưới CF1.
    • Nếu chọn Stop If True tại CF2 thì Excel sẽ kiểm tra CF1 và CF2 bỏ qua tất cả các CFs bên dưới CF2.
    • Nếu chọn Stop If True tại CF3 thì Excel sẽ kiểm tra CF1, CF2 va2 CF3 bỏ qua tất cả các CFs bên dưới CF3.
    • Nếu chọn Stop If True cho tất cả các CF thì định dạng trả về trong Excel 2007 sẽ giống như định dạng trả về trong Excel của các phiên bản trước...
    Ví dụ 3.1: Vùng địa chỉ B3:B8 được áp dụng CF với 3 điều kiện sau:
    • Nếu giá trị trong ô lớn hơn 10 thì định dạng chữ in đậm
    • Nếu giá trị trong ô lớn hơn 20 thì định dạng chữ màu đỏ
    • Nếu giá trị trong ô lớn hơn 30 thì định dạng nền ô màu cam


    Hình trên trình bày các qui định của các CF1, CF2 và CF3 và kết quả trả về chỉ là của CF1, các CF2 và CF3 mặc dù đúng nhưng bị bỏ qua. (Excel 2003 trở về trước)



    Hình trên trình bày các qui định của các CF1, CF2 và CF3 và tuỳ chọn Stop If True cho CF3. Kết quả trả về chỉ là áp dụng tất cả các định dạng của CF1, CF2 và CF3 cho các ô thoã điều kiện. Nếu chọn Stop If True cho cả 3 CF1, CF2 và CF2 thì kết quả định dạng trả về sẽ giống như của Excel 2003 trở về trước.

    Happy day!

    Thanh Phong
    thay đổi nội dung bởi: TranThanhPhong, 28-01-08 lúc 07:11 AM


  5. #4
    Tham gia ngày
    03 2007
    Nơi Cư Ngụ
    TP. HCM
    Bài gởi
    2,025
    Cảm ơn
    2,622
    Được cảm ơn 17,663 lần trong 1,760 bài viết

    Wink 4. CF sử dụng các công thức làm điều kiện

    4. CF sử dụng các công thức làm điều kiện

    Ngoài việc sử dụng tuỳ chọn Cell Value Is và các phép so sánh, bạn có thể xây dựng những công thức riêng của bạn để xác định khi nào thì CF được áp dụng. Để sử dụng công thức riêng trong CF, bạn hãy thay đổi tuỳ chọn Cell Value Is sang Formula Is trong hộp thoại CF, và đưa công thức của bạn vào khung trống nhập liệu bên cạnh. Kết quả công thức của bạn nên trả về giá trị luận lý True (1) hay False (0). Nếu công thức bạn trả về giá trị True thì CF sẽ được áp dụng. Nếu công thức của bạn trả về giá trị False thì CF sẽ không được áp dụng.

    Các công thức phải bắt đầu là dấu bằng (=), trong công thức không thể tham chiếu trực tiếp đến một ô hay một vùng ở một worksheet hay workbook khác (Excel 2007 cho phép điều này). Chúng ta có thể định nghĩa tên (name) tham chiếu đến dữ liệu trên các vùng của các sheet hay workbook khác. Bạn không thể sử dụng những hàm trong module Add-in, nhưng bạn có thể sử dụng các hàm tự định nghĩa dựa trên bằng VBA trong công thức điều kiện.

    Ngoài ra bạn còn có thể nhập vào một ô trên sheet hiện hành tham chiếu đến dữ liệu trong một sheet của workbook khác sau đó khi khai báo điều kiện cho CF thì bạn chỉ cần tham chiếu đến ô giữ địa chỉ này.

    Ví dụ 4.1
    . Bạn muốn tham chiếu đến dữ liệu trong ô A5 trong Sheet1 của workbook Baocao chẳng hạn, thì tại Sheet đang thực hiện CF bạn chọn một ô nào đó nhập vào địa chỉ như sau: =[Baocao.xls]Sheet1!A5 và khi khai báo đối số điều kiện cho CF bạn chỉ cần tham chiếu đến ô giữ địa chỉ này.




    Một thuận lợi của việc sử dụng công thức trong CF là cho phép bạn thay đổi định dạng của một ô dựa trên giá trị của một ô khác.

    Ví dụ 4.2
    . Hãy tô chữ màu đỏ cho các ô tại A13:A18 khi các ô tương ứng ở cột B lớn hơn 10

    B1. Chọn vùng A13:A18
    B2. Vào Format | chọn Conditional Formatting… hộp thoại Conditional Formating hiện ra
    B3. Chọn các tuỳ chọn:
    • Chọn Formula is và nhập
    • Tại ô trống kế bên có thể sử dụng công thức =IF(B13>10,TRUE,FALSE), hay đơn giản hơn =B13>10 hay =$B13>10 hay =B13:B18>10… đều được. Cách dùng địa chỉ trong công thức của CF sẽ được trình bày trong phần sau.
    • Nhấn nút Format và chọn màu đỏ trong ngăn Font của hộp thoại Format Cells
    • Nhấn OK hoàn tất chọn màu cho chữ


    B4. Nhấn OK hoàn tất CF.


    Địa chỉ Tuyệt đối và Tương đối trong công thức của CF

    Khi bạn sử dụng công thức trong CF, bạn cần nhận thức được sự khác nhau giữa địa chỉ tuyệt đối và địa chỉ tương đối. Nếu bạn sử dụng định dạng theo điều kiện để áp dụng cho nhiều ô (range of cells), thì bạn sử dụng địa chỉ tương đối.

    Ví dụ 4.3.
    Giả sử rằng chúng ta muốn áp dụng định dạng theo điều kiện cho vùng A13:A18, sẽ được tô chữ màu đỏ nếu giá trị trong vùng B13:B18 lớn hơn 10. Chúng ta có thể dùng công thức =B13>10 để làm điều này. Tức là giả sử ô B14 có giá trị là 11 thì giá trị trong ô A14 sẽ được tô chữ đỏ. Đó là điều mà chúng ta thường muốn. Tuy nhiên giả sử rằng chúng ta muốn định dạng khoảng A13:A18 tô chữ màu đỏ nếu giá trị ô B13 lớn hơn 10, tức là mỗi ô trong vùng A13:A10 sẽ luôn luôn được so sánh với ô B13. Trong trường hợp này chúng ta phải sử dụng công thức =$B$13>10.



    Khi dùng điều kiện =$B$13>10 --> kết quả trả về False --> áp dụng CF này cho toàn vùng A13:A18 --> không có ô nào được tô chữ màu đỏ (đối chiếu với ví dụ 4.2 để thấy sự khác biệt).


    Công thức mảng (array formula) trong CF

    CF thực thi các công thức theo cách thức thực thi của công thức mảng trong bảng tính, do vậy bạn có thể sử dụng các công thức mảng trong CF. Tuy nhiên, kết thúc công thức mảng trong CF bạn không cần nhấn tổ hợp phím Ctrl+Shift+Enter để kết thúc công Excel luôn xử lý các công thức trong CF theo cách thức của công thức mảng trong bảng tính.

    Sử dụng tên (Name) trong CF

    Như đã nói ở trên, các công thức trong CF không thể tham chiếu đến các ô trong một sheet khác của cùng một workbook. Tuy nhiên bạn có thể khắc phục điều này bằng cách sử dụng tên (name). Định nghĩa một tên tham chiếu đến một vùng của sheet khác, và sử dụng tên đó trong công thức của bạn (với chú ý các địa chỉ tuyệt đối và tương đối như đã nói ở phần trên).

    Ví dụ 4.4.
    Giả sử rằng bạn muốn ô A22 trong sheet tên CFI.4 màu đỏ đậm nếu giá trị bạn nhập vào trong ô A22 không có trong danh sách các giá trị trong vùng A1:A10 nằm trong sheet tên là Ref. Nếu bạn lập công thức như sau thì sẽ bị báo lỗi =COUNTIF(Ref!$A$1:$A$10,A22)=0. Để khắc phục điều này bạn đặt tên Mylist tham chiếu đến vùng =Ref!$A$1:$A$10 và sử dụng tên này trong công thức của bạn như sau: =COUNTIF(MyList,A22)=0


    Sử dụng Date và Time trong CF

    Dates và times trong CF được xử lý dưới dạng các con số tuần tự. Ví dụ như bạn muốn so sánh giá trị trong các ô với ngày 17/02/2007 thì chính là bạn so sánh với con số tuần tự là 39130.

    Ví dụ 4.5.
    Hãy tô nền màu xanh cho các ô thuộc vùng số liệu B28:B37 với điều kiện Ngày ở vùng A28:A37 tương ứng phải lớn hơn ngày 20/02/2007 (có số tuần tự là 39133).

    B1. Chọn vùng B28:B37 và vào hộp thoại CF
    B2. Chọn Formula Is và nhập vào công thức =A28>39133
    B3. Nhấn nút Format, vào ngăn Pattern, chọn màu xanh
    B4. Nhấn OK hai lần để hoàn tất CF.




    Thanh Phong
    Tập tin đính kèm Tập tin đính kèm
    thay đổi nội dung bởi: TranThanhPhong, 30-01-08 lúc 10:38 AM


  6. #5
    Tham gia ngày
    03 2007
    Nơi Cư Ngụ
    TP. HCM
    Bài gởi
    2,025
    Cảm ơn
    2,622
    Được cảm ơn 17,663 lần trong 1,760 bài viết

    Wink 5. Thêm, sao chép, thay đổi và xoá CF

    5. Thêm, sao chép, thay đổi và xoá CF

    Thêm CF

    B1. Chọn các ô cần bổ sung CF
    B2. Chọn tuỳ chọn là Cell Value Is hay Formula Is tuỳ bạn và nhập các đối số cần thiết của CF vào
    B3. Nhấn nút Format và chọn định dạng phù hợp với yêu cầu: tô màu chữ, nền, mẫu nền, kẻ khung, …
    B4. Nhấn nút Add..và lặp lại các bước 1, 2 và 3 để thêm CF mới.

    Sao chép định dạng của CF cho các ô khác

    B1. Chọn các ô có CF mà ta muốn sao chép
    B2. Nhấn nút Format Painter ([IMG]file:///C:/DOCUME%7E1/ttphong/LOCALS%7E1/Temp/msohtmlclip1/01/clip_image001.gif[/IMG]) trên thanh thực đơn Formatting và quét vào các ô mà ta muốn áp dụng CF đang sao chép.

    Thay đổi hoặc xoá CF
    ·Thay đổi định dạng của CF: nhấn vào nút Format của CF mà bạn muốn thay đổi định dạng trong hộp thoại Conditional Formatting (mỗi CF sẽ có một nút Format riêng). Nhấn các nút Clear để xoá bỏ định dạng củ và chọn lại định dạng mới (hoặc chọn luôn định dạng mới cũng được).
    ·Xoá các CF: nhấn vào nút Delete trong hộp thoại Conditional Formatting và chọn các CF mà bạn muốn xoá, sau đó nhấn nút OK để xoá.


    • Khi bạn muốn xoá nhanh tất cả các CF và tất cả các định dạng khác trong các ô đang chọn thì vào thanh thực đơn Edit | chọn Clear | chọn tiếp Formats.
    6. Dùng Go To tìm kiếm các ô có áp dụng CF

    Để chọn tất cả các ô đang có áp dụng CF bạn làm các bước sau:

    B1. Chọn một ô bất kỳ trên sheet (hoặc chọn một ô đang áp dụng CF)
    B2. Vào thanh Edit | chọn Go To (Ctrl+G)
    B3. Nhấn vào nút Special…
    B4. Nhấn vào tuỳ chọn Conditional formats. Khi đó có 2 tuỳ chọn kèm theo tại Data validation
    • Chọn All: kết quả sẽ chọn tất cả các ô có áp dụng CF
    • Chọn Same: kết quả sẽ trả về tất cả các ô có áp dụng CF giống với ô mà bạn chọn ở bước 1. Nếu ô chọn ở bước 1 không có áp dụng CF thì sẽ có thông báo không tìm thấy



    7. Một số vấn đề thường gặp

    CF không áp dụng đúng

    Khi thấy kết quả định dạng trả về của CF không đúng bạn hãy kiểm tra lại:
    • Kiểm lại việc áp dụng nhiều CF cho ô hay vùng: Nếu bạn áp dụng nhiều CF cho một ô hay vùng và nếu có nhiều hơn một CF là đúng (True) thì Excel chỉ áp dụng CF đúng đầu tiên có thứ tự ưu tiên cao.
    • Kiểm tra xem các điều kiện của CF có giao nhau hay không:Nếu các điều kiện trong các CF bị trùng hay giao nhau một phần thì Excel cũng chỉ áp dụng điều kiện đúng đầu tiên. Ví dụ như bạn xác định điều kiện để tô màu nền vàng tại CF1 cho các ô có giá trị từ 100 đến 200, và tại CF2 bạn lại qui định áp dụng tô màu nền đỏ cho các giá trị nhỏ hơn 120. Khi đó các ô chứa giá trị từ 100 đến 119.999999999999 vẫn sẽ áp dụng định dạng của CF1.
    • Kiểm tra lại các địa chỉ tham chiếu:Nếubạn dùng các công thức trong điều kiện của các CF thì hãy địa chỉ tham chiếu này có khả năng bị sai.
    Các thiết lập trong hộp thoại CF biến mất
    • Bạn kiểm tra lại xem các ô mà bạn đang chọn có thể đang áp dụng nhiều loại CF khác nhau vì hộp thoại CF chỉ có thể hiển thị thông tin thiết lập của một loại CF tại một thời điểm mà thôi.
    • Bạn hãy chọn lại các ô khác và vào lại hộp thoại CF lần nữa.
    Không thể sử dụng một số kiểu định dạng trong CF
    • Chúng ta không thể định dạng độ cao dòng hoặc độ rộng cột bằng CF
    Các định dạng màu Font và tô bóng cho ô tự động thay đổi
    Khi chúng ta áp dụng CF cho các ô thì Excel sẽ áp dụng các định dạng cho ô phụ thuộc vào giá trị trong các ô hay kết quả luận lý trả về từ các công thức. Do vậy bạn hãy kiểm tra lai:
    • Nếu CF dùng tuỳ chọn Cell Value Is cho giá trị trong các ô đang chọn thì Excel xem giá trị chứa trong các ô là các chuỗi ASCII. Do vậy, các định dạng như in đậm, tô màu chữ có thể thay đổi nếu nội dung của ô thay đổi.
    • Định dạng của các CF (nếu CF đúng) sẽ đè lên định dạng thông thường của Excel (các định dạng dùng lệnh Fotmat | Cell… ).

    Thanh Phong


  7. #6
    Tham gia ngày
    03 2007
    Nơi Cư Ngụ
    TP. HCM
    Bài gởi
    2,025
    Cảm ơn
    2,622
    Được cảm ơn 17,663 lần trong 1,760 bài viết

    Wink II. Các ví dụ về CF và các kỹ thuật nâng cao

    II. Các ví dụ về CF và các kỹ thuật nâng cao

    A. Các ví dụ cơ bản

    1. Các vấn đề thường gặp


    a. Ẩn các lỗi (Hide Errors)

    Chúng ta có thể dùng CF để kiểm tra các lỗi trong công thức của các ô trên bản tính và thay đổi định dạng của chúng. Ví dụ sau bạn sẽ thấy khi các ô ở cột A chứa số 0 thì kết quả ở cột C sẽ có lỗi #DIV/0.

    B1. Chọn vùng C2:C5
    B2. Vào Format | Conditional Formatting
    B3. Chọn Formula Is trong Condition 1
    B4. Nhập vào công thức sau:
    =ISERROR(C2) : kiểm tra tất cả các lỗi
    =ISNA(C2) : chỉ kiểm tra lỗi #N/A thôi
    =ISERR(C2) : kiểm tra các lỗi ngoại trừ lỗi #N/A
    B5. Nhấn nút Format, chọn màu chữ trùng với màu của ô (ở đây là màu trắng)
    B6. Nhấn OK, và nhấn tiếp OK



    b. Tô màu nền các ô rỗng (ISBLANK)

    B1. Chọn vùng A1:C10
    B2. Vào Format | Conditional Formatting
    B3. Chọn Formula Is trong Condition 1
    B4. Nhập vào công thức: =ISBLANK(A1)
    B5. Nhấn nút Format, chọn màu nền xanh trong ngăn Patterns
    B6. Nhấn OK, và nhấn tiếp OK




    Ghi chú nhóm hàm IS

    Dùng để kiểm tra kiểu giá trị trong ô hoặc các tham chiếu



    c. Ẩn bớt các giá trị trùng (Hide Duplicate Values)

    Ví dụ như hình bên dưới, chúng ta sẽ dùng CF định dạng màu chữ của các giá trị trùng trong cột A (Region) bằng cách tô màu trắng để ẩn chúng đi cho dễ theo dõi.

    B1. Chọn vùng A2:A5
    B2. Vào Format | Conditional Formatting
    B3. Chọn Formula Is tại Condition 1
    B4. Nhập vào công thức =A2=A1
    B5. Nhấn chọn Format, chọn màu chữ sao cho trùng với màu của ô (màu trắng)
    B6. Nhấn OK, và nhấn tiếp OK



    d. Tô màu các giá trị trùng lặp trong cột (Highlight Duplicates in Column)

    B1. Chọn vùng A2:A11
    B2. Vào Format | Conditional Formatting
    B3. Chọn Formula Is tại Condition 1
    B4. Nhập vào công thức: =COUNTIF($A$2:$A$11,A2)>1
    B5. Nhấn nút Format, chọn màu chữ là màu xanh và in đậm
    B6. Nhấn OK, và nhấn tiếp OK



    (Còn tiếp phần này)

    TP.


  8. #7
    Tham gia ngày
    03 2007
    Nơi Cư Ngụ
    TP. HCM
    Bài gởi
    2,025
    Cảm ơn
    2,622
    Được cảm ơn 17,663 lần trong 1,760 bài viết

    Wink 1. CF và các vấn đề thường gặp (tt)

    A. Các ví dụ cơ bản

    1. Các vấn đề thường gặp (tt)

    ...

    e. Tô màu các phần tử thuộc danh sách (Highlight Items in a List)

    B1. Tạo danh sách C2:C4 (giả sử đặt tên là CodeList)
    B2. Chọn vùng số liệu A2:A7
    B3. Vào Format | Conditional Formatting
    B4. Chọn Formula Is từ Condition 1
    B5. Nhập vào công thức: =COUNTIF($C$2:$C$4,A2)
    hoặc nếu dùng Name cho danh sách thì nhập vào: =COUNTIF(CodeList,A2)
    B6. Nhấn nút Format, chọn màu nền là xanh nhạt
    B7. Nhấn OK, và nhấn tiếp click OK



    f. Tô màu các con số trùng với các con số cho trước

    Trong ví dụ này chúng ta dùng CF để tô màu nền các các ô chứa các con số trong vùng B2:G4 (vùng chứa các con số của vé số) nếu nó xuất hiện trong vùng B6:G6 (vùng kết quả xổ số).

    B1. Chọn vùng B2:G4
    B2. Vào Format | Conditional Formatting
    B3. Chọn Formula Is tại Condition 1
    B4. Nhập vào công: =COUNTIF($B$6:$G$6,B2)
    B5. Nhấn nút Format , chọn màu nền là xanh nhạt
    B6. Nhán OK, và nhấn tiếp OK



    g. Tô màu các ngày sắp đến hạn (Highlight Upcoming Expiry Dates)

    Tô màu các khoản phải trả sắp đến hạn trong 30 ngày nữa. Trong ví dụ này các ngày hết hạn chứa trong vùng A2:A4.

    B1. Chọn vùng A2:A4
    B2. Vào Format | Conditional Formatting
    B3. Chọn Formula Is tại Condition 1
    B4. Nhập vào công thức: =AND(A2-TODAY()>=0,A2-TODAY()<=30)
    B5. Nhấn nút Format, chọn màu xanh in cho chữ
    B6. Nhấn OK và nhấn tiếp OK.



    h. Ẩn nội dung các ô khi in (Hide Cell Contents When Printing)

    Bạn có thể dùng CF để ẩn nội dung các ô khi in ấn. Trong ví dụ này chúng ta sẽ tô màu trắng cho chữ trong các ô B2:F4 khi ô H1 chứa ký tự x. Muốn in các ô bị ẩn thì xoá ký tự x torng H1.

    B1. Chọn vùng B2:F4
    B2. Vào Format | Conditional Formatting
    B3. Chọn Formula Is tại Condition 1
    B4. Nhập vào công thức: =$H$1="x"
    B5. Nhấn nút Format , chọn định dạng các chữ màu trắng
    B6. Nhấn OK, và nhấn tiếp OK



    i. Tô màu nền cách dòng (Shade Alternating Rows)

    B1. Nhấp chuột vào nút Select All để chọn tất cả bảng tính
    B2. Vào Format | Conditional Formatting
    B3. Chọn Formula Is tại Condition 1
    B4. Nhập vào công thức: =MOD(ROW(),2)
    B5. Nhấn nút Format, vào ngăn Patterns chọn màu nền xanh nhạt
    B6. Nhấn OK, và nhấn tiếp OK


    • Muốn tô màu nền cách N dòng thì dùng công thức: =MOD(ROW(),N)=0
    • Muốn tô màu nền cách N cột thì dùng công thức: =MOD(COLUMN(),N)=0
    j. Tô màu nền nhóm N dòng cách quãng (Shade Bands of Rows)

    Bạn có thể dùng CF để tô màu nền cho một nhóm dòng trên bảng tính. Ví dụ này sẽ minh hoạ cách tô màu nền cách quãng 4 dòng.

    B1. Nhấn chuột lên nút Select All để chọn toàn bộ sheet
    B2. Vào Format | Conditional Formatting
    B3. Chọn Formula Is tại Condition 1
    B4. Nhập vào công: =MOD(INT((ROW()-1)/4)+1,2)
    B5. Nhấn nút Format, vào ngăn Patterns chọn màu nền là màu xám
    B6. Nhấn OK, và nhấn tiếp OK


    • Muốn tô nền nhóm N cách dòng thì dùng =MOD(INT((ROW()-1)/N)+1,2)

    k. Tô màu nền cách dòng trong danh sách đang áp dụng Filter (Shade Alternating Filtered Rows)

    B1. Chọn vùng A2:B29
    B2. Vào Format | Conditional Formatting
    B3. Tại Condition 1 chọn Formula Is
    B4. Nhận vào công thức: =MOD(SUBTOTAL(3,$A$1:$A2),2)
    B5. Nhấn chuột vào nút Format , vào ngăn Patterns, chọn màu nền xám
    B6. Nhấn OK, và nhấn tiếp OK
    B7. Khi áp dụnh Auto Filter danh sách thì các hàng vẫn được tô nền cách dòng.


    • Muốn tô màu nền cách N dòng thì dùng công thức: =MOD(SUBTOTAL(3,$A$1:$A2),N)
    l. Tạo các hình nền màu (Create Coloured Shapes)

    Bạn có thể dùng CF kết hợp font chữ để tạo nên các hình nền màu trong các ô. Trong ví dụ này chúng ta sẽ tô hình nền màu trong vùng C3:C7 tuỳ thuộc vào giá trị trong các ô ở cột B bên cạnh. Nếu giá trị nhỏ hơn 10 thì ô bên cột C cạnh bên sẽ là hình tròn màu đỏ, nếu giá trị lớn hơn 30 thì hiện hình vuông màu xanh, còn lại thì hiện hình thoi màu vàng.

    B1. Trong ô C3 nhập vào công thức: =IF(B3="","",IF(B3<10,"l",IF(B3>30,"n","t")))
    B2. Chép công thức xuống cho các ô C4:C7
    B3. Định dạng vùng C3:C7 với font chữ Wingding với màu vàng
    B4. Chọn vùng C3:C7
    B5. Vào Format | Conditional Formatting
    B6. Tại Condition 1 chọn Formula Is
    B7. Nhập vào công thức: =$B3<10
    B8. Nhấn nút Format và chọn màu font chữ là màu đỏ, sau đó nhấn nút OK.
    B9. Nhấn nút Add,
    B10. Tại Condition 2 chọn tiếp Formula Is
    B11. Nhập vào công thức: =$B3>30
    B12. Nhấn nút Format, và chọn màu xanh cho font chữ, sau đó nhấn nút OK.
    B13. Nhấn nút OK



    TP.
    Tập tin đính kèm Tập tin đính kèm
    thay đổi nội dung bởi: TranThanhPhong, 12-02-08 lúc 05:15 PM


  9. #8
    Tham gia ngày
    03 2007
    Nơi Cư Ngụ
    TP. HCM
    Bài gởi
    2,025
    Cảm ơn
    2,622
    Được cảm ơn 17,663 lần trong 1,760 bài viết

    Wink 2. Một số ví dụ về CF với dữ liệu Date – Time

    2. Một số ví dụ về CF với dữ liệu Date – Time

    a. Tô màu các ngày lớn hơn ngày 18/09/2000 (trong ô B24) một năm

    B1. Chọn vùng A2:B21
    B2. Vào CF và nhập vào công thức:
    =$A2>DATE(YEAR($B$24)+1,MONTH($B$24),DAY($B$24))
    B3. Định dạng nền màu xanh



    b. Tô màu nền các ngày từ 1/1/2001 đến ngày 30/4/2001

    B1. Chọn vùng D2:E21
    B2. Vào CF và nhập vào công thức:
    =AND($D2>=DATE(2001,1,1),$D2<=DATE(2001,4,30))
    B3. Định dạng nền màu xanh



    c. Tô màu nền các ngày trong tuần hiện hành (tuần bắt đầu là ngày chủ nhật)

    B1. Chọn vùng G2:H21
    B2. Vào CF và nhập vào công thức:
    =AND($G2>(TODAY()-WEEKDAY(TODAY())),$G2<=(TODAY()-WEEKDAY(TODAY())+7)) Hoặc dùng công thức sau:
    =($G2>(TODAY()-WEEKDAY(TODAY())) * ($G2<=(TODAY()-WEEKDAY(TODAY())+7))
    B3. Chọn màu nền xanh



    d. Tô màu nền các ngày cuối tuần (tuần bắt đầu là ngày chủ nhật)

    B1. Chọn vùng N2:O21
    B2. Vào CF và nhập vào công thức:
    =OR(WEEKDAY($N2)=1,WEEKDAY($N2)=7)
    B3. Chọn màu nền xanh



    e. Tô màu nền cho các ngày lễ

    Chúng ta có thể đặt tên cho vùng dữ liệu chứa các ngày lễ

    B1. Chọn vùng Q2:Q21
    B2. Vào CF và nhập vào công thức:
    =ISNUMBER(MATCH($Q2,$S$2:$S$4,0))
    B3. Chọn màu nền là màu xanh



    f. Tô màu các cột là ngày chủ nhật hàng tuần

    B1. Nhập ngày đầu của tháng vào ô U3
    B2. Tại ô V3 nhập vào =U3, tại ô W3 nhập vào =V3+1 , sao chép W3 cho các ô X3:AZ3
    B3. Định dạng vùng V3:AZ3 là dd (chỉ hiển thị ngày)
    B4. Chọn vùng V3:AZ21
    B5. Vào CF chọn Formula Is và nhập vào công thức: =WEEKDAY(V$3)=1
    B6. Chọn nền màu xanh



    g. Sử dụng hàm DateDif và CF để tô nền các thành viên nhỏ hơn 18 tuổi

    B1. Chọn vùng BB2:BC12
    B2. Vào CF và nhập vào công thức: =DATEDIF($BC2,TODAY(), “Y”)<=18
    B3. Chọn màu nền xanh



    h. Kết hợp TODAY và MONTH tô nền những người có sinh nhật trong tháng

    B1. Chọn vùng BE2:BF12
    B2. Vào CF và nhập vào công thức: =MONTH($BF2)=MONTH(TODAY())
    B3. Chọn màu nền xanh




    TP.

    (Tài liệu đang trong quá trình biên soạn và tổng hợp, nếu có ví dụ mới sẽ bổ sung sau).
    Tập tin đính kèm Tập tin đính kèm


  10. #9
    Tham gia ngày
    03 2007
    Nơi Cư Ngụ
    TP. HCM
    Bài gởi
    2,025
    Cảm ơn
    2,622
    Được cảm ơn 17,663 lần trong 1,760 bài viết

    Wink 3. Một số ví dụ về CF với dữ liệu dạng Text

    3. Một số ví dụ về CF với dữ liệu dạng Text

    a. Tô màu nền các ô chứa chuỗi đơn cần tìm

    B1. Chọn vùng A1:B10
    B2. Vào CF chọn Formula Is và nhập công thức:
    • Không phân biệt chữ HOA và thường thì dùng: =TRIM(A1)=”Đào”
    • Có phân biệt chữ HOA và thường thì dùng: =EXACT("Đào",A1)
    B3. Chọn nền màu xanh



    b. Tô màu nền các ô có chứa chuỗi con cần tìm

    B1. Chọn vùng D1:D10 (F1:F10)
    B2. Vào CF chọn Formula Is và nhập công thức:
    • Không phân biệt chữ HOA và thường thì dùng:
    =SEARCH(“Mai”,D1)
    • Có phân biệt chữ HOA và thường thì dùng
    =FIND("Mai",F1) hoặc dùng
    =LEN(F1)<>LEN(SUBSTITUTE(F1,“Mai”,””))
    B3. Chọn nền màu xanh



    c. Tô màu nền các ô chứa chuỗi có các chữ bắt đầu giống chuỗi cần tìm

    B1. Chọn vùng H1:H10 (J1:J10)
    B2. Vào CF chọn Formula Is và nhập công thức:
    • Không phân biệt chữ HOA và thường thì dùng:
    =COUNTIF(H1,”H*”) --> tô nền các ô có ký tự bắt đầu là ký tự H
    • Có phân biệt chữ HOA và thường thì dùng
    =FIND("H",J1)=1 --> tô nền các ô có ký tự bắt đầu là ký tự H
    B3. Chọn nền màu xanh




    d. Tô màu cả dòng khi có một ô thuộc dòng có chứa chuỗi cần tìm

    B1. Chọn các dòng 18 đến 27 (dòng 35 đến 44)
    B2. Vào CF chọn Formula Is và nhập công thức:
    • Ô chứa chuỗi đơn
    =CountIf(18:18,”Mai”) --> Tô màu cả dòng khi có ô chứa chuỗi đơn
    • Ô chứa chuỗi con
    =CountIf(35:35,”*Lan*”) --> Tô màu cả dòng khi có ô chứa chuỗi con
    B3. Chọn nền màu xanh





    e. Tô màu các dòng có lượng hàng tồn kho

    B1. Chọn vùng L2:O10
    B2. Vào CF chọn Formula Is và nhập vào công thức
    =$O2=”Có”
    B3. Chọn nền màu xanh



    TP.
    (Tài liệu đang trong quá trình biên soạn và tổng hợp, nếu có ví dụ mới sẽ bổ sung thêm).
    Tập tin đính kèm Tập tin đính kèm
    thay đổi nội dung bởi: TranThanhPhong, 13-02-08 lúc 04:49 PM


  11. #10
    Tham gia ngày
    03 2007
    Nơi Cư Ngụ
    TP. HCM
    Bài gởi
    2,025
    Cảm ơn
    2,622
    Được cảm ơn 17,663 lần trong 1,760 bài viết

    Wink 4. Các ví dụ CF sử dụng hàm thống kê

    4. Các ví dụ CF sử dụng hàm thống kê

    a. Tìm và tô màu nền của ô chứa giá trị lớn nhất trong vùng số liệu

    B1. Chọn vùng A1:C10
    B2. Vào CF, chọn Formula Is và nhập vào công thức
    =A1=MAX($A$1:$C$10)
    B3. Chọn Format và chọn màu nền xanh trong ngăn Patterns



    b. Tìm và tô màu nền của ô chứa giá trị lớn nhất, nhì, ba trong vùng số liệu

    B1. Chọn vùng E1:G10
    B2. Vào CF, chọn Formula Is và nhập vào công thức
    =E1>=LARGE($E$1:$G$10)
    B3. Chọn Format và chọn màu nền xanh trong ngăn Patterns



    c. Tìm và tô màu nền của ô chứa giá trị nhỏ nhất trong vùng số liệu

    B1. Chọn vùng I1:K10
    B2. Vào CF, chọn Formula Is và nhập vào công thức
    =I1>=MIN($I$1:$K$10)
    B3. Chọn Format và chọn màu nền xanh trong ngăn Patterns



    d. Tìm và tô màu nền của ô chứa giá trị nhỏ nhất khác không (0) trong vùng số liệu

    B1. Chọn vùng M1:O10
    B2. Vào CF, chọn Formula Is và nhập vào công thức
    =M1=MIN(IF($M$1:$O$10<>0,$M$1:$O$10))
    B3. Chọn Format và chọn màu nền xanh trong ngăn Patterns



    e. Tìm và tô màu nền của ô chứa giá trị nhỏ nhất, nhì, ba trong vùng số liệu

    B1. Chọn vùng Q1:S10
    B2. Vào CF, chọn Formula Is và nhập vào công thức
    =Q1<=SMALL($Q$1:$S$10,3)
    B3. Chọn Format và chọn màu nền xanh trong ngăn Patterns



    f. Tìm và tô nền của ô chứa giá trị lớn hơn giá trị trung bình cộng

    B1. Chọn vùng U1:W10
    B2. Vào CF, chọn Formula Is và nhập vào công thức
    =U1>AVERAGE($U$1:$W$10)
    B3. Chọn Format và chọn màu nền xanh trong ngăn Patterns



    TP.


Trang 1/2 1 2 cuốicuối

Thông tin về chủ đề này

Users Browsing this Thread

Hiện có 1 người đang xem đề tài này. (0 thành viên và 1 khách)

Đề tài tương tự

  1. Tô dòng trong Conditional Formatting
    Viết bởi AuditorZ trong chuyên mục Định dạng, trình bày, in ấn bảng tính
    Trả lời: 2
    Bài mới gởi: 28-11-10, 04:40 PM
  2. Conditional formatting
    Viết bởi quanghai1969 trong chuyên mục Lập Trình với Excel
    Trả lời: 9
    Bài mới gởi: 06-09-10, 10:16 PM
  3. công thức trong conditional formatting?
    Viết bởi khanhnth02 trong chuyên mục Hàm và công thức Excel
    Trả lời: 4
    Bài mới gởi: 22-06-09, 01:18 PM
  4. Hỏi cách dùng công thức trong conditional formatting
    Viết bởi meoluoi2010 trong chuyên mục Hàm và công thức Excel
    Trả lời: 1
    Bài mới gởi: 12-06-09, 04:41 PM
  5. Conditional Formatting
    Viết bởi Duong gia trong chuyên mục Những vấn đề chung
    Trả lời: 8
    Bài mới gởi: 05-09-08, 06:30 PM

Bookmarks

Bookmarks

Quyền Sử Dụng Ở Diễn Ðàn

  • Bạn không thể đăng đề tài mới
  • Bạn không thể đăng trả lời
  • Bạn không thể đăng file đính kèm.
  • Bạn không thể sửa bài viết.
  •  

Mudim v0.8 Tắt VNI Telex Viqr Tổng hợp
Chính tả Bỏ dấu kiểu mới  [Bật/Tắt (F9)]