Bài viết: VLOOKUP có phân biệt chữ hoa và thường

[kyo]

VLOOKUP có phân biệt chữ hoa và thường


Nếu bạn để ý, bạn sẽ thấy VLOOKUP không hề phân biệt chữ hoa và thường. Để chứng thực cho điều này, giả sử tôi có dữ liệu như sau:

Bạn có thể thấy, dùng VLOOKUP thông thường khiến cho Excel trả về kết quả là 1 dù rằng cái bạn cần là giá trị số 4 tương ứng với dòng chữ GIẢI PHÁP EXCEL.

Trong nhiều trường hợp, bài toán này là một vấn đề nhức nhối và bạn thì không biết phải giải quyết bằng cách nào.

Cách 1: Sử dụng VLOOKUP và một cột phụ

Dĩ nhiên rồi, vì VLOOKUP không thể phân biệt nên bạn cần một công thức khác có khả năng phân biệt làm nền trước. Đầu tiên, bạn hãy tạo một cột đằng trước cột A, ngay lập tức cột mới phát sinh sẽ trở thành cột A và cột còn lại là cột B. Sau đó bạn gõ công thức: =EXACT(B2,$F$2)

Như bạn thấy, bằng cách sử dụng hàm EXACT để phân biệt trước, bạn sẽ có kết quả tại cột phụ là TRUE hoặc FALSE, và từ đó dùng VLOOKUP để tìm giá trị TRUE.
=VLOOKUP(TRUE,$A$2:$C$5,3,FALSE)

Hoặc nếu bạn không muốn dùng cột phụ, bạn có thể kết hợp hàm EXACT với hàm CHOOSE để tạo một bảng dữ liệu ảo. Tuy nhiên công thức này sẽ cần nhấn Ctrl + Shift + Enter.
{=VLOOKUP(TRUE,CHOOSE({1,2},EXACT($B$2:$B$5,$F$2),$C$2:$C$5),2,FALSE)}

Như vậy qua đó bạn có thể thấy, nếu dùng VLOOKUP, hoặc là bạn phải cần một cột phụ, hoặc bạn phải dùng một hàm khác lạ hơn, đó là CHOOSE.

Cách 2: Dùng INDEX + MATCH

INDEX + MATCH là cặp đôi cùng tiến đầy sức mạnh mà bạn có thể sử dụng để thay thế hàm VLOOKUP. Và trong khả năng nhận biết chữ hoa và thường này, bạn cũng có thể sử dụng nó.
{=INDEX(C2:C5,MATCH(TRUE,EXACT(F3,B2:B5),0))}

Như bạn thấy trên hình trên, cũng với hàm EXACT và công thức mảng, bạn đã có thể giải quyết mối bận tâm bấy lâu mà vẫn dùng hàm quen thuộc là INDEX + MATCH. Nhưng nó vẫn cần sử dụng Ctrl + Shift + Enter.

Cách 3: Dùng LOOKUP

LOOKUP là một hàm rất mạnh được ra đời sau VLOOKUP và INDEX + MATCH, tuy nhiên ít được chú ý tới do cách vận dụng của nó có đôi chút phức tạp. Tuy vậy, bạn cứ thử xem, trong trường hợp này, hãy dùng công thức:
=LOOKUP(1,1/EXACT(B2:B5,F4),C2:C5)

Với công thức trên, bằng cách dùng 1 chia một mảng gồm TRUE và FALSE, bạn sẽ nhận về kết quả tương ứng {1;#DIV/0!;#DIV/0!;#DIV/0!}. Từ đây, hàm LOOKUP dò tìm giá trị 1 sẽ chọn ngay vị trí 1 trong mảng và đối chiếu qua cột số thứ tự để lấy cho bạn.

Và bạn có thể thấy, không cần đến Ctrl + Shift + Enter, cũng không cần đến cột phụ nhưng bạn vẫn hoàn thành điều mà bạn cần.

Chúc bạn thành công!

Một số bài viết có liên quan:
1/ Làm cách nào để ghi chú hiệu quả trong VBA?
2/ Conditional Formatting cho biểu đồ bằng VBA
3/ Khi nào nên sử dụng Msgbox, Inputbox và Userform?
4/ 8 thủ thuật trong VBE bạn nên biết
5/ Kích hoạt macro từ nút bấm ngoài bảng tính
6/ Làm thế nào để thay thế các chữ OK, CANCEL,... nhàm chán của Msgbox
7/ Giới thiệu VBA trong Excel
8/ Viết code để nhìn thấy ai là người cập nhật bảng tính của bạn lần gần đây nhất
9/ 4 cách sử dụng Immediate Window trong VBA hiệu quả hơn
10/ 3 gợi ý nhỏ mang lại thành công trong khai báo biến trong VBA