[Hỏi] Xin chỉ giúp cách tính điền số thứ tự tự động, Sum tự động theo từng mục, Sum tổng cộng

Duy843824 · 2/8/23

Đầu tiên, xin cảm ơn các ACE đã xem bài, sau đó là góp ý, hướng dẫn. Do mình chưa nắm chính xác hướng xử lý nhu cầu nên để bài ở mục Hàm excel.

1. Vấn đề Đánh số thứ tự: (như file excel đính kèm là file đã hoàn chỉnh những nhu cầu cần làm)
- Nhưng để điền hết thứ tự theo như vầy thì mình làm tay hoàn toàn chưa có biện pháp nào khác làm nhanh, nhiều khi có rất nhiều sai sót kéo theo nếu mệt quá, làm nhầm. Khi ví dụ có 03 - 05 mục lớn (tạm gọi Chương) trong file VD có 2 chương A và B, mỗi Chương có 05 đến 20 mục nhỏ (tạm gọi Điều) trong file VD là I,II,III .... thì làm rất lâu và sai sót ko kiểm soát được.
- Đặc biệt khi thay đổi, thêm bớt, xóa, chèn ... thì phải ngồi chỉnh lại từ đầu rất lâu.
- Vậy xin hỏi các bạn có cách nào chỉ giúp để có thể tự động hóa/ kiểm soát kiểm tra dễ dàng hơn. Mình chỉ cần chọn phần nào là Chương (VD trong file: nhập A, B), sẽ tự chạy các số thứ tự I -> II -> III ... và các con của I,II,III này cũng tự chạy/ cập nhật khi có thay đổi từ 1 -> n...

2. Vấn đề tính tổng (gọi tắt Sum) từng điều, Sum từng chương:
- Như trong file ví dụ. Sau khi mình sắp xếp, thêm vớt các thành phần con tứ 1->n; các điều I, II, III ....; các chương A, B, C... thì mới bắt đầu ngồi Sum lại từ nhỏ đến lớn. Từ các điều => các Chương => Tổng cộng Dự toán.
- Việc này sẽ phải ngồi làm lại/ chỉnh sửa rất nhiều và dễ nhầm lẫn lộn khi thêm bớt, xóa Con/ xóa Điều ...
- Câu hỏi cũng như ở 1. có cách nào để có thể tự động hóa/ kiểm soát kiểm tra dễ dàng hơn xin các ACE chỉ giúp.
XIN CẢM ƠN RẤT NHIỀU.

bebo021999 · 3/8/23

Xài đỡ cái này, có thể giảm 80% việc làm thủ công.
Nếu muốn tự động hóa hoàn toàn thì dùng VBA.

dangductuong2125 · 3/8/23

CT đánh số thứ tự tại A7 ngắn hơn tí :

Mã:

=MAX(INDEX($A$6:A6,IFERROR(MATCH(2,INDEX(1/($C$6:C6=""),)),1),):A6,0)+1

bebo021999 · 3/8/23

dangductuong2125 đã viết:
CT đánh số thứ tự tại A7 ngắn hơn tí :

Mã:

=IF(C7="","",MAX(INDEX($A$6:A6,IFERROR(MATCH(2,INDEX(1/($C$6:C6=""),)),1),):A6,0)+1)

CT của bạn đang chỉ đánh số TT 1,2,3, còn chữ cái và số La mã thì không.
Nếu chỉ có vậy thì sao không dùng cái này:

Mã:

=IFERROR(1/(1/IF(ISNUMBER(E7),IF(E6="",1,A6+1))),"")

Cái khó của yêu cầu bài này là dùng 1 CT duy nhất cho hỗn hợp A,B,C, I,II,II và 1,2,3 cho cột A
Có thêm yêu cầu sum thành tiền nữa thì mình cho rằng hàm UDF (dùng VBA) là thích hợp hơn cả

dangductuong2125 · 3/8/23

bebo021999 đã viết:
CT của bạn đang chỉ đánh số TT 1,2,3, còn chữ cái và số La mã thì không.
Nếu chỉ có vậy thì sao không dùng cái này:

Mã:

=IFERROR(1/(1/IF(ISNUMBER(E7),IF(E6="",1,A6+1))),"")

Cái khó của yêu cầu bài này là dùng 1 CT duy nhất cho hỗn hợp A,B,C, I,II,II và 1,2,3 cho cột A
Có thêm yêu cầu sum thành tiền nữa thì mình cho rằng hàm UDF (dùng VBA) là thích hợp hơn cả

À vâng em không đọc hết đoạn chủ thớt yêu cầu cả số la mã. hi

HieuCD · 3/8/23

Duy843824 đã viết:
Đầu tiên, xin cảm ơn các ACE đã xem bài, sau đó là góp ý, hướng dẫn. Do mình chưa nắm chính xác hướng xử lý nhu cầu nên để bài ở mục Hàm excel.

