Hỏi về cách tính ngày tháng

[031113]

Em chào các bác.
Em có vướng mắc nhỏ mong các bác hướng dẫn. Em muốn tính ngày tháng: vd ngày 26/05/2017 em cộng thêm 2 ngày kết quả trả về 28/05/2017 nhưng ngày này là vào chủ nhật em muốn nó tự động cộng thêm 1 ngày nếu kết quả trả về là ngày chủ nhật thì phải làm ntn ạ?
Mong nhận được sự chỉ dẫn của các bác.

 

[bebo021999]

Với A1 là ngày bắt đầu:

=WORKDAY.INTL(A1,2,11)

 

[031113]

Với A1 là ngày bắt đầu:

=WORKDAY.INTL(A1,2,11)

Em thử làm nhưng kết quả tra về là #name? Không biết e làm sai ở đâu bác giúp e với ạ

 

[vanthinh3101]

Em thử làm nhưng kết quả tra về là #name? Không biết e làm sai ở đâu bác giúp e với ạ

Bạn dùng office 2007 hay 2010 ah?
Bạn thử dùng công thức này xem, A1 là ngày bắt đầu nhé!
=IF(WEEKDAY(A1+2,1)=1,A1+2+1,A1+2)

 

[Hoang2013]

Em muốn tính ngày tháng:
vd ngày 26/05/2017 em cộng thêm 2 ngày kết quả trả về 28/05/2017 nhưng ngày này là vào chủ nhật em muốn nó tự động cộng thêm 1 ngày nếu kết quả trả về là ngày chủ nhật thì phải làm ntn ạ?

Mình có thắc mắc: Có khi nào bạn nhập con số lớn hơn 7 không vậy? & lúc đó bạn muốn nó cọng vô bao nhiêu?

 

[031113]

Bạn dùng office 2007 hay 2010 ah?

Em đang dùng office 2007 bác ak

 

[ngoctinh87]

Em thử làm nhưng kết quả tra về là #name? Không biết e làm sai ở đâu bác giúp e với ạ

Công thức này chỉ áp dụng cho office 2010 trở lên.

 

[031113]

Mình có thắc mắc: Có khi nào bạn nhập con số lớn hơn 7 không vậy? & lúc đó bạn muốn nó cọng vô bao nhiêu?

Dạ với việc bây giờ thì em chỉ muốn cộng thêm 2 ngày vào ngày bắt đầu và nếu kết quả trả về vào ngày chủ nhật thì cộng thểm 1 ngày thôi ak

 

[031113]

Công thức này chỉ áp dụng cho office 2010 trở lên.

Dạ e đang dung office 2007 ak
Em thử làm là
=workday(a1,2,1)
A1 là ngày bắt đầu
Thì khi kết quả tra về ngày chủ nhật thì no lại cộng thêm 2 ngày

 

[031113]

Bạn dùng office 2007 hay 2010 ah?
Bạn thử dùng công thức này xem, A1 là ngày bắt đầu nhé!
=IF(WEEKDAY(A1+2,1)=1,A1+2+1,A1+2)

Vâng e vừa làm theo công thức của bác thì được kết quả như y luôn. Rất cảm ơn bác và các bác khác đã xem và giúp đỡ em. Chúc các bác cuối tuần vui vẻ ^^

 

[quocgiacan]

Dạ e đang dung office 2007 ak
Em thử làm là
=workday(a1,2,1)
A1 là ngày bắt đầu
Thì khi kết quả tra về ngày chủ nhật thì no lại cộng thêm 2 ngày

Giả sử: A1= 26/05/2017, A2=2 (số ngày cộng thêm)

Thử: =(WEEKDAY(A1+A2)=1)+A1+A2

 

[bebo021999]

Cái này ngắn hơn một chút:

=A1+2+(WEEKDAY(A1+2)=1)

 

[quocgiacan]

Vâng e vừa làm theo công thức của bác thì được kết quả như y luôn. Rất cảm ơn bác và các bác khác đã xem và giúp đỡ em. Chúc các bác cuối tuần vui vẻ ^^

Bạn có nghĩ qua cái phức tạp hơn như anh Hoang2013 có hỏi:

Mình có thắc mắc: Có khi nào bạn nhập con số lớn hơn 7 không vậy? & lúc đó bạn muốn nó cọng vô bao nhiêu?

Giả sử không phải là 2 ngày cộng thêm, mà là 7 ngày, hoặc 14, hoặc 21 ngày thì có phải cộng bù thêm các ngày CN không?

Lúc đó công thức sẽ không đơn giản với trường hợp bạn đang sử dụng Excel 2007.

Vd: A1= 26/05/2017
A2=8 ngày cộng thêm, thì trong kỳ này có 2 ngày CN, vậy nếu bù thì 8 ngày tính từ 26/05/2017 phải là ngày 05/06/2017.

Công thức tổng quát phải là:

=SMALL(IF(WEEKDAY(A1+ROW(INDIRECT("1:"&A2+7)))>1,A1+ROW(INDIRECT("1:"&A2+7))),A2)

Ctrl+Shift+Enter
Hoặc:

=AGGREGATE(15,6,(A1+ROW(INDIRECT("1:"&A2+7)))/(WEEKDAY(A1+ROW(INDIRECT("1:"&A2+7)))>1),A2)

Enter

Chúc bạn ngày vui.

 

[huonglien1901]

Bạn có nghĩ qua cái phức tạp hơn như anh Hoang2013 có hỏi:


Giả sử không phải là 2 ngày cộng thêm, mà là 7 ngày, hoặc 14, hoặc 21 ngày thì có phải cộng bù thêm các ngày CN không?

Lúc đó công thức sẽ không đơn giản với trường hợp bạn đang sử dụng Excel 2007.

Vd: A1= 26/05/2017
A2=8 ngày cộng thêm, thì trong kỳ này có 2 ngày CN, vậy nếu bù thì 8 ngày tính từ 26/05/2017 phải là ngày 05/06/2017.

Công thức tổng quát phải là:

=SMALL(IF(WEEKDAY(A1+ROW(INDIRECT("1:"&A2+7)))>1,A1+ROW(INDIRECT("1:"&A2+7))),A2)

Ctrl+Shift+Enter
Hoặc:

=AGGREGATE(15,6,(A1+ROW(INDIRECT("1:"&A2+7)))/(WEEKDAY(A1+ROW(INDIRECT("1:"&A2+7)))>1),A2)

Enter

Chúc bạn ngày vui.

Anh Quốc giải thích ý nghĩa của công thức này được không? Em muốn học hỏi thêm,.

 

[quocgiacan]

Anh Quốc giải thích ý nghĩa của công thức này được không? Em muốn học hỏi thêm,.

=SMALL(IF( WEEKDAY(A1+ROW(INDIRECT("1:"&A2+7)))>1, A1+ROW(INDIRECT("1:"&A2+7) ) ),A2)
Đại khái:
Từ ngày 26/05/2017, cộng thêm A2+7=8+7= 15 ngày nữa, tạo thành mảng ngày {27/5,28/5,29/5,...,10/6}, tìm xem các ngày đó không là ngày chủ nhật, dùng SMALL() xếp thứ tự từ nhỏ đến lớn, chọn ngày nhỏ nhất thứ A2, tức là ngày nhỏ thứ 8 trong SMALL.

Hàm Aggregate() cũng tương tự.

Chúc em ngày vui.

 

[eke_rula]

Bạn có nghĩ qua cái phức tạp hơn như anh Hoang2013 có hỏi:


Giả sử không phải là 2 ngày cộng thêm, mà là 7 ngày, hoặc 14, hoặc 21 ngày thì có phải cộng bù thêm các ngày CN không?

Lúc đó công thức sẽ không đơn giản với trường hợp bạn đang sử dụng Excel 2007.

Vd: A1= 26/05/2017
A2=8 ngày cộng thêm, thì trong kỳ này có 2 ngày CN, vậy nếu bù thì 8 ngày tính từ 26/05/2017 phải là ngày 05/06/2017.

Công thức tổng quát phải là:

=SMALL(IF(WEEKDAY(A1+ROW(INDIRECT("1:"&A2+7)))>1,A1+ROW(INDIRECT("1:"&A2+7))),A2)

Ctrl+Shift+Enter
Hoặc:

=AGGREGATE(15,6,(A1+ROW(INDIRECT("1:"&A2+7)))/(WEEKDAY(A1+ROW(INDIRECT("1:"&A2+7)))>1),A2)

Enter

Chúc bạn ngày vui.

26/05/2017+8=03/06/2017 chỉ có 1 ngày CN sao anh tính 2 ta:
Em cũng góp thêm 1 cách khác:

=A1+A2+INT((A2-7+WEEKDAY(A1,2))/7)+1

 

[quocgiacan]

26/05/2017+8=03/06/2017 chỉ có 1 ngày CN sao anh tính 2 ta:
Em cũng góp thêm 1 cách khác:

=A1+A2+INT((A2-7+WEEKDAY(A1,2))/7)+1

Ngày 28/5 và 4/6 em, tổng cộng: 27/5,29/5,30/5,31/5,1/6,2/6,3/6,5/6 = 8 ngày

 

[huonglien1901]

=SMALL(IF( WEEKDAY(A1+ROW(INDIRECT("1:"&A2+7)))>1, A1+ROW(INDIRECT("1:"&A2+7) ) ),A2)
Đại khái:
Từ ngày 26/05/2017, cộng thêm A2+7=8+7= 15 ngày nữa, tạo thành mảng ngày {27/5,28/5,29/5,...,10/6}, tìm xem các ngày đó không là ngày chủ nhật, dùng SMALL() xếp thứ tự từ nhỏ đến lớn, chọn ngày nhỏ nhất thứ A2, tức là ngày nhỏ thứ 8 trong SMALL.

Hàm Aggregate() cũng tương tự.,

Chúc em ngày vui.

Hàm aggregate em chưa thấy lần nào luôn Anh, hàm đặc biệt quá,
Em cảm ơn Anh Quốc đã khai sáng sự ngu dốt của em, đáng để học

 

[quocgiacan]

26/05/2017+8=03/06/2017 chỉ có 1 ngày CN sao anh tính 2 ta:
Em cũng góp thêm 1 cách khác:

=A1+A2+INT((A2-7+WEEKDAY(A1,2))/7)+1

Khà khà! của em rơi vào ngày 04/05 là ngày CN.

 

[bebo021999]

Giả sử không phải là 2 ngày cộng thêm, mà là 7 ngày, hoặc 14, hoặc 21 ngày thì có phải cộng bù thêm các ngày CN không?

quocgiacan đang "hình sự" hóa vụ việc rồi, kekeke
Đơn giản là né ngày chủ nhật thôi, chứ không phải là tính số ngày làm việc trong khoảng thời gian.
Giống như gặp khách hàng đâu đó bên ngoài, mời đến công ty ký hợp đồng sau 2 ngày nữa, nhưng làm ơn né ngày Chủ nhật giùm.