1. Vấn đề Đánh số thứ tự: (như file excel đính kèm là file đã hoàn chỉnh những nhu cầu cần làm)
- Nhưng để điền hết thứ tự theo như vầy thì mình làm tay hoàn toàn chưa có biện pháp nào khác làm nhanh, nhiều khi có rất nhiều sai sót kéo theo nếu mệt quá, làm nhầm. Khi ví dụ có 03 - 05 mục lớn (tạm gọi Chương) trong file VD có 2 chương A và B, mỗi Chương có 05 đến 20 mục nhỏ (tạm gọi Điều) trong file VD là I,II,III .... thì làm rất lâu và sai sót ko kiểm soát được.
- Đặc biệt khi thay đổi, thêm bớt, xóa, chèn ... thì phải ngồi chỉnh lại từ đầu rất lâu.
- Vậy xin hỏi các bạn có cách nào chỉ giúp để có thể tự động hóa/ kiểm soát kiểm tra dễ dàng hơn. Mình chỉ cần chọn phần nào là Chương (VD trong file: nhập A, B), sẽ tự chạy các số thứ tự I -> II -> III ... và các con của I,II,III này cũng tự chạy/ cập nhật khi có thay đổi từ 1 -> n...

2. Vấn đề tính tổng (gọi tắt Sum) từng điều, Sum từng chương:
- Như trong file ví dụ. Sau khi mình sắp xếp, thêm vớt các thành phần con tứ 1->n; các điều I, II, III ....; các chương A, B, C... thì mới bắt đầu ngồi Sum lại từ nhỏ đến lớn. Từ các điều => các Chương => Tổng cộng Dự toán.
- Việc này sẽ phải ngồi làm lại/ chỉnh sửa rất nhiều và dễ nhầm lẫn lộn khi thêm bớt, xóa Con/ xóa Điều ...
- Câu hỏi cũng như ở 1. có cách nào để có thể tự động hóa/ kiểm soát kiểm tra dễ dàng hơn xin các ACE chỉ giúp.
XIN CẢM ƠN RẤT NHIỀU.

Mã:

A5 =IF(AND(C5="",C6=""),MID(ADDRESS(1,COUNTIFS($C$4:C5,"",$C$5:C6,""),4),1,1)&" ",IF(C5="",ROMAN(COUNTBLANK(INDEX($C$4:C5,LOOKUP(2,1/(RIGHT($A$4:A5)=" "),ROW($1:2))):C5)-1),COUNTA(INDEX($C$4:C5,LOOKUP(2,1/($C$4:C5=""),ROW($1:2))):C5)))

Mã:

G5 =IF(AND(C5="",C6=""),SUBTOTAL(9,G6:INDEX(G6:$G$49,AGGREGATE(15,6,ROW($1:49)/(C7:$C$49="")/(C8:$C$50=""),1))),SUBTOTAL(9,G6:INDEX(G6:$G$49,AGGREGATE(15,6,ROW($1:49)/(C7:$C$50=""),1))))

Copy cho các ô còn lại

Duy843824 · 3/8/23

Xin cám ơn mọi người, để mình thử từng cách của mọi người xong báo lại kết quả nhé. :clap2:

LmoovoenX · 3/8/23

Góp vui nhé bạn:

Mã:

A5=IF(C5="",IF(C6=""," "&MID(ADDRESS(1,COUNTIF($A$4:A4,"* ")+1),2,1)&" ",IFERROR(ROMAN(ARABIC(OFFSET(A4,-A4,0))+1),"I")),N(A4)+1)

Mã:

G5=IF(AND(F5="",F6=""),SUM(OFFSET(F5,1,1,MATCH(1,1/ISBLANK(F6:$F$50)/ISBLANK(F7:$F$51),0)-1))/2,IF(F5="",SUM(OFFSET(F5,1,1,MATCH(1,1/ISBLANK(F6:$F$50),0)-1)),E5*F5))

Duy843824 · 4/8/23

HieuCD đã viết:

Mã:

A5 =IF(AND(C5="",C6=""),MID(ADDRESS(1,COUNTIFS($C$4:C5,"",$C$5:C6,""),4),1,1)&" ",IF(C5="",ROMAN(COUNTBLANK(INDEX($C$4:C5,LOOKUP(2,1/(RIGHT($A$4:A5)=" "),ROW($1:2))):C5)-1),COUNTA(INDEX($C$4:C5,LOOKUP(2,1/($C$4:C5=""),ROW($1:2))):C5)))

Mã:

G5 =IF(AND(C5="",C6=""),SUBTOTAL(9,G6:INDEX(G6:$G$49,AGGREGATE(15,6,ROW($1:49)/(C7:$C$49="")/(C8:$C$50=""),1))),SUBTOTAL(9,G6:INDEX(G6:$G$49,AGGREGATE(15,6,ROW($1:49)/(C7:$C$50=""),1))))

Copy cho các ô còn lại

Mình copy vào ô G5, kéo hết xuống tất cả còn lại. thì nó ra 0 hết . 1 vài vị trí #NUM!
Máy mình cài mặc định dấu ; thay vì , trong lệnh hàm. Và đã sửa lại hết thành ; copy vào thì ra kết quả như đã nói.
Cảm ơn b.
- Mình thử phần Tổng trước. phần STT chưa kiểm tra.

Duy843824 · 4/8/23

LmoovoenX đã viết:

Góp vui nhé bạn:

Mã:

A5=IF(C5="",IF(C6=""," "&MID(ADDRESS(1,COUNTIF($A$4:A4,"* ")+1),2,1)&" ",IFERROR(ROMAN(ARABIC(OFFSET(A4,-A4,0))+1),"I")),N(A4)+1)

Mã:

G5=IF(AND(F5="",F6=""),SUM(OFFSET(F5,1,1,MATCH(1,1/ISBLANK(F6:$F$50)/ISBLANK(F7:$F$51),0)-1))/2,IF(F5="",SUM(OFFSET(F5,1,1,MATCH(1,1/ISBLANK(F6:$F$50),0)-1)),E5*F5))

Phần Thành tiền: các dòng con ra số hết. Nhưng dòng tổng của I II III và A B tổng cuối: bị #DIV/0! hết b.
Bạn xem dùm sao vậy. Thanks b.

LmoovoenX · 4/8/23

Duy843824 đã viết:
Phần Thành tiền: các dòng con ra số hết. Nhưng dòng tổng của I II III và A B tổng cuối: bị #DIV/0! hết b.
Bạn xem dùm sao vậy. Thanks b.

Thứ 1, bạn sửa lại những chữ viết tắt và tiếng anh, đây là nội quy diễn đàn.
Thứ 2, bạn gửi lại phần bị lỗi xem sao. Mình thử trên máy mình thấy không lỗi.

HieuCD · 4/8/23

Duy843824 đã viết:
Mình copy vào ô G5, kéo hết xuống tất cả còn lại. thì nó ra 0 hết . 1 vài vị trí #NUM!
Máy mình cài mặc định dấu ; thay vì , trong lệnh hàm. Và đã sửa lại hết thành ; copy vào thì ra kết quả như đã nói.
Cảm ơn b.
- Mình thử phần Tổng trước. phần STT chưa kiểm tra.

Công thức ô G5 chị copy cho nhưng ô màu xanh

Duy843824 · 5/8/23

LmoovoenX đã viết:
Thứ 1, bạn sửa lại những chữ viết tắt và tiếng anh, đây là nội quy diễn đàn.
Thứ 2, bạn gửi lại phần bị lỗi xem sao. Mình thử trên máy mình thấy không lỗi.

Đây bạn xem dùm nhé. Cám ơn bạn.

Duy843824 · 5/8/23

HieuCD đã viết:
Công thức ô G5 chị copy cho nhưng ô màu xanh

1. Sau khi chỉ copy vào những ô màu xanh: tất cả số đã chạy đúng.
Chỉ có duy nhất tổng của Chương: B nó bị kết quả là: #Num!
2. Sau đó mình thử chèn thêm 1 dòng (dòng thứ 8 trong file gửi kèm): thì tổng của Chương: A cũng bị: #Num!
Bạn xem dùm nhé. Cảm ơn bạn.

HieuCD · 5/8/23

Duy843824 đã viết:
1. Sau khi chỉ copy vào những ô màu xanh: tất cả số đã chạy đúng.
Chỉ có duy nhất tổng của Chương: B nó bị kết quả là: #Num!
2. Sau đó mình thử chèn thêm 1 dòng (dòng thứ 8 trong file gửi kèm): thì tổng của Chương: A cũng bị: #Num!
Bạn xem dùm nhé. Cảm ơn bạn.

Thêm dữ liệu phải tính lại tham chiếu, chỉnh số 50 thành 500, 51 thành 501, nếu thích dùng hàng nghìn cũng được

LmoovoenX · 5/8/23

Duy843824 đã viết:
Đây bạn xem dùm nhé. Cám ơn bạn.

Bạn thử lại, tại ô G5 sau khi gõ công thức xong thì nhấn ctrl shift enter thay vì chỉ nhấn enter.

Duy843824 · 18/8/23

HieuCD đã viết:
Thêm dữ liệu phải tính lại tham chiếu, chỉnh số 50 thành 500, 51 thành 501, nếu thích dùng hàng nghìn cũng được

Cảm ơn bạn... thành công luôn bạn ơi ... hè hè. :rofl:

Duy843824 · 20/8/23

được rồi bạn LmoovoenX
cám ơn bạn nhé. Bấm ctrl + Shift + enter lại ok hết.

[Hỏi] Xin chỉ giúp cách tính điền số thứ tự tự động, Sum tự động theo từng mục, Sum tổng cộng

Thành viên mới

File đính kèm

Thành viên gạo cội

File đính kèm

Thành viên tiêu biểu

Thành viên gạo cội

Thành viên tiêu biểu

Chuyên gia GPE

Thành viên mới

Thành viên tiêu biểu

Thành viên mới

Thành viên mới

Thành viên tiêu biểu

Chuyên gia GPE

Thành viên mới

File đính kèm

Thành viên mới

File đính kèm

Chuyên gia GPE

Thành viên tiêu biểu

File đính kèm

Thành viên mới

Thành viên mới

Facebook

Group